Zahlen Soritieren nach größe

[DelphiDustin]

Hallo Leute,

ich hab den soritierungs fehler das immer nur nach der ersten zahl sortiert wird heißt

24
5
67
9

z.B es soll aber natürlich

5
9
24
67

dort stehen. Mir ist bewusst das es daran liegt das es als string und nicht als int formatiert ist. Ich suche nach einer leichten möglichkeit das, nachdem ich es zu einer int formatiert habe, es nach größe zu sortieren. Hat jemand eine gute und leicht zu verstehende methode für mich das zu lösen?

[Uwe Raabe]

Nenn doch bitte deine Delphi-Version und zeig uns deinen Code.

[DelphiDustin]

procedure TForm4.Button1Click(Sender: TObject);
var
z1, z2, z3, z4:string;
Stringlist : TStringlist;
begin
listbox1.Clear;
z1:=edit1.text;
z2:=edit1.text;
z3:=edit1.text;
z4:=edit1.text;
Stringlist := TStringList.create;
stringlist.Delimiter:=',';
stringlist.DelimitedText:=edit1.Text;
stringlist.Sorted:=true;
Stringlist.Sort;
listbox1.Items.Add(Stringlist[0]);
listbox1.Items.Add(Stringlist[1]);
listbox1.Items.Add(Stringlist[2]);
listbox1.Items.Add(Stringlist[3]);
end;
end.

Ich benutze Delphi 10.2

[p80286]

Wahrscheinlich hast Du es übersehen:

Zitat:

Zitat von Schokohase (Beitrag 1445482)

Da du die Delphi-Version nicht angegeben hast, gehe ich mal von der neuesten (Rio 10.3.2) aus.

Delphi-Quellcode:

uses
  System.SysUtils,
  System.Generics.Collections;

procedure TForm1.SortButtonClick(Sender: TObject);
var
  input: string;
  splitted: TArray<string>;
  strItem: string;
  numbers: TArray<Integer>;
  numItem: Integer;
begin
  // Auslesen aus dem Edit
  input := InputEdit.Text;
  // Trennen am Komma
  splitted := input.Split([',']);
  // Umwandeln in (Ganz-)Zahlen
  numbers := [];
  for strItem in splitted do
  begin
    numbers := numbers + [Integer.Parse(strItem)];
  end;
  // Sortieren
  TArray.Sort<Integer>(numbers);
  // Ausgabe
  SortedNumberListBox.Items.BeginUpdate();
  try
    SortedNumberListBox.Items.Clear();
    for numItem in numbers do
      SortedNumberListBox.Items.Add(numItem.ToString());
  finally
    SortedNumberListBox.Items.EndUpdate();
  end;
end;

Ich geh mal davon aus, daß Schokohase weiß was erschreibt.

Gruß
K-H

P.S. das "Helm-Icon" st wirklich hilfreich um den Sourcecode leserlich zu posten.

[DelphiDustin]

Zitat:

Ich geh mal davon aus, daß Schokohase weiß was erschreibt.

Ja schon aber ich arbeite erst mit 3 tagen mit delphi und ich würde gerne ein bisschen versthen was ich programmiere und nicht einfach stumpf abschreiben.

[Stevie]

Eine TStringList sortiert strings und keine Zahlen und da ist die Sortierung '24', '5', '67', '9' durchaus richtig.
Wenn du also Zahlen speichern und sortieren willst, dann pack sie in eine TList<Integer> (unit System.Generics.Collections)

[haentschman]

Zitat:

dann pack sie in eine TList<Integer>

...wäre auch meine bevorzugte Variante.

1. Lesen was TList<> ist. http://docwiki.embarcadero.com/Libra...lections.TList
2. dann machst du aus den Strings in der TStringlist richtige Zahlen (Integer) und packst sie in die TList<Integer)
3. TList<Integer>.Sort Sortieren
4. TList durchlaufen und die Zahlen wieder nach String wandeln, damit sie in der Listbox angezeigt werden können.

[Uwe Raabe]

Zitat:

Zitat von Stevie (Beitrag 1445678)

Eine TStringList sortiert strings und keine Zahlen und da ist die Sortierung '24', '5', '67', '9' durchaus richtig.

Das kann man aber zumindest mit einem CustomSort beeinflussen (siehe https://www.delphipraxis.net/1445547-post9.html)

[Stevie]

Was man nicht alles kann... Frage ist eher, ob man das einem Anfänger so beibringt oder ihm lieber anrät, Daten auch in ihrem optimalen Format zu verarbeiten und nur von Eingabe und nach Anzeige in Strings umzuwandeln. Sonst kommen nämlich irgendwann so Fragen wie "Hilfe, mein Program ist langsam, woran liegt das" ;)

[Bernhard Geyer]

Stichwort wäre hier "Natural Sort".
Und das würde (im Gegensatz zu Nutzung von TList<Integer>) auch mit gemischten Daten (Zahlen und Text) zurecht kommen.

[Sherlock]

Es gilt immer noch die Maxime den Datentypen zu verwenden, der am ehesten den Daten entspricht. Darum ist bei der Verwendung von Zahlen lediglich noch zu fragen, ob es stets ganze Zahlen sind, oder auch mal etwas mit Nachkommaanteil vorkommt. Dann schließe ich mich Stevie und haentschman an mit der Anpassung des Typs gemäß der ermittelten Anforderung, also

Delphi-Quellcode:

TList<Integer>

oder eben

Delphi-Quellcode:

TList<Float>

.

Sherlock

[Stevie]

Zitat:

Zitat von Sherlock (Beitrag 1445731)

oder eben

Delphi-Quellcode:

TList<Float>

Float? *hüstel*

[Uwe Raabe]

Zitat:

Zitat von Sherlock (Beitrag 1445731)

Es gilt immer noch die Maxime den Datentypen zu verwenden, der am ehesten den Daten entspricht.

Das ist immer eine Frage der Sichtweise. Unter der Annahme, daß es sich immer noch um das in dem anderen Thread beschriebene Problem handelt (und der gezeigte Code lasst das vermuten), liegen die Eingangsdaten in Form einer durch Komma und Leerzeichen separierten Liste von Zahlen vor (string), die am einfachsten durch Zuweisen von CommaText in eine StringList aufgelöst werden kann. Einen recht simplen Weg, diese StringList in die gewünschte Sortierung zu bringen, habe ich gezeigt. Danach werden die einzelnen Zahlen in das Items-Property einer ListBox transferiert, wobei man das entgegen dem gezeigten Code-Beispiel einfach durch Zuweisung der StringList erledigen kann.

Berücksichtigt man all das, reduziert sich der Code auf diese Zeilen:

Delphi-Quellcode:

function NumberCompareStrings(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := string.Compare(List[Index1], List[Index2], [coDigitAsNumbers]);
end;

procedure TForm4.Button1Click(Sender: TObject);
var
  lst: TStringlist;
begin
  lst := TStringlist.create;
  try
    lst.CommaText := Edit1.text;
    lst.CustomSort(NumberCompareStrings);
    ListBox1.Items := lst;
  finally
    lst.Free;
  end;
end;

Man sollte bedenken, daß die einzige Rechtfertigung, das Ganze mit einer TList<Integer> oder Ähnlichem zu realisieren, auf dem Wunsch nach einer bestimmten Sortierung basiert. Sowohl bei der Eingabe im TEdit als auch bei der Ausgabe in die Listbox wird ausschließlich mit Strings gearbeitet. Ändert sich der Sortierwunsch, weil plötzlich keine reinen Zahlen, sondern sowas wie "M1, M2, MM11' oder sonstwas im Editfeld steht, würde der TList<Integer> Ansatz einen womöglich recht aufwändigen Umbau des Codes erfordern und schlimmstenfalls zu einer vollkommen redundanten TList<string> Implementierung führen.

Die hier gezeigte Implementierung ist gegen einen derartigen Requirement-Change stabil oder lässt sich durch eine geeignete Anpassung der Compare-Function mit minimalem Aufwand anpassen. Eine Lösung mit TList<Integer> geht meiner Meinung nach an der Problemstellung vorbei und ist unter den bisher bekannten Rahmenbedingungen vollkommen over-engineered.

[KodeZwerg]

Delphi-Quellcode:

TList.Add(POINTER(dieVariableVomFloat));

falls es hilft und wenn ich das richtig im gedächtnis habe, hab ich so tlist mit single (float) precision angelegt und easy sortieren lassen, ansonsten ignorieren :)