class methode an Klassenreferenz aufrufen

[TurboMagic]

Hallo,

gegeben ist Code mit dieser Struktur:

Delphi-Quellcode:

type
  TDECHashClass = class of TDECHash;

  TDECHash = class
  public
    class function IsPasswordHash: Boolean; 
  end;

  TDECPasswordHash = class(TDECHash)
  public
    class function GetMaxSaltLength:UInt16; virtual; abstract;
  end;

  THash_BCrypt = class(TDECPasswordHash)
  public
    class function GetMaxSaltLength:UInt16; override;
  end;

[..]

var
  Hash: TDECHashClass;
begin
  // beschaffe die Klassenreferenz der ausgewählten Klasse aus einer
  // Liste aller registrierten Klassen
  Hash := ClassRegistration.GetHashClass('BCrypt');

  // Hier knallt es:
  if Hash.IsPasswordHash and (TDECPasswordHash(Hash).GetMaxSaltLength > 0) then

Mir ist klar warum es knallt. TDECPasswordHash implementiert die GetMaxSaltLength
Klassenmethode ja nicht, sondern erst die davon erbende THash_BCrypt.
Nur: wie an diese rann kommen, wenn man nur eine TDECHashClass Klassenreferenz
von der BCrypt Klasse aus der Registrierungsliste bekommt?

Grüße
TurboMagic

[himitsu]

TDECPasswordHash ein Instanz-Zeiger (class), aber du brauchst für diesen Cast ebenfalls einen Klassen-Zeiger (class of).

Also nicht TDECPasswordHash sondern ein TDECPasswordHashClass (class of TDECPasswordHash).



Bisschen böse, wenn der Compiler hier nicht meckert.




Vielleicht ließe sich hier auch mit Attributen spielen?

Delphi-Quellcode:

type
  TDECHashClass = class of TDECHash;

  TDECHash = class
  public
    class function IsPasswordHash: Boolean;
  end;

  //[DECMaxSaltLength(-1)]
  TDECPasswordHash = class(TDECHash)
  public
    class function GetMaxSaltLength:UInt16; // hier, oder in der Basisklasse (ohne Cast), das erste Attribut nehmen
  end;

  [DECMaxSaltLength(16)]  // oder mit einem generellen Parameter-Attribut [DECParam('MaxSaltLength', 16)] aka DECParamAttribute
  THash_BCrypt = class(TDECPasswordHash)
  public
  end;

[TurboMagic]

Hallo,

danke für die schnelle Antwort.
Muss mir das in dem Licht mit dem Class Of nochmal anschauen.

Es geht um eine nötige Erweiterung eines der Demo-Programme der DEC...

Grüße
TurboMagic

[himitsu]

Nenn deine Variable HashClass, dann fällt es besser auf, dass es nicht

Delphi-Quellcode:

TDECPasswordHash(HashClass)

sondern

Delphi-Quellcode:

TDECPasswordHashClass(HashClass)

sein müsste. :angle:

[mytbo]

Delphi-Quellcode:

var
  hashClass: TDECHashClass;
begin
  hashClass := ClassRegistration.GetHashClass('BCrypt');
  with hashClass.Create as hashClass do
  try
    if IsPasswordHash
      and (GetMaxSaltLength > 0) then
    begin
      ...
    end;
  finally
    Free;
  end;
end;

Jetzt warte ich darauf, dass ich wegen des "withs" gegrillt werde. :wink:

Bis bald...
Thomas

[himitsu]

Dann wäre das mit der Class-Method aber auch bissl obsolete. :stupid:

[hoika]

Hallo,
der Grill ist angezündet.

KOMM HER ;)

[mytbo]

Zitat:

Zitat von himitsu (Beitrag 1501933)

Dann wäre das mit der Class-Method aber auch bissl obsolete. :stupid:

Da habe ich nicht aufgepasst und "class" überlesen. Suche schon mehrere Stunden in einer externen Library einen hartnäckigen Fehler und wollte mich mal kurz ablenken. Dann mal mit Rtti:

Delphi-Quellcode:

var
  hashClass: TDECHashClass;
  rttiType: TRttiType;
  rttiMethod: TRttiMethod;
  maxSaltLengthValue: TValue;
begin
  hashClass := ClassRegistration.GetHashClass('BCrypt');
  if (hashClass <> Nil)
    and hashClass.IsPasswordHash then
  begin
    rttiType := TRttiContext.Create.GetType(hashClass);
    if rttiType <> Nil then
    begin
      rttiMethod := rttiType.GetMethod('GetMaxSaltLength');
      if (rttiMethod <> Nil)
        and rttiMethod.IsClassMethod then
      begin
        maxSaltLengthValue := rttiMethod.Invoke(hashClass, []);
      end;
    end;

Und jetzt Feierabend.

Bis bald...
Thomas

[gmc616]

OT:

Zitat:

Jetzt warte ich darauf, dass ich wegen des "withs" gegrillt werde.

Jeder sollte für das Verwenden von "with" gegrillt werden.:twisted:

Zitat:

...der Grill ist angezündet.

Ich habe Kohle am Start.:zwinker:

[haentschman]

...ich brings Bier mit. :cheers:

[TurboMagic]

Ihr könnt ja gerne grillen, ich hab' dafür den Bug gefixt.
Himitsu's Hinweis war richtig! Das hatte ich doch glatt übersehen.

Ist halt die Frage ob der Compiler das erkennen könnte/müsste.

[Uwe Raabe]

Zitat:

Zitat von TurboMagic (Beitrag 1501941)

Ist halt die Frage ob der Compiler das erkennen könnte/müsste.

Bei einem Hardcast ist der Compilers blind - soll er ja dann auch sein.

[himitsu]

Hier könnte er aber "mindestens" eine Warnung rausbringen, wenn nicht gar direkt einen Fehler werfen, selbst bei einem harten Cast, da sowas eh nie funktionieren kann.

(welches man über einen Cast mit untypisiertem Pointer umgehen könnte, wenn man wirklich mal sowas machen wöllte)


casts von/zu/zwischen Object/Class/Interface/String können ja nie funktionieren.
Vor einer Weile hatten wir den Fall, dass Jemand ein "TEdit" in einen Strind casten wollte (

Delphi-Quellcode:

... := string(Edit1);

), um den Text zu bekommen, was natürlich knallte. (OK, hier hätte der Compiler "schlau" sein und .ToString nutzen können, was aber auch schwachsinn wäre, weil es fast niegendwo implementiert ist und TObject nur den Klassennamen rausgibt)

[Uwe Raabe]

Zitat:

Zitat von himitsu (Beitrag 1501954)

Hier könnte er aber "mindestens" eine Warnung rausbringen, wenn nicht gar direkt einen Fehler werfen, selbst bei einem harten Cast, da sowas eh nie funktionieren kann.

Kannst du ja haben. Unter Hinweise und Warnungen: Unsichere Typumwandlung.

[Stevie]

Du musst auch eine Klassenreferenz auf eine andere Klassenreferenz casten

Delphi-Quellcode:

type
  TDECHashClass = class of TDECHash;
  TDECPasswordHashClass = class of TDECPasswordHash;

  TDECHash = class
  public
    class function IsPasswordHash: Boolean;
  end;

  TDECPasswordHash = class(TDECHash)
  public
    class function GetMaxSaltLength:UInt16; virtual; abstract;
  end;

  THash_BCrypt = class(TDECPasswordHash)
  public
    class function GetMaxSaltLength:UInt16; override;
  end;

[..]

var
  Hash: TDECHashClass;
begin
  // beschaffe die Klassenreferenz der ausgewählten Klasse aus einer
  // Liste aller registrierten Klassen
  Hash := ClassRegistration.GetHashClass('BCrypt');

  // Hier knallt es:
  if Hash.IsPasswordHash and (TDECPasswordHashClass(Hash).GetMaxSaltLength > 0) then