Sekunden seit 1. Januar 0:00 1970

[Luckie]

So ich bekomme die Sekunden die seit obigen Datum verstrichen sind. Jetzt würde ich gerne diese in ein gescheites Datum umrechnen.
Für ersteres habe ich schon einen Ansatz:

Delphi-Quellcode:

procedure TForm1.ListBox1Click(Sender: TObject);
const
  TAB = #9;
var
  sUser : String;
  ui11 : Pointer;
  ft : TFILETIME;
  st : TSYSTEMTIME;
  ui : ULARGE_INTEGER;
  buf1, buf2 : array[0..255] of Char;
begin
    st.wYear             := 1970;
    st.wMonth            := 1;
    st.wDayOfWeek        := 0;
    st.wDay              := 1;
    st.wHour             := 0;
    st.wMinute           := 0;
    st.wSecond           := 0;
    st.wMilliseconds     := 0;
    SystemTimeToFileTime(st,ft);
    ui.QuadPart := PUserInfo11(ui11)^.usri11_last_logon+ULARGE_INTEGER(ft).QuadPart;
    FileTimeToSystemTime(TFileTime(ui),st);
    GetTimeFormat(LOCALE_USER_DEFAULT, TIME_FORCE24HOURFORMAT, @st, nil, buf1, sizeof(buf1));
    GetDateFormat(LOCALE_USER_DEFAULT, DATE_SHORTDATE, @st, nil, buf2, sizeof(buf2));
    Memo1.Lines.Add('Last-Logon'+TAB+': '+String(buf2)+' / '+String(buf1) );
  end;
  NetAPIBufferFree(ui11);
end;

Nur leider stimmt das:

Zitat:

Last-Logon : 1970-01-01 / 00:01:44

nicht. Da war ich noch nicht mal geboren, geschweige denn dass ich mich da schon an meinem jetztigen Rechner eingeloggt hätte. :shock:

[MrSpock]

Hallo Luckie,

ich war da schon geboren und bin sogar schon zur Schule gegangen. Deshalb kann ich vielleicht helfen :mrgreen: .

Delphi-Quellcode:

 
  with st do
  begin
    Datum := EncodeDate(year, month, Day);
    Zeit := EncodeTime(Hour, Minute, Second, Milliseconds);
  end;

[MathiasSimmack]

Ändert sich was, wenn du den DWORD-Wert als int64 castest, Luckie?
Wie bei INetTime:

Code:

ui.QuadPart := int64(PUserInfo11(ui11)^.usri11_last_logon) +
  ULARGE_INTEGER(ft).QuadPart;

[Luckie]

@MrSpock: Kann ich leider nicht brauchen, da es später nonVCL werden soll.

@Mathias: Hilft leider aich nicht.

Aber ich habe was gefunden.

Delphi-Quellcode:

st.wYear             := 1970;
st.wMonth            := 1;
st.wDayOfWeek        := 0;
st.wDay              := 1;
st.wHour             := 0;
st.wMinute           := 0;
st.wSecond           := 0;
st.wMilliseconds     := 0;
SystemTimeToFileTime(st,ft);
RaiseLastOsError;

RaisLastOSError liefert: "Aufruf einer Systemfunktion fehlgeschlagen." Und das stimmt auch mit meiner Beobachtung über ein. Als Datum bekomme ich nämlich immer das, was ich in die Struktur eintrage.

[Chewie]

Du willst also einen UNIX-Timestamp in eine lesbare Zeitangabe umrechnen? Das hatten wir hier schon mal: http://www.delphipraxis.net/viewtopic.php?t=1030. Im vorletzten Post wurde laut Autor eine Lösung gefunden.

[Luckie]

Danke für den Hinweis. Da gibt es nur ein Probleme, wie ich schon zu Spitzohr gesagt habe, es muß ohne SysUtils gehen.

Der Hinweis von Christian auf die Stelle im PSDK hab eich gefunden, nur leider kennt Delphi kein Int32x32To64.

Zitat:

The time functions included in the C run-time use the time_t type to represent the number of seconds elapsed since midnight, January 1, 1970. The following example converts a time_t value to a file time, using the Int32x32To64 function.

Code:

void TimetToFileTime( time_t t, LPFILETIME pft )
{
    LONGLONG ll = Int32x32To64(t, 10000000) + 116444736000000000;
    pft->dwLowDateTime = (DWORD) ll;
    pft->dwHighDateTime = ll >>32;
}

[MathiasSimmack]

Luckie, schon mal in die "WinNT.h" geguckt?

Code:

#define Int32x32To64(a, b) ((LONGLONG)((LONG)(a)) * (LONGLONG)((LONG)(b)))

Oder, wenn mich mein bisschen Wissen nicht trügt:

Delphi-Quellcode:

function Int32x32To64(const a, b: dword): int64;
begin
  Result := int64(a) * int64(b);
end;

Und zu dem "nichts bringen": vielleicht fehlt in der Logon-Zeit auch das 10-Mio-Intervall? Sprich die Anzahl der 100ns-Intervalle?

[Luckie]

ja, ja, jaaaaa. :P Mathias du bist ein Schatz. :stupid:

Halt alles zurück. Da stimmt was nicht.

Noch mal von vorne. Das habe ich jetzt:

Delphi-Quellcode:

function Int32x32To64(const a, b: dword): int64;
begin
  Result := int64(a) * int64(b);
end;

procedure TForm1.ListBox1Click(Sender: TObject);
const
  TAB = #9;
var
  sUser : String;
  ui11 : Pointer;
  ft : TFILETIME;
  st : TSYSTEMTIME;
  ui : ULARGE_INTEGER;
  li : longint;
  buf1, buf2 : array[0..255] of Char;
begin
  Memo1.Clear;
  sUser := Listbox1.Items.Strings[Listbox1.ItemIndex];
  if sUser <> ''then
  begin
    NetUserGetInfo(nil, PWideChar(WideString(sUser)), 11, ui11);
   {st.wYear             := 1970;
    st.wMonth            := 1;
    st.wDayOfWeek        := 0;
    st.wDay              := 1;
    st.wHour             := 0;
    st.wMinute           := 0;
    st.wSecond           := 0;
    st.wMilliseconds     := 0;
    SystemTimeToFileTime(st,ft);
    ui.QuadPart := int64(PUserInfo11(ui11)^.usri11_last_logon)+ULARGE_INTEGER(ft).QuadPart;
    FileTimeToSystemTime(TFileTime(ui),st);}
    li := Int32x32To64(PUserInfo11(ui11)^.usri11_last_logon, 10000000) + 116444736000000000;
    ft.dwLowDateTime := DWORD(li);
    ft.dwHighDateTime := li shl 32;
    FileTimeToSystemTime(TFileTime(ui),st);
    GetTimeFormat(LOCALE_USER_DEFAULT, TIME_FORCE24HOURFORMAT, @st, nil, buf1, sizeof(buf1));
    GetDateFormat(LOCALE_USER_DEFAULT, DATE_SHORTDATE, @st, nil, buf2, sizeof(buf2));
    Memo1.Lines.Add('Last-Logon'+TAB+': '+String(buf2)+' / '+String(buf1) );
end;
  NetAPIBufferFree(ui11);
end;

Jetzt bin ich schon seit 1601-01-01 / 00:00:00 eingeloggt. :shock:

[nailor]

http://manfred.maday.bei.t-online.de/page6_5.htm

schau dir mal Punkt 10.1 an. Bei korrekten Eingabewerten sollte damit auch eine richtige Umrechnung ohne VCL möglich sein.

[Luckie]

Danke für den Link. Aber es muß auch so mit API-Funktionen gehen.

[Luckie]

Auf Mathias ist doch verlass. :mrgreen:

Hier die Lösung:

Delphi-Quellcode:

function Int32x32To64(const a, b: dword): int64;
begin
  Result := int64(a) * int64(b);
end;

function SecsToDateTime(secs: int64): String;
var
  ft : TFILETIME;
  st : TSYSTEMTIME;
  lt : TSYSTEMTIME;
  li : int64;
  buf1, buf2 : array[0..255] of Char;
begin
  if secs = 0 then
  begin
    result := '';
    exit;
  end;
  st.wYear             := 1970;
  st.wMonth            := 1;
  st.wDayOfWeek        := 0;
  st.wDay              := 1;
  st.wHour             := 1;
  st.wMinute           := 0;
  st.wSecond           := 0;
  st.wMilliseconds     := 0;
  SystemTimeToFileTime(st,ft);
  { Version 1 }
  {ui.QuadPart := Int32x32To64(PUserInfo11(ui11)^.usri11_last_logon, 10000000)
        + 116444736000000000;
  FileTimeToSystemTime(TFileTime(ui),st);
  FileTimeToSystemTime(TFileTime(ui),st);}
  { Version 2 }
  li := Int32x32To64(secs, 10000000) + 116444736000000000;
  ft.dwLowDateTime := DWORD(li);
  ft.dwHighDateTime := li shr 32;
  FileTimeToSystemTime(TFileTime(ft),st);
  SystemTimeToTzSpecificLocalTime(nil, st, lt);
  GetTimeFormat(LOCALE_USER_DEFAULT, TIME_FORCE24HOURFORMAT, @lt, nil, buf1, sizeof(buf1));
  GetDateFormat(LOCALE_USER_DEFAULT, DATE_SHORTDATE, @lt, nil, buf2, sizeof(buf2));
  result := String(buf2)+' / '+String(buf1);
end;

Man, wen ich so langsam schon alles erwähnen muß: Mathias als lebender Debugger, Danial als Tester und Marcel van Brakel als Tester und Helfer. Wenn das so weiter geht, ist die Aboutbox bald größer als das Programmfenster. :mrgreen:

[nailor]

Mir war grad langweilig, und ich wusste nix zu machen (was für eine Verkettung unglücklicher Zwischenfälle :wink: ), also hab ich mal einen Sekunden-Seit-1970-In-Datum-Umrechner gemacht:

Delphi-Quellcode:

var
  input, z, x, a, b, c, d, e, Tag, Monat, Jahr: LongWord;
  {Input sind die Sekunden seit 1970, der Rest Hilfsvariablen bzw. das Ergebnis}
begin
{Den Quelltext, den ich angepasst habe, war in Turbo Pascal
geschrieben (hab ich nie gemacht) aber anscheinend gabs da noch
kein div oder so was. Im Original waren sogar noch alle Werte
Extended und die Befahle INT(X) was einen Extendend zurückgibt.
Da kann man also noch was verbessern.}

{Das Programm scheint zu klappen, nur wenn man die Zahlen zu groß wählt
(so um das Jahr 2106), dann wird es falsch. Auch negative Zahlen sind
nicht zu empfehlen}

input := strtoint64(edit1.Text);

z := Trunc(input / (60 * 60 * 24) + 0.5 + 2440587.5);
x := Trunc((z - 1867216.25) / 36524.25);

a := z + x + 1 - Trunc(x / 4);
b := a + 1524;
c := Trunc((b - 122.1) / 365.25);
d := Trunc(365.25 * c);
e := Trunc((b - d) / 30.6001);

Tag := b - d - Trunc(30.6001 * e);

if e < 14 then
  Monat := e - 1
else
  Monat := e - 13;

if monat > 2 then
  Jahr := c - 4716
else
  Jahr := c - 4715;

Edit2.Text := inttostr(Tag) + '. ' + inttostr(Monat) + '. ' + inttostr(Jahr);
end;

[Luckie]

danke für deien Mühe, aber wie ich schon geschrieben, habe, ich habe schon eine lösung und die halte ich für eleganter, als deine.