TXMLDocument kann nicht created werden

[Ykcim]

Hallo Zusammen,

ich hänge an einem ganz doofen Fehler fest:
Ich arbeite das erste Mal mit xml-Files und möchte zwei Werte ändern. Nachdem ich jetzt lange erfolglos es versucht habe - inkl. Internetsuche, habe ich eine neues Projekt eröffnet. In diesem habe ich ein TXMLDocument auf das Form gelegt und es hat wunderbar geklappt.

Dann wollte ich das Ganze in mein eigentliches Project überführen und es klappt wieder nicht. Ich glaube das Ganze hängt an dem Create-Aufruf, obwohl dort nicht der Fehler auftritt. Denn wenn ich in dem TestProjekt das TXMLDocument Object wieder lösche und das ganze im Code create, klappt es nur, wenn ich dem Parent "Self" eintrage. Wenn ich wie in meinem eigentlichen Projekt "nil" eintrage, klappt es auch nicht. Das Ganze findet aber ein einer Klasse statt, sodass Self nicht funktioniert.

Delphi-Quellcode:

function TLogic.XMLEdit(xmlPfad: string; TargetPfad: string): Boolean;
var   WmDKntn: IXMLNode;
      XMLDcmnt: TXMLDocument;
      NwVlDateien, NwVlWF_Name: string;
begin
   Try
      XMLDcmnt:= TXMLDocument.Create(xmlPfad);
      Try
         XMLDcmnt.LoadFromFile(xmlPfad);
         WmDKntn:= XMLDcmnt.DocumentElement;
         NwVlDateien:= StringReplace(WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
         NwVlWF_Name:= StringReplace(WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
         WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue:= NwVlDateien;
         WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue:= NwVlWF_Name;
         XMLDcmnt.SaveToFile(TargetPfad + NwVlDateien);
         Result:= true;
      Finally
         XMLDcmnt.Free;
      End;
   Finally
      Result:= false;
   End;
end;

Ich habe es auch schon mit

Delphi-Quellcode:

XMLDcmnt:= TXMLDocument.Create(xmlPfad);

versucht, aber das hatte keinen Einfluss.

Kann mir jemand sagen, was ich falsch mache?

Die Fehlermeldung besagt

Zitat:

Ungültige Zeigeroperation

Vielen Dank
Patrick

[shebang]

Zitat:

Zitat von Ykcim (Beitrag 1542526)

Kann mir jemand sagen, was ich falsch mache?

Findet das Ganze in einem Thread statt und wenn ja, hast du vorher ein CoInitialize aufgerufen?

[Ykcim]

Hallo shebang,

vielen Dank für Deine Frage. Das ganze findet nicht in einem extra Thread, sondern direkt im Hauptthread statt.
Was mich wundert ist, dass es nur funktioniert, wenn ich ein TXMLDocument auf das Form lege (geht nicht, weil die Procedure in einer Klasse stattfindet) oder ich als Parent "Self" angebe (Geht nicht, weil die Procedure in einer Klasse sattfindet).

Ich bin ratlos...

[haentschman]

Halölle...8-)

versuche Mal:

Delphi-Quellcode:

XMLDcmnt: IXMLDocument;

...
Finally
  XMLDcmnt.Free; // könnte dann weg weil ist ein interface
End;

PS:
Du arbeitest auch mit

Delphi-Quellcode:

WmDKntn: IXMLNode;

Klassen und interfaces zu mischen ist imho keine gute Idee. :wink:

[bcvs]

Ich create ein TXMLDocument immer mit einer Dummy-Componente als Owner, niemals mit nil, so wie hier beschrieben:
http://www.delphipraxis.net/185202-x...exception.html

[Ykcim]

Hallo Zusammen,

vielen Dank!!!

Ich bin gerade auch über diese Beitrag gestolpert, als ich mal nach "Delphi TXMLDocument.Create" gesucht habe...: https://stackoverflow.com/questions/...nent-on-the-fo


Ich habe es jetzt geändert und so scheint es zu funktionieren:

Delphi-Quellcode:

function TLogic.XMLEdit(xmlPfad: string; TargetPfad: string): Boolean;
var   WmDKntn: IXMLNode;
      XMLDcmnt: IXMLDocument;  //Änderung
      NwVlDateien, NwVlWF_Name, NwFlNm: string;
begin
   Try
      //XMLDcmnt:= TXMLDocument.Create(xmlPfad);  WEG
      Try
         //XMLDcmnt.LoadFromFile(xmlPfad);  WEG
         XMLDcmnt:= LoadXMLDocument(xmlPfad); //HINZU
         NwFlNm:= StringReplace(XMLDcmnt.FileName,'.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
         WmDKntn:= XMLDcmnt.DocumentElement;
         NwVlDateien:= StringReplace(WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
         NwVlWF_Name:= StringReplace(WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
         WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue:= NwVlDateien;
         WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue:= NwVlWF_Name;
         XMLDcmnt.SaveToFile(TargetPfad + NwVlDateien);
         Result:= true;
      Finally
         //XMLDcmnt.Free; WEG, weil nicht created
      End;
   Finally
      Result:= false;
   End;
end;

Vielen Dank
Patrick

[DeddyH]

Spinne ich, oder gibt die Funktion in jedem Fall false zurück?

[Ykcim]

:lol:
Nein, du spinnst nicht

Ich hatte vergessen das letzte Finally noch in ein Except ändern... So sieht es jetzt aus!

Delphi-Quellcode:

function TLogic.XMLEdit(xmlPfad: string; TargetPfad: string): Boolean;
var   WmDKntn: IXMLNode;
      XMLDcmnt: IXMLDocument;
      NwVlDateien, NwVlWF_Name, NwFlNm: string;
begin
   Try
      if TargetPfad[Length(TargetPfad)] <> '\' then begin
         TargetPfad:= TargetPfad + '\';
      end;
      XMLDcmnt:= LoadXMLDocument(xmlPfad);
      NwFlNm:= ExtractFileName(StringReplace(XMLDcmnt.FileName,'.zip','.xml',[rfIgnoreCase, rfReplaceAll]));
      WmDKntn:= XMLDcmnt.DocumentElement;
      NwVlDateien:= StringReplace(WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      NwVlWF_Name:= StringReplace(WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue:= NwVlDateien;
      WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue:= NwVlWF_Name;
      XMLDcmnt.SaveToFile(TargetPfad + NwVlDateien);
      Result:= true;
   Except
      Result:= false;
   End;
end;

Vielen Dank an alle!!!
LG Patrick

[himitsu]

Delphi-Quellcode:

      XMLDcmnt := TXMLDocument.Create(xmlPfad);
      Try
         XMLDcmnt.LoadFromFile(xmlPfad);

Entweder schon beim Erstellen laden, oder erst später ... beides macht normal eigentlich niemand.
(ich würde den Parameter beim Create weglassen und nur LoadFromFile nutzen)

Und ja, das XMLDcmnt.Free weg und direkt als Interface die Variable. (wenn, dann maximal noch

Delphi-Quellcode:

XMLDcmnt := nil;

)


PS, bissl Kürzer wäre ReplaceStr, bzw,

Delphi-Quellcode:

ReplaceText(XMLDcmnt.FileName, '.zip', '.xml')

, aber eigentlich nutzt man doch ein

Delphi-Quellcode:

ChangeFileExt(xmlPfad, '.xml')

?

Zitat:

Delphi-Quellcode:

   Finally
      Result:= false;
   End;

Das ergibt immer False ... wolltes du vielleicht ein Except?

Und wenn ja, dann schäm dich.
Fehlermeldungen blind wegzuwerfen und in garnichts oder nur einen Boolean zu konvertieren ... sowas gehört sich nicht.
* ordentiche Fehlermeldung
* oder wenigestens in ein Log schreiben

Was machst du denn außerhalb, bei einem False?

Delphi-Quellcode:

procedure TLogic.XMLEdit(xmlPfad: string; TargetPfad: string);
var WmDKntn: IXMLNode;
      XMLDcmnt: IXMLDocument;
      NwVlDateien, NwVlWF_Name, NwFlNm: string;
begin
      if TargetPfad[Length(TargetPfad)] <> '\' then begin
         TargetPfad:= TargetPfad + '\';
      end;
      XMLDcmnt:= LoadXMLDocument(xmlPfad);
      NwFlNm:= ExtractFileName(StringReplace(XMLDcmnt.FileName,'.zip','.xml',[rfIgnoreCase, rfReplaceAll]));
      WmDKntn:= XMLDcmnt.DocumentElement;
      NwVlDateien:= StringReplace(WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      NwVlWF_Name:= StringReplace(WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue:= NwVlDateien;
      WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue:= NwVlWF_Name;
      XMLDcmnt.SaveToFile(TargetPfad + NwVlDateien);
end;

Die Interfaces geben sich selbst frei
und die Fehlermeldung wird automatisch angezeigt.

Und beim Aufruf des XMLEdit kann man entweder abbrechen und Fehlermeldung anzeigen lassen
oder dort mit einem Try-Except die Sache entsprechend der Anforderungen dort behandeln. (alternativen Code ausführen lassen oder die Fehlermmeldung manuell anzeigen)

[Ykcim]

Hallo himitsu,

vielen Dank für die guten Anregungen!

Zitat:

PS, bissl Kürzer wäre ReplaceStr, bzw, ReplaceText(XMLDcmnt.FileName, '.zip', '.xml') , aber eigentlich nutzt man doch ein ChangeFileExt(xmlPfad, '.xml') ?

Den Befehl kannte ich nicht - habe ich gerne übernommen.

Zitat:

Das ergibt immer False ... wolltes du vielleicht ein Except?

Stimmt, war ein Fehler!

Zitat:

Und wenn ja, dann schäm dich.
Fehlermeldungen blind wegzuwerfen und in garnichts oder nur einen Boolean zu konvertieren ... sowas gehört sich nicht.
* ordentiche Fehlermeldung
* oder wenigestens in ein Log schreiben

Ganz schön streng - finde ich aber gut, nur dann wird man besser! :oops:

Zitat:

Was machst du denn außerhalb, bei einem False?

Nur wenn ein True zurückgeliefert wird, wird die ursprüngliche Datei gelöscht. Der Benutzer sieht in drei FileListBoxes wie die Dateien bearbeitet und verschoben werden. In der FileListBox mit den ursprünglichen Download-Dateien soll am Ende nichts mehr drinstehen.

So sieht der ganze Ablauf aus jetzt aus:

Delphi-Quellcode:

procedure TFrm_BD_DHL.btn_ExtractDataClick(Sender: TObject);
var   Logic: TLogic;
      FList: TStringList;
      I: integer;
      EditResult: boolean;
begin
   Logic:= TLogic.Create;
   FList:= TStringList.Create;
   Try
      //Erst nur die ZIP-Files mit den PDF-Files
      Logic.GetAllFilesEM(edt_DownloadPath.Text, 'zip', FList, false);
      for I := 0 to FList.Count -1 do begin
         EditResult:= EditMoveWmDFiles(FList[I], edt_PDFPath.Text, edt_XMLPath.Text);
         if EditResult then begin
            DeleteFile(FList[I]);
         end;
         FlLstbx_Download.Update;
         FlLstbx_PDF.Update;
         FlLstbx_XML.Update;
      end;
      //Zum Schluss die XML-Files, damit sie nicht vor dem Ablegen der PDF-Files verarbeitet werden
      FList.Clear;
      Logic.GetAllFilesEM(edt_DownloadPath.Text, 'xml', FList, false);
      for I := 0 to FList.Count -1 do begin
         EditResult:= EditMoveWmDFiles(FList[I], edt_PDFPath.Text, edt_XMLPath.Text);
         if EditResult then begin
            DeleteFile(FList[I]);
         end;
         FlLstbx_Download.Update;
         FlLstbx_PDF.Update;
         FlLstbx_XML.Update;
      end;
   Finally
      Logic.Free;
      FList.Free;
   End;
end;

function TFrm_BD_DHL.EditMoveWmDFiles(FilePath, PDFPath, XMLPath: string): boolean;
var   Logic: TLogic;
begin
   Try
      Logic:= TLogic.Create;
      Try
         if LowerCase(ExtractFileExt(FilePath)) = '.zip' then begin
            Result:= Logic.ExctractZIP(FilePath, PDFPath);
         end;
         if LowerCase(ExtractFileExt(FilePath)) = '.xml' then begin
            Result:= Logic.XMLEdit(FilePath, XMLPath);
         end;
      Finally
         Logic.Free;
      End;
   Except
      Result:= false;
   End;
end;


function TLogic.ExctractZIP(ZipPfad, ExtractPfad: string): boolean;
var   ZFile: TZipFile;
begin
   Try
      ZFile:= TZipFile.Create;
      Try
         ZFile.Open(ZipPfad, zmRead);
         ZFile.ExtractAll(ExtractPfad);
         Result:= true;
      Finally
         ZFile.Free;
      End;
   Except
      Result:= false;
   End;
end;


function TLogic.XMLEdit(xmlPfad: string; TargetPfad: string): Boolean;
var   WmDKntn: IXMLNode;
      XMLDcmnt: IXMLDocument;
      NwVlDateien, NwVlWF_Name, NwFlNm: string;
begin
   Try
      if TargetPfad[Length(TargetPfad)] <> '\' then begin
         TargetPfad:= TargetPfad + '\';
      end;
      XMLDcmnt:= LoadXMLDocument(xmlPfad);
      NwFlNm:= ChangeFileExt(ExtractFileName(xmlPfad), '.xml');
      WmDKntn:= XMLDcmnt.DocumentElement;
      NwVlDateien:= StringReplace(WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      NwVlWF_Name:= StringReplace(WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue, '.zip','.xml',[rfIgnoreCase, rfReplaceAll]);
      WmDKntn.ChildNodes.FindNode('Dateien').ChildNodes.FindNode('Dateiname').NodeValue:= NwVlDateien;
      WmDKntn.ChildNodes.FindNode('WF_Name').ChildNodes.FindNode('WF_Name').NodeValue:= NwVlWF_Name;
      XMLDcmnt.SaveToFile(TargetPfad + NwVlDateien);
      Result:= true;
   Except
      MessageDlg('Die Datei ' + xmlPfad + ' konnte nicht editiert werden. Bitte manuell eingreifen und den Administrator informieren.', mtError, [mbOK], 0);
      Result:= false;
   End;
end;

Vielen Dank
Patrick

[himitsu]

Zitat:

den Administrator informieren

Wenn jetzt noch die Exception.Message in dem Dialog oder einer Logdatei stünde, dann hatte der arme Admin einen Hinweis darauf, was nicht ging.

MessageBoxen zur Fehlerbehandlung haben den Nachteil, dass man außenrum nichts mehr machen kann.
Direkt mit Exceptions zu arbeiten hatt den Voreil, dass man beim Aufrufer reagieren kann.
* Zusatzinfos im Fehlertext
* oder eben nochmal Alternatives versuchen

Delphi-Quellcode:

try Speichere; except SpeichereAndersOderWoanders; end;

Wir hatten so eine Funktion erst im Client, welche in der x-ten Ebene versteckt mit einem ShowMessage den Fehler anzeigte.
Als diese Funktion dann in einem Dienst benutzt wurde, welcher keinen Zugriff auf einen Monitor hatte ... da blieb das Programm dann wunderschön hängen, ohne dass es tagelang jemand bemerkte ... und selbst danach, wusste erstmal niemand, warum es hängt.

[Ykcim]

Hallo himitsu,

dazu habe ich eine Frage - etwas out of topic.

Es handelt sich hierbei um eine Client-Server-App und ich sende Messages an den Client zwecks Logging. Aber wie kann ich einen Fehler melden und auch Exception-Daten verwenden, wenn try/except verwende.
Wie komme ich im except-Teil an die Exception, damit ich die Meldung verarbeiten kann? In der Vergangenheit habe ich meistens mit einem GlobalExceptionHandler gearbeitet...

Vielen Dank
Patrick

[AuronTLG]

Code:

Try
//...
Except on E : Exception
  Do Begin
     ShowMessage(E.Message);
     End;
End;

Vielleicht habe ich ja was missverstanden, aber diese Konstruktion hier sollte das doch tun, oder?
Logischerweise kann man alle möglichen Dinge mit der Exception dann machen...

[himitsu]

https://docwiki.embarcadero.com/RADS...tions_(Delphi) :zwinker:

Delphi-Quellcode:

except
  on E: Exception do begin
    MachWas(E.ClassName + ' ' + E.Message);
  end;
end;

Delphi-Quellcode:

except
  on E: Exception do
    if E is EFileError then
      MachWasAnderes(E.ClassName + ' ' + E.Message)
    else
      MachWas(E.ClassName + ' ' + E.Message);
end;

Delphi-Quellcode:

except
  on ESpecialError do
    Sonstwas;  // ja, Die Variable muß man nicht angeben, wenn man sie nicht braucht und sie muß nicht zwangsweise E heißen, aber 99,998% nennen sie so
  on E: EFileError do
    MachWasAnderes(E.ClassName + ' ' + E.Message);
  on E: Exception do
    MachWas(E.ClassName + ' ' + E.Message);
end;

Delphi-Quellcode:

except
  MachWas(Exception(ExceptObject).Message);
end;

finally
  if ExceptObject <> nil then
    MachWas(Exception(ExceptObject).Message);  // egal wo ... sobald ExceptObject nicht nil, ist man gerade irgendwo in einer Fehlerbehandlung
end;

aber psssssst :duck:

[Ykcim]

Vielen Dank!

Das werde ich versuchen in meine Apps einzubauen!

LG Patrick