TObjectList sauber an function übergeben und wieder zurück

[norwegen60]

Hallo.

ich habe eine TObjectList, bei der ich verschiedene Berechnungen vornehmen will. Ich suche den sauberen Weg, wie ich die Liste an die Funktionen übergeben und des Ergebnis wieder zurück gebe. Dabei soll es möglich sein, dass die SourceList unverändert bleibt.

Hier ein abgespecktes Beispiel

Delphi-Quellcode:

type
  TTest = class
  private
    FValue: Double;
  public
    property Value: Double read FValue write FValue;

    constructor Create;
    destructor Destroy; override;
  end;

  TTestList = class(TObjectList<TTest>);

implementation

procedure PrePareList(SourceList, DestList: TTestList);
// Erstellt Liste und kopiert Werte von SourceList dort hin
var
  i: Integer;
  lTest: TTest;

begin
  if DestList <> nil then
    DestList.Free;
  DestList := TTestList.Create(true);

  for i := 0 to SourceList.Count - 1 do
  begin
    lTest := TTest.Create;
    DestList.Add(lTest);
    lTest.Value := SourceList[i].Value;
  end;
end;

function DoAdding(SourceList, DestList: TTestList):Boolean;
var
  i: Integer;
  lTempList: TTestList;

begin
  PrePareList(SourceList, DestList: TTestList); // Damit wird in jedem Fall DestList = SourceList zurück gegeben

  for i := 0 to DestList.Count - 1 do
    DestList[i].Value := DestList[i].Value + 5;

  Result := true;  // Wenn korrekt ausgeführt. In Beispiel einfach immer
end;

function DoMultiplicate(SourceList, DestList: TTestList):Boolean;
var
  i: Integer;
  lTempList: TTestList;

begin
  PrePareList(SourceList, DestList: TTestList); // Damit wird in jedem Fall DestList = SourceList zurück gegeben

  for i := 0 to DestList.Count - 1 do
    DestList[i].Value := DestList[i].Value * 5;

  Result := true;  // Wenn korrekt ausgeführt. In Beispiel einfach immer
end;

procedure DoCalculations(SourceList, DestList: TTestList);
var
  lTempList: TTestList;

begin
  PrePareList(SourceList, DestList: TTestList); // Damit wird in jedem Fall DestList = SourceList zurück gegeben

  if FlagAddieren then
  begin
    if DoAdding(DestList, lTempList: TTestList) then
    begin
      DestList.Free;
      DestList := lTempList;
      lTempList := nil;
    end;
  end;

  if FlagMultiplicate then
  begin
    if DoMultiplicate(DestList, lTempList: TTestList) then
    begin
      DestList.Free;
      DestList := lTempList;
      lTempList := nil;
    end;
    // Bei false wären Daten ja immer noch unverändert in DestList. Abder ein mögliches Speicherleck
  end;
end;

procedure Start;
var
  i: Integer;
  lStartList, lResultList: TTestList;
  lTest: TTest;

begin
  lStartList := TTestList.Create(true);
  try
    for i := 1 to 5 do
    begin
      lTest := TTest.Create;
      lStartList.Add(lTest);
      lTest.Value := i;
    end;

    DoCalculations(lStartList, lResultList: TTestList);

  finally
    lStartList.Free;
    lResultList.Free;
  end;
end;

So das Prinzip.

Jetzt aber die Fragen:

• Wie mache ich das sauber, so dass der Speicher sauber created und wieder gefreet wird
• Der Rechenablauf minimiert wird
• Wann ist bei der Übergabe an die procdure/function var nötig/sinnvoll
  Delphi-Quellcode:

  procedure DoCalculations(var SourceList, DestList: TTestList);

• Welche Vorteile böten sich bei
  Delphi-Quellcode:

  lTempList := DoAdding(DestList)

  . Wo findet hier sinnvollerweise das lTempList := TTestList.Create statt. In der function oder vor dem Aufruf

[scrat1979]

Antwort zu Punkt 3: den „var“-Parameter kannst du dir sparen, Objekte werden immer über Call-By-Reference (also quasi var) übergeben.

[samso]

Zitat:

Zitat von scrat1979 (Beitrag 1469254)

Antwort zu Punkt 3: den „var“-Parameter kannst du dir sparen, Objekte werden immer über Call-By-Reference (also quasi var) übergeben.

Das ist so pauschal nicht richtig. Wenn die Instanz innerhalb der Prozedur erstellt wird, muss sehr wohl mit var bzw. out gearbeitet werden.

Beispiel:

Delphi-Quellcode:

procedure PrePareList(SourceList, DestList: TTestList);
// Erstellt Liste und kopiert Werte von SourceList dort hin
var
  i: Integer;
  lTest: TTest;

begin
  DestList.Free;
  DestList := TTestList.Create(true);

  for i := 0 to SourceList.Count - 1 do
  begin
    lTest := TTest.Create;
    DestList.Add(lTest);
    lTest.Value := SourceList[i].Value;
  end;
end;

Diese Konstruktion produziert ein Memoryleak, weil DestList durch den Aufrufer nicht freigegeben werden kann. Denn die Referenz der neu erzeugten Liste wird so nicht an den Aufrufer zurückgegeben. Richtig ist folgende Konstruktion:

Delphi-Quellcode:

procedure PrePareList(SourceList: TTestList; var DestList: TTestList);
// Erstellt Liste und kopiert Werte von SourceList dort hin
var
  i: Integer;
  lTest: TTest;
begin
  DestList.Free;
  DestList := TTestList.Create(true);  // <- diese Referenz muss zurück gegeben werden

  for i := 0 to SourceList.Count - 1 do
  begin
    lTest := TTest.Create;
    DestList.Add(lTest);
    lTest.Value := SourceList[i].Value;
  end;
end;

So muss das dann komplett durchgezogen werden. Also:

Delphi-Quellcode:

function DoAdding(SourceList: TTestList; var DestList: TTestList): Boolean;
function DoMultiplicate(SourceList: TTestList; var DestList: TTestList):Boolean;

[DeddyH]

Das stimmt so nicht. Das Objekt (genauer: die Instanz) selbst wird ohne Angabe von const, var oder out als Call by Value übergeben. Wenn man ein Objekt als Konstantenparameter übergibt, kann man ihm keine andere Instanz zuweisen, aber seine Eigenschaften ändern. Ich würde aber in Routinen ohne triftigen Grund keine Instanzen erzeugen, da man sonst sehr schnell durcheinanderkommt und sich entweder Speicherlecks oder wilde Zeiger fabriziert. Stattdessen bevorzuge ich persönlich folgende Vorgehensweise:

Delphi-Quellcode:

procedure TuWas(const Src, Dest: TSomeList);
var
  i: integer;
begin
  Assert(Assigned(Src), 'Keine Quellliste übergeben');
  Assert(Assigned(Dest), 'Keine Zielliste übergeben');
  Dest.Clear;
  for i := 0 to Src.Count - 1 do
    begin
      // Nur als Beispiel
      Dest.Add(Src[i]);
    end;
end;

[edit] Mist, zu langsam [/edit]

[norwegen60]

Zunächst Danke für die schnellen Antworten

Zitat:

Zitat von DeddyH (Beitrag 1469256)

Das stimmt so nicht. Das Objekt (genauer: die Instanz) selbst wird ohne Angabe von const, var oder out als Call by Value übergeben.

Dass Objekte kein var brauchen dachte ich anfangs auch habe aber eben festgestellt, dass es unterschiedlich reagiert.
Um es sicher zu stellen:

• Wenn das Objekt in der Funktion erzeugt wird, muss ein var dazu
• Wenn man verhindern will, dass eine neue Instanz erzeugt wird (Create), kann man das mit const verhindern

Zitat:

Zitat von DeddyH (Beitrag 1469256)

Ich würde aber in Routinen ohne triftigen Grund keine Instanzen erzeugen, da man sonst sehr schnell durcheinanderkommt und sich entweder Speicherlecks oder wilde Zeiger fabriziert.

Dem stimme ich zu. Grund dafür hier mal anzufragen. Um Sicherheit zu gewinnen

Zitat:

Zitat von DeddyH (Beitrag 1469256)

[edit] Mist, zu langsam [/edit]

Das verunsichert mich etwas. Deine Vorredner haben doch was anderes gezeigt. Nämlich wie die Instanzen in der Routine erzeugt werden.

Zitat:

Zitat von samso (Beitrag 1469255)

Diese Konstruktion produziert ein Memoryleak, weil DestList durch den Aufrufer nicht freigegeben werden kann. Denn die Referenz der neu erzeugten Liste wird so nicht an den Aufrufer zurückgegeben.

Das hatte ich festgestellt. Jetzt weiß ich warum.

Letzte Frage:
Könnte Aufbau

Delphi-Quellcode:

lTempList := DoAdding(DestList)

Vorteile bieten? Was muss da beachtet werden bzw. stimmt das hier?

Delphi-Quellcode:

function PrePareList(SourceList: TTestList): TTestList;
// ------------------------------------------------------------------------------------------
// Erstellt Liste und kopiert Werte von SourceList dort hin
var
  i: Integer;
  lTest: TTest;
begin
  Result.Clear;

  for i := 0 to SourceList.Count - 1 do
  begin
    lTest := TTest.Create;
    Result.Add(lTest);
    lTest.Value := SourceList[i].Value;
  end;
end;

function DoAddition(SourceList: TTestList): TTestList;
// ------------------------------------------------------------------------------------------
// Führe rechenfunktion durch, die auch auf vorige Werte in der Liste zurückgreift. 
// Wenn SourceList und Result auf selbem Objekt liegen, wurden die vorigen Werte durch den Loop schon verändert => Zuerst zusätzliche Instanz schaffen. Oder gibt es andere Möglichkeit?
var
  i: Integer;
  lTest: TTest;
  lTempList:TTestList;
begin
  lTempList := lTempList.Create(true);
  lTempList := PrePareList(SourceList);


  for i := 0 to SourceList.Count - 1 do
  begin
    if i>0 then
      Result.Value := lTempList[i].Value + lTempList[i-1].Value
    else
      Result.Value := lTempList[i].Value;
  end;

  lTempList.Free;
end;

Procedure Start;
// ------------------------------------------------------------------------------------------
// Vorbereitung der Liste und Aufruf der Funktionen
var
  lStartList, lResultList:TTestList;
begin
  lStartList := TTestList.Create(true);
  lResultList := TTestList.Create(true);

  ...

  lResultList := PrePareList(SourceList);
  
  // Und hier mein Problem. Da die Berechnungen aufeinander aufbauen sollen, ist Result-Objekt = Übergabe-Objekt. Wenn jeder Eintrag für sich geändert wird kein Problem. 
  // Wenn die Funktion aber auf vorige Einträge zugreift, wären die schon verändert. Jetzt müsste ich in der Funktion zuerst eine Kopie erzeugen. Korrekt?

  lResultList := DoAddition(lResultList);

  ...

  lStartList.Free;
  lResultList := TTestList.Create(true);

[DeddyH]

Wo soll das Funktionsergebnis (also die Instanz) denn herkommen, wenn sie nicht innerhalb der Funktion erzeugt wird? Was spricht denn dagegen, beide Instanzen in der aufrufenden Routine zu erzeugen und als Konstanten-Parameter zu übergeben?

[norwegen60]

Zitat:

Zitat von DeddyH (Beitrag 1469264)

Wo soll das Funktionsergebnis (also die Instanz) denn herkommen, wenn sie nicht innerhalb der Funktion erzeugt wird? Was spricht denn dagegen, beide Instanzen in der aufrufenden Routine zu erzeugen und als Konstanten-Parameter zu übergeben?

Es spricht nichts dagegen. Es geht mir ums Verständnis. Und da frage ich mich, wie das Konstrukt aussehen müsste, wenn man die Liste als function zurück gibt.

Doch ein kleines Problem habe ich doch. Wie muss das dann aussehen?

Delphi-Quellcode:

procedure TuAlles(const SourList, DestList:TTestList);
begin
  TuWas1(SourceList, DestList);
  // Wie gehe ich vor, dass mit dem nächsten Aufruf die vorige DestList als SourceList übergeben wird
  TuWas2(SourceList, DestList);
end;

// Das hier funktioniert nicht mehr, da ja als const hereingegeben und damit die Zuweisung DestList := lTempList; fehl schlägt

procedure TuAlles(const SourList, DestList:TTestList);
var
  lTempList:TTestList;
begin
  PrepareDestList(SourceList, DestList);

  lTempList:=TTestList.Create;
  PrepareDestList(SourceList, lTempList);

  if TuWas1(DestList, lTempList)then
  begin
    DestList.Free;  // Jetzt muss ich die ja freigeben um danach meine neue Ergebnisse dran zu hängen
    DestList := lTempList;
    lTempList:= nil;
  end;
    
  lTempList:=TTestList.Create;
  PrepareDestList(SourceList, lTempList);

  if TuWas2(DestList, lTempList)then
  begin
    DestList.Free;
    DestList := lTempList;
    lTempList:= nil;
  end;
end;

[DeddyH]

Ich würde ohne Grund nicht an den Instanzen herumspielen, sondern nur an den enthaltenen Daten.

Delphi-Quellcode:

procedure Tuwas(sonst Src, Dest: TSomeList);
begin
  // Mit den Daten der Listen arbeiten
end;

procedure TuAlles;
var
  List1: TSomeList;
  List2: TSomeList;
  List3: TSomeList;
begin
  List3 := nil;
  List2 := nil;
  List1 := TSomeList.Create;
  try
    List2 := TSomeList.Create;
    TuWas(List1, List2);
    List3 := TSomeList.Create;
    TuWas(List2, List3);
  finally
    List1.Free;
    List2.Free;
    List3.Free;
  end;
end;

[norwegen60]

In der Art hatte ich es ursprünglich. Da die Berechnungen zum Teil aufwändig sind, führe ich sie nur noch aus, wenn sie auch benötigt wird

Delphi-Quellcode:

  if FlagTuWas1 then
    TuWas1(List1, List2);

  if FlagTuWas2 then
    TuWas2(List2, List3);

was so dann natürlich nicht geht. Wenn TuWas1 nicht ausgeführt würde müsste ich List1 statt List2 in TuWas2 eingeben

Und der Ansatz

Delphi-Quellcode:

var
  lTempList:TTempList;
begin
  PrepareDestList(SourceList, DestList);

  lTempList:= TAbsBaseList.Create(true);
  try
    // -------------------------------------------------------------------------------------------------------------------------------------
    if FlagTuWas1 then
      if TuWas1(DestList, lTempList) then     // Wenn erfolgreich ausgeführt 
        PrepareDestList(lTempList, DestList); // Ergebnis in Weitergabe-/Rückgabeliste kopieren

    // -------------------------------------------------------------------------------------------------------------------------------------
    if FlagTuWas2 then
      if TuWas2(DestList, lTempList) then
        PrepareDestList(lTempList, DestList); // Ergebnis in Weitergabe-/Rückgabeliste kopieren
  finally
    lTempList.Free;
  end;
end;

erscheint mir aufwändig, da das neue Ergbnis immer wieder in lTempList kopiert wird um es dann wieder dem nächsten Aufruf übergeben zu können

[DeddyH]

Benötigst Du denn wirklich mehrere Instanzen? Was genau hast Du eigentlich vor?

[norwegen60]

Ich weiß keinen Weg, wie ich um 3 Instanzen rum komme
Was ich machen muss sind diverse Rechenschritte Wie z.B.

1. Korrektur um einen zu berechnenden Wert
2. Averaging über die X rechts und links liegenden Werte in der Liste
3. Ableitung nach Savitzky/Golay

Instanz 1 enthält die Ausgangsdaten die nicht verändert werden sollen
Instanz 2 enthält die zuletzt berechneten Werte
Instanz 3 enthält die aktuell berechneten Werte

Bei 1. ist es keine Problem zu sagen Instanz2[i].Value := Instanz2[i].Value + 6 (hier reichen 2 Instanzen)
Bei 2. und 3. gibt es aber das Problem, dass ich z.B. sage Instanz3[i].Value := (Instanz2[i-1].Value + Instanz2[i].Value + Instanz2[i+1].Value)/3 (Mittelwert über drei Werte)

Würde ich nur mit Instanz2 arbeiten, wäre der Wert Instanz2[i-1] im vorigen Loop schon geändert.
Instanz1 funktioniert auch nicht, da Instanz2 in Berechnung 1. schon geändert wurde somit auf Instanz2 weitergemachet werden muss
Ich hoffe es ist jetzt etwas klarer

[Stevie]

Und deshalb mag ich interface basierte Collections so - da braucht man sich um so Zeugs gar nicht kümmern:

Delphi-Quellcode:

{$APPTYPE CONSOLE}

uses
  Spring.Collections,
  SysUtils;

type
  TTest = class
  private
    FValue: Double;
  public
    property Value: Double read FValue write FValue;
  end;

  ITestList = IList<TTest>;

function CopyTestList(const SourceList: ITestList): ITestList;
var
  i: Integer;
  lTest: TTest;
begin
  Result := TCollections.CreateObjectList<TTest>(True);

  for i := 0 to SourceList.Count - 1 do
  begin
    lTest := TTest.Create;
    lTest.Value := SourceList[i].Value;
    Result.Add(lTest);
  end;
end;

function DoAdding(const SourceList: ITestList): ITestList;
var
  i: Integer;
begin
  Result := CopyTestList(SourceList);

  for i := 0 to Result.Count - 1 do
    Result[i].Value := Result[i].Value + 5;
end;

function DoMultiplicate(const SourceList: ITestList): ITestList;
var
  i: Integer;
begin
  Result := CopyTestList(SourceList);

  for i := 0 to Result.Count - 1 do
    Result[i].Value := Result[i].Value * 5;
end;

var
  FlagAddieren: Boolean;
  FlagMultiplicate: Boolean;

function DoCalculations(const SourceList: ITestList): ITestList;
var
  temp: ITestList;
begin
  temp := SourceList;

  if FlagAddieren then
    temp := DoAdding(temp);

  if FlagMultiplicate then
    temp := DoMultiplicate(temp);

  Result := temp;
end;

procedure Start;
var
  i: Integer;
  lStartList, lResultList: ITestList;
  lTest: TTest;
begin
  lStartList := TCollections.CreateObjectList<TTest>(true);

  for i := 1 to 5 do
  begin
    lTest := TTest.Create;
    lStartList.Add(lTest);
    lTest.Value := i;
  end;

  FlagAddieren := True;
  FlagMultiplicate := True;
  lResultList := DoCalculations(lStartList);

  for lTest in lResultList do
    Writeln(lTest.Value.ToString);
end;

begin
  try
    Start;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

[norwegen60]

Zitat:

Zitat von Stevie (Beitrag 1469306)

Und deshalb mag ich interface basierte Collections so - da braucht man sich um so Zeugs gar nicht kümmern:

WOW, jetzt sind wir ganz nah dort wie ich es mir mit functions vorgestellt habe. Einziges Problem. Ich habe noch nie mit Interfaces gearbeitet. Eigenlich sieht es ja sehr ähnlich aus.

Kurz zusammengafasst:

• lStartList wird in Start erzeugt
• Alle anderen Listen werden in CopyTestList erzeugt
• Aber wer kümmert sich um das Free. Denn wenn ich durch bin, sind drei Listen erzeugt, arbeiten tu ich aber letztlich nur mit lStartList und lResultList. Und wenn ich mit der fertig bin, was mach ich mit der? Auch lResultList.Free; Und die Elemente in der lResultList sind dann auch all freigegeben? Und was ist mit der Liste, die in DoAdding erzeugt wurde?

Normale TObjectList funktionieren ja auch ohne Free. Ich muss mich dann nur nicht wundern wenn irgenwann der Speicher voll ist. Wer also kümmert sich hier um das Free?

[TurboMagic]

Das ist doch genau der Gag an Interfaces in Delphi: Free ist nicht nötig.
Die sind referenzgezählt und wenn keiner mehr auf die InterfaceReferenz
zeigt geht die auf 0 und das Interface wird freigegeben.

Nur eines darf man nicht tun: das Interface als Objektreferenz erzeugen und
sowohl als Interface- und Objektreferenz benutzen und dann die Objektreferenz
mit Free freigeben. Das knallt dann, weil man dem Interface dadurch hinter
dem Rücken das Ding freigibt.

Also wenn Interface, dann immer nur über Interface Referenzen benutzen!

Grüße
TurboMagic

[norwegen60]

Zitat:

Zitat von TurboMagic (Beitrag 1469328)

Nur eines darf man nicht tun: das Interface als Objektreferenz erzeugen und sowohl als Interface- und Objektreferenz benutzen und dann die Objektreferenz mit Free freigeben.

Meinst du sowas:

Delphi-Quellcode:

type
  ITestList = IList<TTest>;

function SoJa:ITestList;
begin
  Result := TCollections.CreateObjectList<TTest>(True);
end;

function SoNie:ITestList;
begin
  Result := ITestList.Create;
end;

Procedure Start;
var
  lTest:ITestList;
begin
  lTest := SoNie;
  lTest.Free;

  // So was darf man? Ist aber unnötig, da beim Verlassen von Start lTest sowieso freigegeben wird
  lTest := SoJa;
  lTest.Free;
end;

[DeddyH]

Vergiss das Free einfach im Zusammenhang mit referenzgezählten Interfaces. Die Instanz wird ganz automatisch freigegeben, wenn der letzte Verweis auf sie ungültig wird, sei es, dass die Variable aus dem Scope läuft oder explizit auf nil gesetzt wird.

[himitsu]

Beides nicht .... KEIN Free,

Ob man aber das letzte

Delphi-Quellcode:

lTest := nil;

macht oder nicht, das ist egal, aber entspricht deinen Kommentaren.
Und selbst das Erste wäre nicht nötig.

[Stevie]

Interfaces haben kein

Delphi-Quellcode:

Create

oder

Delphi-Quellcode:

Free

, damit erübrigt sich die Frage ob man das machen sollte oder nicht.

Die Spring4D Collections sind so designed, dass du niemals mit den implementierenden Klassen in Berührung kommst, du erzeugst sie alle über die entsprechenden Methoden auf

Delphi-Quellcode:

TCollections

aus der Unit

Delphi-Quellcode:

Spring.Collections

. Niemals z.B.

Delphi-Quellcode:

Spring.Collections.Lists

ins uses und selbst

Delphi-Quellcode:

TList<TTest>.Create

machen.

[mytbo]

Zitat:

Zitat von Stevie (Beitrag 1469350)

Die Spring4D Collections sind so designed, dass du niemals mit den implementierenden Klassen in Berührung kommst, du erzeugst sie alle über die entsprechenden Methoden auf

Delphi-Quellcode:

TCollections

aus der Unit

Delphi-Quellcode:

Spring.Collections

. Niemals z.B.

Delphi-Quellcode:

Spring.Collections.Lists

ins uses und selbst

Delphi-Quellcode:

TList<TTest>.Create

machen.

Ich verwende seit Kurzem Spring4D und DSharp. Habe bis jetzt gedacht, dass ich alles an Infos gegoogelt habe. Und ganz zufällig erfahre ich hier, dass ich wohl auf das falsche DSharp Beispiel "Sample7.Main" gesetzt habe. :roll:

Bis bald...
Thomas

[Stevie]

Zitat:

Zitat von mytbo (Beitrag 1469362)

Und ganz zufällig erfahre ich hier, dass ich wohl auf das falsche DSharp Beispiel "Sample7.Main" gesetzt habe. :roll:

Touché, stammt vermutlich noch aus der Zeit, als DSharp selber noch interface basierte Collections hatte und kompiliert derzeit nicht mal - von daher jo, bestimmt das falsche Beispiel.
Aber wenn es sonst außer nem ironischen Seitenhieb nichts zu klagen gibt, dann bin ich ja froh :mrgreen: