ADO Queries per Thread aktualisieren

[Schwarzesshaaf666]

Ich habe ein Problem mit den Threads. Ich habe ein Datenmodul auf dem ganz, ganz viele ADO Queries sind. Diese sollen je per Thread parallel aktualisiert werden. Ich habe eine Thread-Klasse erstellt, die im Create eine DataSource bekommt und im Execute wird das Query "einfach" geschlossen und geöffnet. Danach will ich vom Thread wissen, ob er fertig ist und wie viele Datensätze das Query hat.

Meine Thread-Klasse:

Delphi-Quellcode:

TQThread = class(TThread)
  private
    FQuery: TADOQuery;
    FDataSource: TDataSource;
    FIsRunning: Boolean;
    FRecordCount: Integer;

    function GetIsRunning: Boolean;

    procedure DisableFormControls;
    procedure EnableFormControls;
  protected
    procedure Execute; override;

  public
    constructor Create(DataSource: TDataSource);
    destructor Destroy; override;

  published
    property IsRunning: Boolean read GetIsRunning;
    property RecordCount: Integer read FRecordCount write FRecordCount;
  end;


constructor TQThread.Create(DataSource: TDataSource);
begin
  FDataSource := DataSource;
  FQuery := TADOQuery(FDataSource.DataSet);
  FreeOnTerminate := True;

  inherited Create(True);
end;

destructor TQThread.Destroy;
begin
  FreeAndNil(FQuery);

  inherited;
end;

procedure TQThread.DisableFormControls;
begin
  FDataSource.DataSet.DisableControls;
end;

procedure TQThread.EnableFormControls;
begin
  FDataSource.DataSet.EnableControls;
end;

procedure TQThread.Execute;
begin
  inherited;

  try
    try
      FIsRunning := True;
      RecordCount := 0;

      Synchronize(DisableFormControls);

      FQuery.Close;
      FQuery.Open;

      FQuery.Last;
      FQuery.First;

      RecordCount := FQuery.RecordCount;
    except
      on Ex: Exception do
      begin
        dxMessageDlg('Fehler beim Ausführen des Query-Thead! (' + FQuery.Name + ', ' + Self.QualifiedClassName + ')' + #13#10#13#10 + 'Fehlermeldung: ' + Ex.Message + #13#10 + Ex.StackTrace + #13#10 + 'SQL: ' + FQuery.SQL.Text, mtError, [mbOK], 0);
      end;
    end;
  finally
    if not Terminated then
    begin
      Synchronize(EnableFormControls);
      FIsRunning := False;
    end;
  end;
end;

function TQThread.GetIsRunning: Boolean;
begin
  Result := FIsRunning;
end;

Ich starte für jede Query einen Thread und packe ihn in ein TDictionary, das ich in einem Timer regelmäßig prüfe, ob IsRunning True oder False ist. Wenn True, dann will ich in der GUI die Anzahl der Datensätze ausgeben. Das passiert dann im Timer selbst. Das hat sehr lange gut funktioniert, bis ich diese Woche die GUI umgebaut habe. Ich habe auf dem Thread die letzten Direktzugriffe auf die GUI entfernt (es wurden eine Progressbar ein bzw. ausgeblendet und Buttons gesperrt. Das alles wird nicht mehr gebraucht.) Lasse ich nun alles laufen, bekomme ich folgenden Fehler:

Zitat:

---------------------------
GExperts Debugger Exception Notification
---------------------------
Project crent.exe raised exception class EOleSysError with message 'OLE-Fehler 80040200'.
---------------------------
[&Filter ...] [Ignore &All this Session] [&Break] [Additional &Info] [&Continue]
---------------------------
ThreadId=11352
ProcessId=49
ThreadName=""
ExceptionMessage="OLE-Fehler 80040200"
ExceptionName="EOleSysError"
ExceptionDisplayName="EOleSysError"
ExceptionAddress=759D6AE2
FileName=<not available>
LineNumber=<not available>
ExceptionObject=14682200
Classes=[EOleSysError,EOleError,Exception,TObject]

---------------------------

Und das für jeden Thread. Interessanterweise konnte ich nicht feststellen an welcher Stelle es knallt, es scheint nicht im Timer zu passieren, der Debugger hält dort nicht am Breakpoint an. Bei dem Thread habe ich mich an die "Vorlage" von Dalai (https://www.delphipraxis.net/194264-...s-tthread.html) gehalten, da ich seinen Thread ziemlich passend fand. Habt Ihr vielleicht einen Tipp, was hier falsch läuft?

[Delphi.Narium]

Eine Mutmaßung:

Gleichzeitiger Zugriff: Da der Code in einem Thread ausgeführt wird, könnte es zu Problemen kommen, wenn mehrere Threads gleichzeitig auf die gleiche ADO-Verbindung zugreifen.

Du musst (höchstwahrscheinlich) die Threadsicherheit gewährleisten, die Zugriffe auf die ADO-Komponenten / ADO-Verbindung synchronisieren.

FQuery.RecordCount sollte nach dem FQuery.Open bereits den richtigen Wert enthalten, so dass das Last-First-Konstrukt nach dem Open entbehrlich sein sollte.

Dass RecordCount nicht korrekt war, bzw. auf 0 stand, hab' ich nur (früher mal) bei der BDE mit DBase und Paradox erlebt, aber noch nie bei der Nutzung der ADO-Komponenten und "richtigen" Datenbanken wie Oracle, SQL-Server, FireBird, MySQL, ...

[Olli73]

Zitat:

Das hat sehr lange gut funktioniert

Oh, ein Wunder ;)

https://stackoverflow.com/questions/...ion-in-threads

[Schwarzesshaaf666]

@Olli73 Wenn ich das so lese, ist es echt ein Wunder. :-D Aber danke, der Tipp hat sämtliche Fehlermeldungen beseitigt. Wobei ich noch nicht ganz verstehe warum.

@Delphi.Narium Du hast natürlich recht: Es ist noch eine alte Angewohnheit aus alten Tagen. Hab das Last/First entfernt.

[Schwarzesshaaf666]

Mein Problem ist jetzt aber, dass sich RecordCount und IsRunning nicht ändern und ich die Anzahl der Datensätze nicht ausgeben kann. Hat jemand dazu eine Idee?

[Olli73]

Wo / wie / was machst du denn mit dem recordcount?

[Schwarzesshaaf666]

Im Execute direkt nach dem FQuery.Open. Die richtige Zahl wird auch definitiv eingetragen (hab's debuggt).

[TRomano]

Ich denke, dass Du einfach für jeden Thread, der Queries o.ä. behandelt, eine eigene Connection benötigst.

[Olli73]

Zitat:

Zitat von Schwarzesshaaf666 (Beitrag 1545615)

Im Execute direkt nach dem FQuery.Open. Die richtige Zahl wird auch definitiv eingetragen (hab's debuggt).

Aber wo ist dann dein Problem?

[Schwarzesshaaf666]

Wie oben erwähnt: Wenn ich von außen auf RecordCount aus dem Thread zugreife steht da immer eine 0 und im IsRunning immer True. Ich bekomme nicht die richtigen Werte, obwohl diese im Thread selbst richtig gesetzt werden.

[Olli73]

Also wenn du den Zustand von außen Pollen willst, dann macht es wenig Sinn, FreeOnTerminate auf true zu setzen, da das Objekt dann ggf. zu früh freigegeben wird. Aber den Zustand pollen macht sowieso keinen Sinn, entweder du benutzt das Ereignis OnTerminate oder du übergibst eine call-back-prozedur und rufst diese dann am Ende des Threads mit synchronize auf und machst dann dort mit Recordcount was immer du machen willst.

[Schwarzesshaaf666]

Oha, das mit dem OnTerminate ist ein guter Tipp. Hab das völlig übersehen. Statt mit dem Timer zu pollen, melde ich den RecordCount nun im OnTerminate. Danke!

Edit: Am Ende hat sich rausgestellt, dass im Thread eigentlich nur CoInitialize(nil) und CoUninitialize() gefehlt haben.

[haentschman]

Hallöle...8-)

Delphi-Quellcode:

constructor TQThread.Create(DataSource: TDataSource);
begin
  FDataSource := DataSource;
  FQuery := TADOQuery(FDataSource.DataSet);
  FreeOnTerminate := True; // <--

  inherited Create(True);
end;

Persönlich würde immer das inherited immer im Konstruktor an erste Stelle setzen. In deinem Falle greiftst auf eine Variable des TThread zu, die noch nicht existent sein sollte, weil das Create des TThread noch nicht durchlaufen ist. Warum das bei dir funktioniert, weis ich nicht...:gruebel: Klärt mich auf. :zwinker:

besser:

Delphi-Quellcode:

constructor TQThread.Create(DataSource: TDataSource);
begin
  inherited Create(True);

  FDataSource := DataSource;
  FQuery := TADOQuery(FDataSource.DataSet);
  FreeOnTerminate := True;
end;

[Schwarzesshaaf666]

Warum es funktioniert kann ich nicht sagen. Meine Vermutung: FreeOnTerminate ist eine Variable aus TThread und deswegen schon erreichbar.

[Schwarzesshaaf666]

Hier meine aktuelle, lauffähige Version des Threads, falls jemand etwas ähnliches braucht:

Delphi-Quellcode:

interface

type
  TQThread = class(TThread)
  private
    FQuery: TADOQuery;
    FDataSource: TDataSource;
    FRightsPk: Integer;
    FRecordCount: Integer;
    FIsRunning: Boolean;
    FQueryName: string;
  protected
    procedure Execute; override;

  public
    constructor Create(DataSource: TDataSource);
    destructor Destroy; override;

    property RightsPk: Integer read FRightsPk write FRightsPk;
    property RecordCount: Integer read FRecordCount write FRecordCount;
    property IsRunning: Boolean read FIsRunning write FIsRunning;
    property QueryName: string read FQueryName write FQueryName;
  end;

implementation

constructor TQThread.Create(DataSource: TDataSource);
begin
  inherited Create(True);

  FDataSource := DataSource;
  FreeOnTerminate := True;
end;

destructor TQThread.Destroy;
begin
  inherited;
end;

procedure TQThread.Execute;
begin
  inherited;

  CoInitialize(nil);

  try
    try
      FQuery := TADOQuery(FDataSource.DataSet);

      RightsPk := FDataSource.Tag;
      IsRunning := True;
      RecordCount := 0;
      QueryName := FQuery.Name;

      FQuery.Close;
      FQuery.Open;

      RecordCount := FQuery.RecordCount;
      IsRunning := False;
    except
      on Ex: Exception do
      begin
        dxMessageDlg('Fehler beim Ausführen des Query-Thead! (' + FQuery.Name + ', ' + Self.QualifiedClassName + ')' + #13#10#13#10 + 'Fehlermeldung: ' + Ex.Message + #13#10 + Ex.StackTrace + #13#10 + 'SQL: ' + FQuery.SQL.Text, mtError, [mbOK], 0);
      end;
    end;
  finally

    CoUninitialize();
  end;
end;

Um die Ergebnisse abzufragen, nutze ich das Event OnTerminate:

Delphi-Quellcode:

procedure TForm1.TerminateThread(Sender: TObject);
var
  RightsPk: Integer;
  RecordCount: Integer;
begin
  RightsPk := TQThread(Sender).RightsPk;
  RecordCount := TQThread(Sender).RecordCount;

  // Verarbeitung der Variablen
end

Ich sehe gerade, IsRunning ist hier sogar völlig überflüssig... :-)

PS: Kann ich den ersten Beitrag nicht bearbeiten, um den Thread als "gelöst" zu markieren?

[HolgerX]

Hmm...

Zitat:

Code:

CoInitialize(nil);
  try
    try
      FQuery := TADOQuery(FDataSource.DataSet);

      RightsPk := FDataSource.Tag;
      IsRunning := True;
      RecordCount := 0;
      QueryName := FQuery.Name;

      FQuery.Close;
      FQuery.Open;

      RecordCount := FQuery.RecordCount;

Dir ist bewusst, dass der ADOQuery 'außerhalb' des Thread erzeugt wird und du somit innerhalb Execute auf die Komponente 'außerhalb' deines Threads zugreifst und das alle (eventuellen) Messages der ADOQuery im Hauptthread stattfinden?
Ich vermute, dass du eine ADOConnection mit diesem Query verwendest, welche auch außerhalb des Threads genutzt wird?
Also diese außerhalb deines Threads ist!

So weit ich weiß sollte jeder Thread seine eigende ADOQuery/ADOConnection selber erstellen, nur so ist sichergestellt, dass diese auch im Kontext des Threads läuft!

Also den Connectionstring, sowie den SQL-String an den Thread geben und nicht das ADOQuery selber!.

Irgendwo habe ich nen Sourcecode gesehen, welcher dann das Record-Set Thread Save aus dem Thread an den MainThread zurück gibt, weiß aber nicht mehr wo....

[Schwarzesshaaf666]

Nein, bewusst war mir das nicht. Hab nach dem genannten Code gesucht und ihn hier gefunden. Hab ihn noch etwas angepasst, da ich die Threads irgendwie in OnTerminate identifizieren muss.

Delphi-Quellcode:

type
  TFieldInfoRecord = Record
    DataType: TFieldType;
    Name: String;
    Size: Integer;
    Value: Variant;
    Attributes: TParameterAttributes;
  End;

  TDBThread = class(TThread)
    constructor Create(Const AConnectionString, ASql: string; FDArray: TFieldInfoArray; ARightsPk: Integer);
  private
    FConnectionString, FSql: string;
    FRecordSet: _RecordSet;
    FRightsPk: Integer;
    FFDArray: TFieldInfoArray;
  protected
    procedure Execute; override;
  public
    property RecordSet: _RecordSet read FRecordSet;
    property RightsPk: Integer read FRightsPk write FRightsPk;
  end;

implementation

constructor TDBThread.Create(Const AConnectionString, ASql: string; FDArray: TFieldInfoArray; ARightsPk: Integer);
var
  i: Integer;
begin
  inherited Create(False);

  FConnectionString := AConnectionString;
  FSql := ASql;
  SetLength(FFDArray, Length(FDArray));
  for i := 0 to High(FDArray) do
  begin
    FFDArray[i].DataType := FDArray[i].DataType;
    FFDArray[i].Size := FDArray[i].Size;
    FFDArray[i].Name := FDArray[i].Name;
    FFDArray[i].Value := FDArray[i].Value;
    FFDArray[i].Attributes := FDArray[i].Attributes;
  end;
  FRightsPk := ARightsPk;
end;

procedure TDBThread.Execute;
var
  i: Integer;
begin
  inherited;

  CoInitialize(nil);
  try
    With TADODataSet.Create(nil) do
      try
        try
          CommandTimeOut := 600;
          ConnectionString := FConnectionString;
          Commandtext := FSql;
          Parameters.ParseSQL(FSql, True); // extract parameters
          for i := Low(FFDArray) to High(FFDArray) do // set parametervalues
          begin
            Parameters.ParamByName(FFDArray[i].Name).DataType := FFDArray[i].DataType;
            Parameters.ParamByName(FFDArray[i].Name).Size := FFDArray[i].Size;
            Parameters.ParamByName(FFDArray[i].Name).Value := FFDArray[i].Value;
            Parameters.ParamByName(FFDArray[i].Name).Attributes := FFDArray[i].Attributes;
          end;
          Open;
          FRecordSet := RecordSet; // keep recordset
        except
          on Ex: Exception do
            MessageDlg('Error in Thread: ' + Ex.Message + sLineBreak + 'SQL: ' + FSql, mtError, [mbOK], 0);
        end;
      finally
        Free;
      end;
  finally
    CoUninitialize;
  end;
end;