TJSON.JSONToObject DateTime als LocalTime

[Hobbycoder]

Hi,

ich übertrage Datenstrukturen mittels ObjectToJSON und JSONToObject pber http zwischen Client und Server, was soweit recht simple und fehlerfrei funktioniert. Nur bei den TDateTime-Werten habe ich so meine Probleme.

Je nach TJSONOptions habe ich auf der Serverseite eine Abweichung um +1 oder +2 Stunden. Das wird sicherlich auf Grund der zeitzone und Winter-/Sommerzeit so sein.
Jedoch, wie kann ich das verhindern oder wie kann ich das auf die lokale Uhrzeit korrigieren. Die übertragene Zeit soll auf dem Server immer passend zu dessen Computerzeit und Zeitzone angezeigt werden.

Die o.g. Abweichung habe ich schon wenn Server und Client beide auf meinem Rechner laufen. Später soll der Client auch in der Türkei laufen, jedoch bei den übertragenen Daten am Server mit deutscher Zeit angezeigt werden.

Danke im Voraus.

[skybibo]

Hi,

normalerweise wird in dem Fall mit UTC gearbeitet. UTC ist unabhängig von der Zeitzone und es gibt keine Sommer/Winterzeit. Die Speicherung und Übertragung erfolgt dann nur im UTC Format und wird dann am Ziel wieder in die Lokale Zeit umgewandelt (oder eine andere Zeitzone).

[Hobbycoder]

Über die TJSONOption [joDateIsUTC] kann ich das ja einstellen.

Dann muss ich auf Serverseite mit der Funktion:

Delphi-Quellcode:

function UTCToLocalTime(AValue: TDateTime): TDateTime;
var
  SysTime1, SysTime2: TSystemTime;
  TZinfo: TTimeZoneInformation;
begin
  GetTimeZoneInformation(TZinfo);
  DateTimeToSystemTime(AValue, SysTime1);
  SystemTimeToTzSpecificLocalTime(@TZinfo, SysTime1, SysTime2);
  Result := SystemTimeToDateTime(SysTime2);
end;

das in die lokale Zeit umrechnen. Trotzdem habe ich immer noch eine Stunde zuviel. Berücksichtigt die Funktion SystemTimeToTzSpecificLocalTime keine Sommer-/Winterzeit?

[Olli73]

Wie sieht denn der String aus, den du sendest?

2009-06-30T18:30:00+02:00 (lokale Zeit)

oder

2007-12-24T18:21:00Z (UTC)

[Hobbycoder]

Gesendet und empfangen wird "2023-11-01T10:52:32.271Z"

Nach der Umrechnung habe ich 01.11.23 11:52:32

[Olli73]

sieht aber richtig aus !?

[Hobbycoder]

Ja, nur dass wir zu dem Zeitpunkt 10:52 hatten.
Deswegen meine Frage, fehlt das noch die Berücksichtigung Sommer/Winterzeit? Oder muss die Funktion das so können?

[Uwe Raabe]

Um 10:52 LocalTime sollte bei UTC aber ein anderer Wert herauskommen als "2023-11-01T10:52:32.271Z". Das Problem liegt also vermutlich beim Sender und nicht beim Empfänger.

Wie sieht denn der Code auf Client-Seite aus?

[Olli73]

Was passiert wenn du "joDateIsUTC" abschaltest?

[Hobbycoder]

Zitat:

Zitat von Uwe Raabe (Beitrag 1528825)

Um 10:52 LocalTime sollte bei UTC aber ein anderer Wert herauskommen als "2023-11-01T10:52:32.271Z". Das Problem liegt also vermutlich beim Sender und nicht beim Empfänger.

Wie sieht denn der Code auf Client-Seite aus?

Delphi-Quellcode:

UE:=TJson.JsonToObject<TUserEntry>(Str, [joIgnoreEmptyStrings, joIgnoreEmptyArrays, joDateIsUTC]);

bzw.

Delphi-Quellcode:

Result:=TJson.ObjectToJsonString(Self, [joIgnoreEmptyStrings, joIgnoreEmptyArrays, joDateIsUTC]);

Beides jeweils in einer Funktion des Objects.

Server und Client verwenden die gleiche Unit und laufen auch beim Test auf dem gleichen Rechner.

[DeddyH]

Delphi-Quellcode:

Result:=TJson.ObjectToJsonString(Self, [joIgnoreEmptyStrings, joIgnoreEmptyArrays]);

So müsste es IMHO richtig sein.

[Hobbycoder]

Zitat:

Zitat von Olli73 (Beitrag 1528827)

Was passiert wenn du "joDateIsUTC" abschaltest?

Ohne joDateIsUTC (

Delphi-Quellcode:

Result:=TJson.ObjectToJsonString(Self, [joIgnoreEmptyStrings, joIgnoreEmptyArrays]);

) wird folgender String gesendet: "2023-11-01T11:13:32.391+01:00" (empfangen wird jedoch nach JSONToObject "2023-11-01T11:13:32.391 01:00"- Statt dem + ist eine Leerstelle drin).

Mit oder ohne die funtion UTCToLocalTime erhalte ich dann eine Differenz von +2 Stunden. Also 13:13:32

[Olli73]

Wenn du "joDateIsUTC" verwendest, musst du (scheinbar) vor "ObjectToJSON" selber in UTC umrechnen. Ohne "joDateIsUTC" sollte einfacher sein...

[Olli73]

Und ggf. "joDateFormatISO8601" nutzen

[Hobbycoder]

UTC wäre schon gut, denn ich muss für den Realbetrieb die Zeitumrechnung für unterschiedliche zeitzonen berücksichtigen.

Von daher wäre eine Funktion UCTToLocalTime da recht nützlich.
Was mich wirklich wundert: Dieses Problem müsste ja eigenltich jeder haben, der die TJSON.ObjectToJSONString bzw. TJSON.JSONToObject nutzt und irgendwelche Zeitdaten überträgt.
Ich könnte natürlich auch die Zeit als String übertragen. Was aber mein Problem mit den Zeitzonen nicht berücksichtigt.

[Olli73]

Zitat:

Zitat von Hobbycoder (Beitrag 1528834)

UTC wäre schon gut, denn ich muss für den Realbetrieb die Zeitumrechnung für unterschiedliche zeitzonen berücksichtigen.

Wenn ja hinten "+01" z.B. dransteht, kann man ja immer noch umrechnen...

Zitat:

Zitat von Hobbycoder (Beitrag 1528834)

Ich könnte natürlich auch die Zeit als String übertragen. Was aber mein Problem mit den Zeitzonen nicht berücksichtigt.

Ist ja schon string:

https://docs.jsonata.org/date-time

JSON does not have a built-in type for date/time values. The general consensus is to store the date/time value as a string in ISO 8601 format.

[Uwe Raabe]

Zitat:

Zitat von Hobbycoder (Beitrag 1528834)

Was mich wirklich wundert: Dieses Problem müsste ja eigenltich jeder haben, der die TJSON.ObjectToJSONString bzw. TJSON.JSONToObject nutzt und irgendwelche Zeitdaten überträgt.

Die Methoden verhalten sich bei korrekter Anwendung auch richtig.

Delphi-Quellcode:

type
  TMyObject = class
  public
    FDt: TDateTime;
  end;

procedure Test();
begin
  var dt := EncodeDateTime(2023, 11, 1, 10, 52, 0, 0);
  var obj := TMyObject.Create;
  try
    obj.FDt := dt;
    var json := TJson.ObjectToJsonObject(obj, [joDateFormatISO8601]);
    Writeln(json.ToJSON);
    obj.FDt := 0;
    TJson.JsonToObject(obj, json, [joDateFormatISO8601]);
    if SameDate(obj.FDt, dt) then
      Writeln('OK')
    else
      Writeln('Fail');
  finally
    obj.Free;
  end;
end;

Ergibt

Zitat:

{"dt":"2023-11-01T10:52:00.000+01:00"}
OK

Kannst du mal ein konkretes Beispiel zeigen, mit dem das Problem reproduzierbar ist?

[Olli73]

Also bei mir funktioniert das hier auch (Delphi 11):

Delphi-Quellcode:

unit Unit7;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, REST.Json;

type
  TMyClass = Class
    Test: TDateTime;
  End;

  TForm7 = class(TForm)
    btn1: TButton;
    procedure btn1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form7: TForm7;

implementation

{$R *.dfm}

procedure TForm7.btn1Click(Sender: TObject);
var
  dt: TDateTime;
  MyObj: TMyClass;
  S: String;
begin
  MyObj := TMyClass.Create;
  try
    MyObj.Test := Now;
    S := TJSON.ObjectToJsonString(MyObj, [joDateFormatISO8601]);
    ShowMessage(S);

    MyObj.Free;
    MyObj := TJson.JsonToObject<TMyClass>(S, [joDateFormatISO8601]);
    ShowMessage(DateTimeToStr(MyObj.Test));

  finally
    MyObj.Free;
  end;

end;

end.

[Hobbycoder]

Hier mal die Unit der Klasse

Delphi-Quellcode:

unit uUserstatus;

interface

uses System.Classes, system.sysutils, System.Generics.Collections, REST.Json;

type
  TUserStatus=(usStarted, usStopped, usInIdle, usInWork);

  TUserEntry=class
  private
    FDuration: Cardinal;
    FStatus: TUserStatus;
    FTime: TDateTime;
    FUsername: string;
    FGuid: string;
    FUserGuid: string;
    procedure SetDuration(const Value: Cardinal);
    procedure SetStatus(const Value: TUserStatus);
    procedure SetTime(const Value: TDateTime);
    procedure SetUsername(const Value: string);
    procedure SetGuid(const Value: string);
    procedure SetUserGuid(const Value: string);
  public
    procedure Assign(Source: TObject);
    function ToJson: string;
    procedure FromJson(Str: string);
  published
    property UserGuid: string read FUserGuid write SetUserGuid;
    property Guid: string read FGuid write SetGuid;
    property Username: string read FUsername write SetUsername;
    property Time: TDateTime read FTime write SetTime;
    property Status: TUserStatus read FStatus write SetStatus;
    property Duration: Cardinal read FDuration write SetDuration;
  end;

  TUserList=class(TObjectList<TUserEntry>)
  end;

implementation

{ TUserEntry }

procedure TUserEntry.Assign(Source: TObject);
begin
  if Source is TUserEntry then
  begin
    self.FUserGuid:=TUserEntry(Source).UserGuid;
    self.FGuid:=TUserEntry(Source).Guid;
    self.FUsername:=TUserEntry(Source).Username;
    self.FTime:=TUserEntry(Source).Time;
    self.FStatus:=TUserEntry(Source).Status;
    self.FDuration:=TUserEntry(Source).Duration;
  end;
end;

procedure TUserEntry.FromJson(Str: string);
var
  UE: TUserEntry;
begin
  UE:=TJson.JsonToObject<TUserEntry>(Str, [joIgnoreEmptyStrings, joIgnoreEmptyArrays]);
  try
    Self.Assign(UE);
  finally
    UE.Free;
  end;
end;

procedure TUserEntry.SetDuration(const Value: Cardinal);
begin
  FDuration := Value;
end;

procedure TUserEntry.SetGuid(const Value: string);
begin
  FGuid := Value;
end;

procedure TUserEntry.SetStatus(const Value: TUserStatus);
begin
  FStatus := Value;
end;

procedure TUserEntry.SetTime(const Value: TDateTime);
begin
  FTime := Value;
end;

procedure TUserEntry.SetUserGuid(const Value: string);
begin
  FUserGuid := Value;
end;

procedure TUserEntry.SetUsername(const Value: string);
begin
  FUsername := Value;
end;

function TUserEntry.ToJson: string;
begin
  Result:=TJson.ObjectToJsonString(Self, [joIgnoreEmptyStrings, joIgnoreEmptyArrays]);
end;

end.

Gesendet wirde über IdHTTP

Delphi-Quellcode:

    UEStr:=FUserEntry.ToJson;
    Response:=FHttp.Post('http://'+FHost+':'+FPort.ToString+TIdURI.ParamsEncode('/upe.php?userentry='+UEStr), ss);

und empfangen über IdHTTPServer

Delphi-Quellcode:

    UEStr:=ARequestInfo.Params.Values['userentry'];
    if UEStr<>'' then
    begin
      UE:=TUserEntry.Create;
      try
        UE.FromJson(UEStr);
        UserSettingsList.LoadFromFile(FPath+'usersettings.dat');
        DoUpdateEntry(UE);
      finally
        UE.Free;
      end;
    end;

[Olli73]

Wenn du UTC verwenden willst, musst du wohl vorher umrechnen:

Delphi-Quellcode:

UTCNow := TTimeZone.Local.ToUniversalTime(Now);

[Hobbycoder]

Zitat:

Zitat von Olli73 (Beitrag 1528844)

Wenn du UTC verwenden willst, musst du wohl vorher umrechnen:

Delphi-Quellcode:

UTCNow := TTimeZone.Local.ToUniversalTime(Now);

Danke ;-) Das war's. Klingt eigentlich logisch, hab ich nur igendwie nicht dran gedacht.

Aber, und das finde ich jetzt merkwürdig, wenn ich joDateIsUTC verwende, erhalte ich am Server eine Stunde zu wenig. Wenn ich joDateFormatISO8601 verwende, dann stimmt die Zeit auf beiden Seiten. (Jetzt natürlich mit Umrechnung LocalToUTC am Client bevor die Uhrzeit ins Object geschrieben wird, und UTCToLocal am Server nach dem die Uhrzeit aus dem Object gelesen wurde)

[Uwe Raabe]

Zitat:

Zitat von Hobbycoder (Beitrag 1528845)

wenn ich joDateIsUTC verwende, erhalte ich am Server eine Stunde zu wenig. Wenn ich joDateFormatISO8601 verwende, dann stimmt die Zeit auf beiden Seiten. (Jetzt natürlich mit Umrechnung LocalToUTC am Client bevor die Uhrzeit ins Object geschrieben wird, und UTCToLocal am Server nach dem die Uhrzeit aus dem Object gelesen wurde)

Wenn du joDateIsUTC angibst, dann sagst du lediglich, dass die Zeiten in den Objektfeldern in UTC vorliegen (ToJSON) bzw. geschrieben werden sollen (FromJSON). Das JSON-Format wird nur durch joDateFormatISO8601 beeinflusst. Beide Optionen sind voneinander unabhängig.