Hilfe zu IThumbnailProvider

[Benmik]

Ich würde gern ausprobieren, über IThumbnailProvider Miniaturansichten von JPG zu erstellen. Das gestaltet sich aber schwierig, im Internet findet man für Delphi kaum etwas. Bei Stackoverflow habe ich zwei Hinweise gefunden:
Hier folgenden Code:

Delphi-Quellcode:

function LoadBitmapWithShellExtension(const ADllFileName: UnicodeString; const ACLSID: TCLSID;
  const AFileName: UnicodeString; ASize: Integer; out AAlpha: WTS_ALPHATYPE): HBITMAP;
type
  TDllGetClassObject = function(const CLSID, IID: TGUID; out Obj): HRESULT; stdcall;
var
  DllModule: HMODULE;
  DllGetClassObject: TDllGetClassObject;
  ClassFactory: IClassFactory;
  ThumbnailProvider: IThumbnailProvider;
  InitializeWithFile: IInitializeWithFile;
  PersistFile: IPersistFile;
begin
  DllModule := LoadLibraryW(PWideChar(ADllFileName));
  if DllModule = 0 then RaiseLastOSError;
  try
    @DllGetClassObject := GetProcAddress(DllModule, 'DllGetClassObject');
    if not Assigned(DllGetClassObject) then
      RaiseLastOSError;
    OleCheck(DllGetClassObject(ACLSID, IClassFactory, ClassFactory));
    try
      OleCheck(ClassFactory.CreateInstance(nil, IThumbnailProvider, ThumbnailProvider));
      try
        if Succeeded(ThumbnailProvider.QueryInterface(IInitializeWithFile, InitializeWithFile)) then
          try
            OleCheck(InitializeWithFile.Initialize(PWideChar(AFileName), STGM_READ));
          finally
            InitializeWithFile := nil;
          end
        else
          if Succeeded(ThumbnailProvider.QueryInterface(IPersistFile, PersistFile)) then
            try
              OleCheck(PersistFile.Load(PWideChar(AFileName), STGM_READ));
            finally
              PersistFile := nil;
            end
          else
            raise Exception.Create('Cannot initialize handler');

        OleCheck(ThumbnailProvider.GetThumbnail(ASize, Result, AAlpha));
      finally
        ThumbnailProvider := nil;
      end;
    finally
      ClassFactory := nil;
    end;
  finally
    FreeLibrary(DllModule);
  end;
end;

Es war mühsam, den ans Laufen zu bringen; ich habe IThumbnailProvider in Delphi nirgenwo gefunden und musste die Deklaration aus einer anderen Fundstelle einfügen. Letztlich bin ich dann bei

Delphi-Quellcode:

DllGetClassObject(ACLSID, IClassFactory, ClassFactory)

hängengeblieben, weil mir nicht klar ist, was für

Delphi-Quellcode:

ACLSID

eingesetzt werden muss. Ich habe dann auch nicht versucht, das herauszuknobeln, weil ich bei

Delphi-Quellcode:

System.Win.ComServ.DllGetClassObject

gelesen habe: Do not call DllGetClassObject directly. DllGetClassObject is exported by all ActiveX server DLLs, and it is called internally by the operating system. When a user calls CoGetClassObject (or CoCreateInstance, which internally calls CoGetClassObject) to obtain a class factory for an ActiveX object, the OLE engine loads the ActiveX server DLL into memory and calls its DllGetClassObject function. Die Umsetzung von

Delphi-Quellcode:

CoCreateInstance

ist mir leider auch nicht klar.

Die zweite Stelle ist von Remy Lebeau. Hier gefällt mir 1) mit

Delphi-Quellcode:

IInitializeWithStream

. Das umzusetzen habe ich aber auch keine Chance.

Hat vielleicht jemand den richtigen Code in der Schublade?

[himitsu]

Ich würde es erstmal mit {B196B28F-BAB4-101A-B69C-00AA00341D07} probieren, also der GUID von IClassFactory,
oder vermutlich {50d9450f-2a80-4f08-93b9-2eb526477d1b} Recipe Thumbnail Handler, aus der Microsoft-Demo :gruebel:
https://github.com/microsoft/Windows...ovider/Dll.cpp
oder {cf572d73-d6e5-4d45-acad-f18f4f76656f} ... schau mal, was zu IThumbnailProvider in HKEY_CLASSES_ROOT\CLSID gefunden wird.

Du mußt einen Provider finden, welcher für deinen Dateityp eine Preview bietet.
Als Erstes hätte ich nun Hoffnung, dass Diese auch bei den jeweiligen Dateitypen eingetragen ist.
Für png, jpg und pdf hier auf die Schnelle zwar ein paar GUID darin gefunden, aber Nichts, was scheinbar mit Thumbnails zu tun hat.



Da steht doch beim Hersteller beschrieben, wie das Interface aussieht? (ok, hier mal nur implizit und nicht direkt mit einer Implementation)
https://learn.microsoft.com/en-us/wi...mbnailprovider

Der Name des Interfaces ist egal, aber der heißt ja "IThumbnailProvider"
und dann findet sich dort die nötige GUID, der Vorfahre und die Deklaration der einzigen Methode.


Alternativ lädt man sich das WinSDK/PSDK/... runter, denn unten findest du die Headerdatei, aus der du dir die C++-Deklaration kopieren und dann nach Delphi übersetzen kannst. (alternativ im Internet nach diesem Dateinamen suchen ... PS: Microsoft hat Vieles auf Github hochgeladen)



[edit]
"Vieles" ist gut ... da sind inzwischen schon 5200 Repos :shock:

[Benmik]

Vielen Dank, Himitsu. Das Ganze ist am Rand meiner Kenntnisse, bzw. eigentlich darüber hinaus. Zudem bin ich mittlerweile im Zweifel, ob mir IThumbnailProvider eigentlich das bringt, was ich brauche, nämlich eine Miniaturansicht des JPG-Inhalts. Diese ganzen Thumbnailsachen scheinen nämlich einen quadratischen Thumbnail zurückzugeben, was etwas anderes ist.

Ich habe jetzt - nicht zuletzt aus didaktischen und auch sportlichen Gründen - intensiv weiter gesucht und ein paar Stellen gefunden, die relativ weit führen, aber eben nie einen funktionierenden Code liefern. Ich habe das Gefühl, wenn ich ein bisschen mehr in diesem Stoff stünde, dann wäre es von diesen Beispielen aus gar nicht so schwer, aber hingekriegt habe ich es einfach nicht.

Natürlich als Erstes die bereits erwähnten Vorschläge von Remy Lebeau. Nur halt: Wie umsetzen?

Hier hat Postscripter in einem russischen Forum in #9 ein Gerüst angegeben und in #10 offenbar auch fertiggestellt. Leider komme ich an test.rar nicht heran, selbst auf eine Anmeldung hin erfolgte keine Antwort.

Hier gibt es ebenfalls eine Anleitung, die ich aber auch nicht ans Laufen gebracht habe. Die dort angegebene

Delphi-Quellcode:

function GetPreviewHandlerCLSID(const AFileName: string): string;

funktioniert auch nicht. Ein Hinweis darauf, warum nicht, findet sich in der mit Vergnügen zu lesenden Frage von Ian Boyd, wie man den richtigen IPreviewHandler erzeugt. Der entscheidende Hinweis wird ganz am Schluss von Simon Mourier gegeben ("There are today some files that don't have a preview handler at all (.txt and all image types like .png, .jpg or the modern .heic, .webp, etc.)."). Tatsächlich habe ich einfach zu Fuß die Registry durchsucht, und in der Tat gab es unter HKEY_CLASSES_ROOT\jpegfile\ShellEx\ den genannten Schlüssel {e357fccd-a995-4576-b01f-234630154e96} mit der GUID {C7657C4A-9F68-40fa-A4DF-96BC08EB3551} als Wert. Den kannte ich schon von Microsoft, es handelt sich um CLSID_PhotoThumbnailProvider.

Ich habe mich erstmal an Postscripter gehalten und die beiden Interfaces als Klasse implementiert. Warum man die beiden

Delphi-Quellcode:

Initialize

umbiegen muss -> keine Ahnung, Postscriper selbst schreibt "извращенцы", was "Perverse!" heißt. Ein paar Deklarationen habe ich eingefügt, auch wenn sie in den referenzierten Units enthalten waren, da die Units nicht immer dieselbe Deklaration hatten und auch, um unabhängig zu sein. Die Prozedur läuft auch durch, jedoch hat das Bitmap eine Breite/Länge von 0, obwohl mir das Handle plausibel aussieht. Allerdings habe ich auch keine Ahnung, womit ich die Aufrufe von

Delphi-Quellcode:

GetThumbnail

und

Delphi-Quellcode:

Initialize_WS

eigentlich füllen soll, das sind doch API-Aufrufe?! Postscripter hat sie mit

Delphi-Quellcode:

Beep

und

Delphi-Quellcode:

Showmessage('Funktioniert!'

gefüllt; Endgültiges steht wohl im test.rar, das ich ja nicht habe.

Es ist ja klar, dass ich da herumdoktere, ohne mehr als eine Halbahnung zu haben, was ich da eigentlich tue. Wahrscheinlich kann jemand von den alten Hasen da Ordnung ins Chaos bringen.
(Der Versuch,

Delphi-Quellcode:

FPreviewHandler := CreateComObject

statt

Delphi-Quellcode:

TComObjectFactory

zu benutzen und damit

Delphi-Quellcode:

QueryInterface

durchzuführen, scheitert übrigens an "Interface not supported".)

Delphi-Quellcode:

uses
  ...
  ComServ,Winapi.ActiveX, ComObj, Winapi.ShlObj, Winapi.PropSys;

type
  {$EXTERNALSYM WTS_ALPHATYPE}
  WTS_ALPHATYPE = (
    WTSAT_UNKNOWN = 0,
    WTSAT_RGB = 1,
    WTSAT_ARGB = 2
  );

const
  {$EXTERNALSYM SID_IThumbnailProvider}
  SID_IThumbnailProvider    = '{e357fccd-a995-4576-b01f-234630154e96}';
  SID_IInitializeWithStream = '{b824b49d-22ac-4161-ac8a-9916e8fa3f7f}';
  SID_IInitializeWithFile   = '{b7d14566-0509-4cce-a71f-0a554233bd9b}';

  type
  IThumbnailProvider = interface(IUnknown)
    [SID_IThumbnailProvider]
    function GetThumbnail(cx: UINT; var phbmp: HBITMAP; var Flags: DWORD): HResult; stdcall;
  end;

  IInitializeWithFile = interface(IUnknown)
    [SID_IInitializeWithFile]
    function Initialize(pszFilePath: PWideChar; grfMode: DWORD): HRESULT; stdcall;
  end;

  IInitializeWithStream = interface(IUnknown)
    [SID_IInitializeWithStream]
    function Initialize(const pstream: IStream; grfMode: DWORD): HRESULT; stdcall;
  end;

  TThumbnailProvider = class(TComObject, IThumbnailProvider, IInitializeWithStream, IInitializeWithFile)
  private
  protected
    function GetThumbnail(cx: UINT; var phbmp: HBITMAP; var Flags: DWORD): HResult; stdcall;
    function IInitializeWithFile.Initialize = Initialize_WF; // извращенцы
    function IInitializeWithStream.Initialize = Initialize_WS;
    function Initialize_WF(pszFilePath: PWideChar; grfMode: DWORD): HResult; stdcall;
    function Initialize_WS(const pstream: IStream; grfMode: DWORD): HResult; stdcall;
  end;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  function  LoadPreviewHandler(const FileName: string):HBitmap;
  function  ErstelleMiniatur(const FileName: string; BMPHandel:HBitmap):HBitmap;
  function  GetPreviewHandlerCLSID(const AFileName: string): string;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  BMP:TBitmap;
begin
  BMP := TBitmap.Create(256,256);
  Try
    BMP.Handle := ErstelleMiniatur('C:\Temp\7IV06423.JPG',BMP.Handle);
  Finally
    BMP.Free;
  end;
end;

function  ErstelleMiniatur(const FileName: string; BMPHandle:HBitmap):HBitmap;
var
  LPreviewGUID          : TGUID;
  LInitializeWithFile   : IInitializeWithFile;
  LInitializeWithStream : IInitializeWithStream;
  LInitializeWithItem   : IInitializeWithItem;
  LIStream              : IStream;
  LShellItem            : IShellItem;
  FPreviewHandler : IPreviewHandler;
  FFileStream:TFileStream;
  TP:IThumbnailProvider;
  Alpha:WTS_ALPHATYPE;
  Alpha2:Cardinal;
const
  CLSID_PhotoThumbnailProvider = '{C7657C4A-9F68-40fa-A4DF-96BC08EB3551}';
begin
  Result := BMPHandle;
  LPreviewGUID:= StringToGUID('{098f2470-bae0-11cd-b579-08002b30bfeb}');
  LPreviewGUID:= StringToGUID(SID_IThumbnailProvider);
  LPreviewGUID:= StringToGUID(CLSID_PhotoThumbnailProvider);
  TComObjectFactory.Create(ComServer, TThumbnailProvider, LPreviewGUID, 'Miniatur', 'Miniatur', ciSingleInstance, tmSingle);
//  FPreviewHandler := CreateComObject(LPreviewGUID) As IPreviewHandler;
//  if (FPreviewHandler = nil) then
//    exit;
  TP := TThumbnailProvider.Create;
  If TP.QueryInterface(IInitializeWithStream, LInitializeWithStream) = S_OK then begin
    FFileStream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
    LIStream := TStreamAdapter.Create(FFileStream, soOwned) as IStream;
    LInitializeWithStream.Initialize(LIStream, STGM_READ);
    TP.GetThumbnail(256,Result,Alpha2);
    Alpha := WTS_ALPHATYPE(Alpha2);
    TP.Free;
  end;
end;

function TThumbnailProvider.GetThumbnail(cx: UINT; var phbmp: HBITMAP; var Flags: DWORD): HResult;
begin

end;

function TThumbnailProvider.Initialize_WF(pszFilePath: PWideChar; grfMode: DWORD): HResult;
begin

end;

function TThumbnailProvider.Initialize_WS(const pstream: IStream; grfMode: DWORD): HResult;
begin

end;

[striderx]

Ich mache das (m. E. wesentlich einfacher) mit GDI+:

Delphi-Quellcode:

function GDIPMakeThumbnail(sSourceFile, sTargetFile:  String;
                           AWidth, AHeight:  Word):  Boolean;

var
  BM:            tBitmap;
  GR:            tGPGraphics;
  GDPImage:      TGPImage;
  GDPThumbnail:  TGPImage;
  H:             Single;
  R1:            Single;
  R2:            Single;
  W:             Single;

begin
  Result := False;
  {............................................................................}
  if not tFile.Exists(sSourceFile) then Exit;
  {............................................................................}
  if (sTargetFile = '') or (sTargetFile = sSourceFile) then Exit;
  {............................................................................}
  if (AWidth < 10) or (AHeight < 10) then Exit;
  {............................................................................}
  BM        := tBitmap.Create;
  BM.Width  := AWidth;
  BM.Height := AHeight;
  GR        := tGPGraphics.Create(BM.Canvas.Handle);
  GDPImage  := TGPImage.Create(sSourceFile);
  {............................................................................}
  R1 := AWidth / AHeight;
  H  := GDPImage.GetHeight;
  W  := GDPImage.GetWidth;
  if (H = 0) or (W = 0) then Exit;
  {............................................................................}
  R2 := W / H;
  if R1 > R2 then begin
     W := AHeight * R2;
     H := AHeight;
  end
  else begin
     W := AWidth;
     H := AWidth / R2;
  end;
  {............................................................................}
  GDPThumbnail := GDPImage.GetThumbnailImage(Round(W), Round(H), nil, nil);
  GR.DrawImage(GDPThumbnail, MakeRect((AWidth - W) / 2, (AHeight - H) / 2, W, H));
  try
    BM.SaveToFile(sTargetFile);
    Result := True
  except
    ShowMsg('Fehler beim Speichern der Thumbnail-Datei', ' Fehler', mb_OK,
            mb_IconError);
  end;
  {............................................................................}
  GR.Free;
  GDPImage.Free;
  GDPThumbnail.Free;
  BM.Free;
end;

[himitsu]

"Diese" Thumbnails sind nunmal vorwiegend für die Vorschau im Explorer und dort sind die Icons/Images nunmal Quadrate.

[mytbo]

Zitat:

Zitat von Benmik (Beitrag 1514318)

Ich würde gern ausprobieren, über IThumbnailProvider Miniaturansichten von JPG zu erstellen.

Ich habe deinen Thread nur kurz überflogen. Dieser Beitrag (Beispiel ganz unten) aus dem DevExpress Support Center könnte vielleicht etwas für dich sein.

Bis bald...
Thomas

[Benmik]

Zitat:

Zitat von striderx (Beitrag 1514402)

Ich mache das (m. E. wesentlich einfacher) mit GDI+:

GDI+ hatte ich gar nicht auf dem Schirm, obwohl ich das schon für das verlustfreie Drehen einsetze.
Welche GDI+-Unit verwendest du denn? Anscheinend nicht die von Erik van Bilsen.

@Himitsu: Ja, das habe ich ein bisschen spät bemerkt. Allerdings ging es mir dann immer mehr um den "sportlichen" Aspekt, ich wollte das Ganze zumindest einmal ans Laufen bringen und dabei auch noch verstehen.

@mytbo: Vielen Dank. Eine Eigenart dieser reinen Thumbnail-Prozessoren ist, dass sie bei JPG-Dateien nachschauen, ob es ein Thumbnail gibt und dann verwenden sie das. Für größere Miniaturbilder ist das von der Qualität her nicht akzeptabel. Meine gegenwärtige Lösung arbeitet mit IExtractImage aus Winapi.ShlObj und das funktioniert gut. Ich wollte unter anderem aber auch mal sehen, ob die neueren Methoden vielleicht schneller sind.

[himitsu]

Vielleicht ist es einfacher, sich über IShellFolder und IShellIcon oder IExtractIcon das Vorschau-Icon zu besorgen?

[venice2]

https://rmklever.com/?p=266

[striderx]

Zitat:

Zitat von Benmik (Beitrag 1514406)

Welche GDI+-Unit verwendest du denn? Anscheinend nicht die von Erik van Bilsen.

Das ist die von Prodigy.

[Benmik]

@Himitsu: Mein Fokus hat sich im Laufe der Recherche etwas verschoben, seit klar ist, dass IThumbnailProvider quadratische Bilder zurückliefert. Ich würde mittlerweile aus sportlichen Gründen gern wissen, wie man diese Sachen mit COM-Objekten und Factories bei IThumbnailProvider richtig handhabt und warum mein Code nicht funktioniert. Vielleicht erbarmt sich ja irgendwann einmal ein Wissender, der hier vorbeikommt, und erklärt es mir.

@striderx: Danke! Nie von gehört.

@venice2: Super-Link! Zum Lernen offenbar genau das Richtige!

[Benmik]

Ich vermute mal, dass wegen der Seltenheit des Suchwortes "IThumbnailProvider" im Laufe der Zeit noch so einige Leute über Google hierher kommen werden, von denen eine Reihe auch an der Extraktion von Vorschaubildern für ihre JPG interessiert sind.

Daher möchte ich hier erwähnen, welche Lösung ich für mich gefunden habe. Und zwar betten immer mehr Kameras in die JPG neben einem kleinen Thumbnail (APP1) auch noch ein weiteres großes Bild im Full-HD-Format ein, also 1920 x 1080 Pixel. Dies geschieht mittels MPF (Multi-Picture Format), einem Zusatz zur EXIF-Spezifikation, das im APP2 gespeichert wird. (Sogar die kleine Panasonic TZ101 tut das). Bei deutlich größeren Vorschaubildern als 120 Pixel Breite ist die Hochskalierung des eingebetteten Thumbnails keine Option, eine Vorschau größer als 1920 Pixel wird es aber wohl kaum geben. Es bietet sich also an, dieses Bild zu extrahieren und schlicht mit

Delphi-Quellcode:

StretchDraw

in der gewünschten Größe zu zeichnen.

Meine JPG haben mittlerweile locker 20 MB, während die MPF-Bilder meist zwischen 300 und 900 kB groß sind. Das Einlesen von so großen JPG und vor allem die Dekomprimierung verbrauchen enorme Zeit und Speicher. Dies bedeutet auch, dass nur relativ wenige JPG im Speicher gehalten und beim erneuten Einlesen direkt aus dem Speicher genommen werden können. Bei der MPF-Lösung werden jedoch nur die ersten 256 kB für das EXIF eingelesen (weniger als 256 kB liest Windows sowieso nicht) und dann nochmal die 300 - 900 kB für das MPF, wenn man sie selektiv aus dem Dateistream liest. Tatsächlich benötigt das Einlesen beim ersten Durchgang nur 10 msec je Datei, und ab dem zweiten nur 1 msec, und das auch bei 4.500 Dateien (16 GB Speicher).

Ich füge noch den Code bei, wie ich von TBytes zu TBitmap komme:

Delphi-Quellcode:

uses
  ...
  JpegImage,SynGDIPlus,...

var
  JpegImage:TJpegImage;
  BMP:TBitmap;
  TBMPF: TBytes;
  Breite, Höhe: integer;
If EXIF.ExtrahiereMPF(TBMPF) then begin
  JpegImage := TJpegImage.Create;
  JpegImage.CreateFromBuffer(TBMPF, Length(TBMPF));
  BMP := TBitmap.Create(Breite, Höhe);
  BMP.PixelFormat := pf24bit;
  BMP.Canvas.StretchDraw(BMP.Canvas.ClipRect,JpegImage.ToBitmap);
  JpegImage.Free;
end;

Delphi-Quellcode:

ExtrahiereMPF

ist eine Methode aus meiner selbst geschriebenen EXIF-Unit, die das MPF-Bild aus dem Filestream in einen TBytes-Puffer kopiert. Ich füge noch ein Diagramm der relevanten MPF-Struktur bei, die unglaublich kompliziert und verwirrend gestaltet wurde. Die Spezifikation findet man hier.

Delphi-Quellcode:

.CreateFromBuffer

und

Delphi-Quellcode:

.ToBitmap

kommen aus SynGDIPlus von Synopse.

EDIT: Durch mein neues Vorgehen fällt plötzlich auf, dass keineswegs alle Bilder meiner Sony ein MPF haben, was mich total verblüfft. Eine Untersuchung zeigt, dass fast alle Bilder, die keins haben, Hochkantbilder sind. Eine Erklärung dafür könnte die sein, dass diese MPF damals eigentlich dazu eingeführt wurden, dass auf einem Fernseher ein besseres Vorschaubild gezeigt werden konnte. Da Hochkantbilder auf einem Fernseher viel kleiner dargestellt werden, wurde das bei ihnen wahrscheinlich weggelassen. Die Sony-Kameras werden in den Specs regelmäßig mit "MPF Baseline compliant" beworben. Es scheint so, als wäre eine alte Sache einfach immer weitergeführt worden. Verrückt.

[himitsu]

Problem an TJpegImage und Co. ist oft, dass selbst bei Zoom, oftmals die Bilder zuerst in ein TBitmap gezeichnet und anschließend gestrecht werden,
anstatt gleich gestrecht in das Temp-Bitmap gezeichnet zu werden.

Drum hat Delphi, z.B. im TImage, mit großen Bildern (JPEG,PNG,TIFF) oft Probleme.
z.B. siehe TWICImage, denn die WIC-API (Windows Imaging Component) ist eigentlich speziell für die stückchenweise Behandlung extrem großer Bilder sehr speichersparend optimiert .... man müsste nur die API richtig benutzen.

Ich hab hier einen netten Testfall, wo eine technische Zeichnug als TIFF nur wenige 100 KB groß ist, aber beim Versuch ein Vorschaubild zu bekommen, da rauchen die Delphi-Klassen bei ab, weil als Bitmap ist das Ding rießig.

[striderx]

Zitat:

Zitat von Benmik (Beitrag 1514433)

@striderx: Danke! Nie von gehört.

GDIPAPi und GDIPOBJ gehören zum Lieferumfang von Delphi.

[Benmik]

Zitat:

Zitat von himitsu (Beitrag 1514444)

Problem an TJpegImage und Co. ist oft, dass selbst bei Zoom, oftmals die Bilder zuerst in ein TBitmap gezeichnet und anschließend gestretcht werden,...

Das ist interessant, denn ich beobachte bei meiner Methode, dass die 16 GB bis an den Rand vollaufen, was so erstmal nicht verständlich ist. 1920 x 1080 müssten als Bitmap etwa 6 MB sein, das kann doch eigentlich 16.000 MB nicht auslasten, zumal sie ja nach dem Zeichnen sofort freigegeben werden.

Was käme denn als Alternative in Frage? Ich muss da wohl noch ein bisschen forschen.

[Benmik]

Zitat:

Zitat von himitsu (Beitrag 1514444)

z.B. siehe TWICImage...

Das war ein wunderbarer Hinweis. Ich habe mal probehalber auf TWICImage umgestellt und siehe da, plötzlich sind alle 24 Kerne voll ausgelastet und die Speicherbefüllung steigt langsam und linear bis auf 65% und verharrt dann dort; und das trotz einiger Umkopiererei. Sehr nützlich war diese Routine von hier ("High quality bitmap resize with transparency"):

Delphi-Quellcode:

Uses
  Winapi.Wincodec,
  Vcl.Graphics;

procedure ResizeBitmap(Bitmap: TBitmap; const NewWidth, NewHeight: integer);
var
  Factory: IWICImagingFactory;
  Scaler: IWICBitmapScaler;
  Source : TWICImage;
begin
  Bitmap.AlphaFormat := afDefined;
  Source := TWICImage.Create;
  try
    Factory := TWICImage.ImagingFactory;
    Source.Assign(Bitmap);
    Factory.CreateBitmapScaler(Scaler);
    Scaler.Initialize(Source.Handle, NewWidth, NewHeight,
      WICBitmapInterpolationModeHighQualityCubic);
    Source.Handle := IWICBitmap(Scaler);
    Bitmap.Assign(Source);
    Scaler := nil;
    Factory := nil;
  finally
    Source.Free;
  end;
end;

Dieses TWICImage muss ich mir noch genauer anschauen.

[himitsu]

Der Scaler ist zwar nicht der Schnellste (gegenüber Anderem z.B. aus GDI+)
aber er arbeitet in kleinen Blöcken und braucht selber somit kaum Speicher.
Nur blöd, wenn Delphi selber ihn garnicht verwendet und stattdessen ein TBitmap nimmt und dort über TCanvas kopiert/skaliert.
Auch schmeißen sie direkt nach dem Laden viele Interfaces sofort wieder weg, so daß man sich selber Vieles wieder unnötig neu erstellen muß.