Mit PChar arbeiten

[Pseudemys Nelsoni]

hi,

da bin ich wieder 8).

Also ich habe mal eine frage zum thema PChar...

Da ich immer nur mit strings gearbeitet habe (vcl), frag ich mich wie ich mit PChars umzugehen habe, das fällt mir nämlich ziemlich schwer...
Z.B hatte ich eben gerade wieder so ein Problem das ich einen PChar erweitern wollte:

Delphi-Quellcode:

wDir := wDir + 'System32\';

aber das geht natürlich nicht weil "'System32\'" ja ein string ist...

geht das auch ohne hin und her konvertiereri mit string() und PChar() ?

[MathiasSimmack]

Äh, stört´s dich wenn ich antworte? ;)
Keine Sorge, das steht zwar sicher auch in den Tutorials, aber nicht als Extra-Kapitel.

Schau mal im PSDK nach den "lstr*"-Funktionen.
In deinem Fall

Delphi-Quellcode:

lstrcpy(wDir,'c:\windows'); // <-- kopiert "c:\windows" in "wDir"
lstrcat(wDir,'\System32');          // <-- hängt "\System32" an "wDir" an

Wie gesagt, PSDK: lstrcpy, lstrcmp, lstrcat, lstrlen, usw. Meist gibt´s auch Versionen für Widechars, erkennbar am W, bspw. "lstrcpyW" usw.

[MrKnogge]

Zitat:

Zitat von Pseudemys Nelsoni

Delphi-Quellcode:

wDir := wDir + 'System32\';

aber das geht natürlich nicht weil "'System32\'" ja ein string ist...

Ich weis, Mathias hat die antwort jetzt schon gepostet, aber liegt des "Problem" nicht eher an dem + ?

Wenn wDir vom Typ PChar ist, und man zum Beispiel:

Delphi-Quellcode:

wDir := 'System32\'

schreiben würde, ging das doch auch, weil Delphi 'System32\' dann als PChar-Konstante speichert,oder irre ich mich jetzt da :gruebel:

[MathiasSimmack]

Zitat:

Zitat von MrKnogge

Ich weis, Mathias hat die antwort jetzt schon gepostet, aber liegt des "Problem" nicht eher an dem + ?

Ja, durch das Plus meckert der Compiler rum, dass die Typen nicht passen. In einigen Fällen genügt es, wenn man beides noch mal als "pchar" castet:

Delphi-Quellcode:

wDir := pchar(wDir + 'System32\');

Zitat:

Delphi-Quellcode:

wDir := 'System32\'

schreiben würde, ging das doch auch, weil Delphi 'System32\' dann als PChar-Konstante speichert,oder irre ich mich jetzt da :gruebel:

Nein, du hast natürlich recht. Die einfache Zuweisung, wie in deinem Beispiel gezeigt, ist bei Delphi nicht das Problem. Nur wenn die pchar-Variable bereits etwas enthält, und du möchtest noch einen Text anhängen, dann brauchst du entweder die o.g. Funktion, oder du versuchst dein Glück mit dem o.g. Casten. In dem Fall geht es ja darum, dass der schon vorhandene Inhalt von "wDir" nicht entfernt wird. Und das würde er, wenn du einfach nur

Delphi-Quellcode:

wDir := 'System32\';

schreibst.


btw: Über den Sinn, an "wDir" (die Vermutung liegt nahe, dass die Variable den Namen des Windows-Verzeichnisses enthält) noch das Systemverzeichnis anzuhängen, will ich mal nicht streiten. Vielleicht ist das reale Beispiel ein anderes, ansonsten wäre wohl "GetSystemDirectory" eine Idee. :mrgreen:
Aber man kann ja auch programm-intern weiter mit Strings arbeiten. Ich habe für ein Programm bspw. mal den Ordner "%windir%\help" benötigt, und dafür habe ich mir eine Funktion geschrieben, die mir den Ordner wie gewohnt als String zurückliefert:

Delphi-Quellcode:

function GetWinHelpDir: string;
begin
  SetLength(Result,GetWindowsDirectory(nil,0) + 1);
  SetLength(Result,GetWindowsDirectory(@Result[1],length(Result)));

  if(Result <> '') then
    Result := Result + '\help\';
end;

Und damit ließ sich a) gut arbeiten, und b) das Casten nach pchar war im Bedarfsfall auch kein Problem.

[Muetze1]

Moin!

Zitat:

Zitat von MathiasSimmack

In einigen Fällen genügt es, wenn man beides noch mal als "pchar" castet:

Delphi-Quellcode:

wDir := pchar(wDir + 'System32\');

Ich würde aber denn vorschlagen das so zu casten:

Delphi-Quellcode:

wDir := wDir + PChar('System32\');

Was aber genauso wenig laufen würde, da er IMHO hier nur die Adressen zusammen rechnet. Problem bei PChar ist, das es Zeicher auf ein Array von Char ist und Delphi bei Zeigern keine grossen Automatismen mitbringt - er rechnet dann eher mit den Zeigern. Daher nutze die oben beschriebenen lstrcat(), etc Funktionen oder die PChar Funktionen aus der SysUtils (StrCat)...

MfG
Muetze1

[MathiasSimmack]

Ein bisschen aus dem Zusammenhang gerissen, sorry, aber -

Zitat:

Zitat von Muetze1

Was aber genauso wenig laufen würde [...]

Deswegen schrieb ich ja, dass es in einigen Fällen ausreicht nach pchar zu casten. Dabei fallen mir erst mal hauptsächlich Membervariablen von irgendwelchen Records ein, die als pchar deklariert sind. Bspw. der Filter bei "GetOpenFileName/GetSaveFileName". Oder auch die Beschreibung (lpszTitle) bei "SHBrowseForFolder". In solchen Fällen kannst du Strings und PChars nochmal nach pchar casten, was IMHO keine Probleme verursacht.

Blödes Beispiel mit dem Record für "SHBrowseForFolder", aber es geht:

Delphi-Quellcode:

GetMem(bla,MAX_PATH); // var bla : pchar;
try
  ZeroMemory(bla,sizeof(bla));
  lstrcpy(bla,'Hallo, Du! ');


  // "BrowseInfo" mit Werten füllen
  ZeroMemory(@BrowseInfo,sizeof(BrowseInfo));
  { ... }
  BrowseInfo.lpszTitle      := pchar(bla + 'Wähle einen Ordner!');

  // usw.
  { ...}

finally
  FreeMem(bla);
end;

Dagegen würde dein Vorschlag von oben

Delphi-Quellcode:

    BrowseInfo.lpszTitle      := bla + pchar('Wähle einen Ordner');

nicht funktionieren sondern die Compilermeldung

Zitat:

[Fehler] fldbrows.pas(260): Operator ist auf diesen Operandentyp nicht anwendbar

verursachen.

Wenn du allerdings kein pchar benutzt sondern selbst ein Zeichenarray deklarierst und als Ziel benutzt, dann funktioniert beides nicht:

Delphi-Quellcode:

var
  bla  : array[0..MAX_PATH]of char;
begin
  bla  := 'Hallo Du! ';

  // [Fehler] Unit1.pas(31): Inkompatible Typen: 'Array' und 'PChar'
  bla  := pchar(bla + 'Wähle einen Ordner');

  // [Fehler] Unit1.pas(32): Operator ist auf diesen Operandentyp nicht anwendbar
  bla  := bla + pchar('Wähle einen Ordner');
end;

In dem Fall brauchst du API- oder SysUtils-Funktionen.

Es ist also eine Typfrage.
Aber ich nehme an, dass du das auch sagen wolltest?

[Muetze1]

Moin!

Genau das wollte ich sagen - und ich sagte auch extra, das es so genauso wenig laufen würde. Das mit der Compilermeldung war mir auch ohne Compiler klar. Somit meinen wir beide das gleiche und mein vorheriger Post war in dem Sinne unnötig - sorry.

MfG
Muetze1

[MathiasSimmack]

Kein Problem. Lieber einmal mehr und zu ausführlich was schreiben, als einmal zu wenig ... ;)

[Pseudemys Nelsoni]

oha wurde hier viel geschrieben :shock:

Zitat:

Äh, stört´s dich wenn ich antworte? ;)

keinesfalls, bin über jede antwort dankbar :mrgreen:

Zitat:

Schau mal im PSDK nach den "lstr*"-Funktionen.

Werd ich tun, ich glaub 1mal hatte ich die damals auch schon benutzt. Was ich jedoch bei den Funktionen vermisste ist "lstrpos". Irgendwie gibt es keine Pos funktion, das mich wieder zwingt strings zu bennutzen. :\

Zitat:

schreiben würde, ging das doch auch, weil Delphi 'System32\' dann als PChar-Konstante speichert,oder irre ich mich jetzt da :gruebel:

Jo, Zuweisungen klappen problemlos, da Delphi (soweit ich mir das Vorstelle) den String automatisch in einen PChar mit anschliessendem #0 umwandelt. Das Problem war eher das zusammenfügen:

Zitat:

wDir + 'System32\';

von einem PChar/string.

Zitat:

btw: Über den Sinn, an "wDir" (die Vermutung liegt nahe, dass die Variable den Namen des Windows-Verzeichnisses enthält)

korrekt :mrgreen:

Zitat:

ansonsten wäre wohl "GetSystemDirectory" eine Idee

Also die Funktion hatte ich in der Wapi-help auch gefunden, jedoch habe ich nur rausgeleseb das diese den systemordner zurückgibt. Ist sie auch für den System32-ordner?

Zitat:

Ich würde aber denn vorschlagen das so zu casten: : wDir := wDir + PChar('System32\');

Wird das #0 zeichen das wDir ja schon bereits enthält automatisch entfernt und ans Ende gesetzt?



Alles in allem - DANKE für die antworten/tips :thuimb:

[MathiasSimmack]

Zitat:

Zitat von Pseudemys Nelsoni

Also die Funktion hatte ich in der Wapi-help auch gefunden, jedoch habe ich nur rausgeleseb das diese den systemordner zurückgibt. Ist sie auch für den System32-ordner?

Je nach OS liefert sie den korrekten Systemordner zurück. Unter 9x also "System", unter NT/2000/XP "System32". Mit anderen Worten: Ja! ;)

Zitat:

Zitat:

Ich würde aber denn vorschlagen das so zu casten: : wDir := wDir + PChar('System32\');

Wird das #0 zeichen das wDir ja schon bereits enthält automatisch entfernt und ans Ende gesetzt?

Diese Form des Castens (oder Castings?) funktioniert aber nicht, wie auch Muetze1 schon schrieb. Extra aus dem Grund habe ich überhaupt Delphi angeschmissen und hier Beispiele mit den Fehlermeldungen zitiert. Das "Zusammenfügen" von PChar und String funktioniert eigentlich nur (wie oben geschrieben), wenn die Zielvariable selbst vom Typ "pchar" ist. Und dann sollte es nach Möglichkeit nicht die PChar-Variable sein, die du bereits benutzt. ;)

Ein Beispiel hatte ich ja genannt, ansonsten bleib bei "lstrcat" (API-Funktion) oder der passenden SysUtils-Funktion. Das ist der sichere und bessere Weg.

[Pseudemys Nelsoni]

Werd ich machen mathis, danke für die mühe ;). Ging mir da nur mehr ums Prinzip wie das mit dem #0 zeichen ist. :)

Achja, eine weitere Frage habe ich und zwar...PChar kann man ja "einfach so" deklarieren und benutzen, richtig? (scheint ja so)
Wozu gibt es denn Beispiele wie diese hier(aus der Delphi-Hilfe):

Delphi-Quellcode:

var

  F: file;
  Size: Integer;
  Buffer: PChar;
begin
  AssignFile(F, 'test.txt');
  Reset(F, 1);
  try
    Size := FileSize(F);
    GetMem(Buffer, Size);
    try
      BlockRead(F, Buffer^, Size);
      ProcessFile(Buffer, Size);
    finally
      FreeMem(Buffer);
    end;
  finally
    CloseFile(F);
  end;

end;

ich meine wozu ist da Getmem gut wenns auch ohne geht?

[MathiasSimmack]

Das ist anders gemeint -

Wenn du bspw. mit DLLs arbeiten willst/musst, die aber Strings als Parameter erwarten, dann ist normalerweise diese "ShareMem"-Unit notwendig. (War doch so, @all?) Jedenfalls kannst du die Parameter aber auch als "pchar" deklarieren, weil du dann ja keinen Speicher erzeugst, sondern (vereinfacht ausgedrückt; die Profis mögen es mir nachsehen) weil du auf den Speicherbereich der übergebenen "Strings" zugreifst.

Aus dem Grund brauchst du in so einem Fall:

Delphi-Quellcode:

procedure ShowMe(const p: pchar);
begin
  MessageBox(0,p,nil,0);
end;

var
  ca : array[0..MAX_PATH]of char;
  s  : string;
begin
  ca := 'Hallo, Welt!';
  ShowMe(ca);

  s  := 'Hallo, Welt!';
  ShowMe(pchar(s));
end.

keinen Speicher deklarieren, weil ja der pchar (Muetze1 sagte es schon) ein Zeiger auf das Zeichenarray ist.

Anders sieht es aus, wenn du in deinem Programm mit einem PChar arbeiten willst/musst, bspw. wenn du vorher nicht weißt ob ein

Delphi-Quellcode:

  ca : array[0..MAX_PATH]of char;

ausreichen wird. Denke bspw. an "GetWindowsDirectory". Diese Funktion liefert, wenn der Puffer zu klein ist, die Anzahl der benötigten Bytes (= Zeichen) zurück. Nach dem Muster funktioniert ja auch die von mir weiter oben gepostete Funktion, die den "%windir%\help"-Ordner zurückliefert - nur, dass ich dort anstelle des PChar eben den String (Result) benutzt habe.

In so einem Fall musst du den Speicher(bereich) mit "GetMem" erzeugen, sonst ist deine PChar-Variable nur ein Pointer, und jeder Versuch, sie zu verwenden oder mit Inhalt zu füllen, hat einen Fehler zur Folge.

[Pseudemys Nelsoni]

Gut erklät, danke sehr :thuimb:

[MathiasSimmack]

Ich danke dir. :mrgreen:
Hier ist so ein Beispiel:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  p     : pchar;
  dwLen : dword;
begin
  // folgender Witz: Wenn der Puffer zu klein ist, dann
  // liefert "GetWindowsDirectory" die erforderliche
  // Größe zurück, DAS #0-ZEICHEN EINGESCHLOSSEN ...
  dwLen := GetWindowsDirectory(nil,0);
  if(dwLen > 0) then
  begin
    GetMem(p,dwLen);
    try
      ZeroMemory(p,dwLen);

      // ... da der Puffer nun groß genug ist, liefert
      // die Funktion die Anzahl der kopierten Zeichen
      // zurück, die abschließende #0 diesmal NICHT
      // eingeschlossen (deswegen "dwLen - 1")
      if(GetWindowsDirectory(p,dwLen) = dwLen - 1) and
        (p[0] <> #0) then
      MessageBox(0,p,nil,0);
    finally
      FreeMem(p);
    end;
  end;
end;

Wenn du da mal das Erstellen des Speichers weglässt, dann kracht´s ... ;)

[Pseudemys Nelsoni]

So ein Beispiel habe ich gebraucht, ich glaube ich verstehe es hehe 8)

Danke nochmal für das schreiben des Codes :thuimb:

[MathiasSimmack]

Hier hast du noch ein Beispiel (dann hör ich aber auch auf, dich zu nerven) aus der Rubrik: "Es ist zwar ein PChar, aber ..." -

Die Funktion [msdn]"InternetCrackUrl"[/msdn] zerlegt einen Grafen (;)) in seine Bestandteile; sprich: Host, Schema, usw. Die entsprechenden Membervariablen sind zwar als pchar deklariert, allerdings dienen sie hier der Ausgabe der Daten. Das heißt, die Funktion erwartet von dir, dass du einen Puffer bereitstellst, der groß genug ist.

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
const
  szUrl   =
    'http://www.delphipraxis.net/topic28303_profil+temp+verzeichniss.html';
var
  url     : TUrlComponents;
  scheme,
  buf,
  urlpath : array[0..MAX_PATH]of char;
begin
  ZeroMemory(@url,sizeof(url));
  url.dwStructSize     := sizeof(url);

  url.lpszHostName     := buf;
  url.dwHostNameLength := sizeof(buf);
  url.lpszScheme       := scheme;
  url.dwSchemeLength   := sizeof(scheme);
  url.lpszUrlPath      := urlpath;
  url.dwUrlPathLength  := sizeof(urlpath);

  if(InternetCrackUrl(szUrl,length(szUrl),0,url)) then
    MessageBox(0,pchar(Format('Host: %s' + #13#10 + 'Schema: %s' + #13#10 +
    'URL: %s',[buf,scheme,urlpath])),nil,0);
end;

Wenn du denkst, dass das statische Array (0-MAX_PATH) nicht ausreicht, dann kannst du auch hier mit "pchar"-Variablen arbeiten, wobei du dann natürlich den Puffer vorher mit "GetMem" erzeugen musst. Ansonsten rumpelt´s wieder ...

So, genug jetzt. :)