Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Object-Pascal / Delphi-Language (https://www.delphipraxis.net/32-object-pascal-delphi-language/)
-   -   Delphi ein String einem TFont zuweisen (https://www.delphipraxis.net/34974-ein-string-einem-tfont-zuweisen.html)

DymonD 30. Nov 2004 23:49


ein String einem TFont zuweisen
 
Hi,
ich habe mit dem TFontDialog experimentiert und habe folgendes probiert:
Delphi-Quellcode:
procedure TEinstellungen.Button7Click(Sender: TObject);
begin
FontDialog1.Execute;
Label1.Font := FontDialog1.Font;
end;
Nun bin ich soweit gekommen, dass ich den Label1.Font verändern kann (d. h. mit Schriftart, Farbe, Größe, etc.). Dann habe ich mir gedacht, das soll so bleiben, also speichere ich das doch in eine MeinProg.ini (nicht nur das, ich muss das auch mit
Delphi-Quellcode:
ClientSocket1.Socket.SendText(Meinfont);
senden können). Aber wie speichere ich das Format in einen String?

Kann mir da einer helfen?

THX im Voraus

Gruß, Dima

Airblader 1. Dez 2004 05:20

Re: ein String einem TFont zuweisen
 
FontToString()
oder
FontToStr()

weiss es nicht mehr genau :wink:

Jens Schumann 1. Dez 2004 07:29

Re: ein String einem TFont zuweisen
 
Hallo,
Zitat:

Zitat von Airblader
FontToString()
oder
FontToStr()

weiss es nicht mehr genau :wink:

Delphi bringt diese Funktionen nicht mit.

Ich habe es vor langer Zeit mal so gelöst:
Delphi-Quellcode:
function FontToString(Value: TFont) : String;
begin
  Result:='';
  If Assigned(Value) then
    begin
    Result:='Name='+Value.Name+';';
    Result:=Result+'Color='+IntToStr(Value.Color)+';';
    FValue:=Result+'Size='+IntToStr(Value.Size)+';';
    Result:=Result+'Style=[';
    If fsBold in Value.Style then
      Result:=Result+'B';
    If fsItalic in Value.Style then
      Result:=Result+'I';
    If fsUnderLine in Value.Style then
      Result:=Result+'U';
    If fsStrikeOut in Value.Style then
      Result:=Result+'S';
    Result:=Result+']';
    end;
end;

DymonD 1. Dez 2004 18:40

Re: ein String einem TFont zuweisen
 
Hi,
OK, danke schön. Zumindest kann ich das in eine .ini speichern. Und wie wandle ich das Ganze wieder zurück? Oder kann ich einem Label1.Font einen String zuweisen? :wall:

Gruß, Dima

PS: kann ich trotzdem irgendwo StrToFont bzw FontToStr runterladen o. ä.? Ich meine, es ist bequem, nur eine Zeile zu haben :-D

DymonD 1. Dez 2004 19:31

Re: ein String einem TFont zuweisen
 
Hi,
noch was: habe versucht, das Umgekehrte eigenhändig zu erstellen... Leider gab's eine Exception, als ich versucht habe, den String in den TFont umzuwandeln...
Delphi-Quellcode:
function TEinstellungen.StringToFont(Value: String) : TFont;
begin
    begin
    // Schriftart
    Delete(Value, 1, 5); // 'Name=' entfernen
    Result.Name := Copy(Value, 1, pos(';', Value) - 1); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Farbe
    Delete(Value, 1, 7); // ';Color=' entfernen
    Result.Color := StrToInt(Copy(Value, 1, pos(';', Value) - 1)); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Größe
    Delete(Value, 1, 6); // ';Size=' entfernen
    Result.Size := StrToInt(Copy(Value, 1, pos(';', Value) - 1)); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Stil
    Delete(Value, 1, 8); // ';Style=[' entfernen
    if Value[1] = 'B' then begin
      Result.Style := Result.Style + [fsBold];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'I' then begin
      Result.Style := Result.Style + [fsItalic];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'U' then begin
      Result.Style := Result.Style + [fsUnderLine];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'S' then begin
      Result.Style := Result.Style + [fsStrikeOut];
      Delete(Value, 1, 1);
      end;
    end;
end;
Was ist alles falsch?

Gruß, Dima

Stevie 3. Dez 2004 08:37

Re: ein String einem TFont zuweisen
 
Das geht so auch nicht! TFont ist ein Objekt und kein Record, wie man vermuten könnte.
Deshalb müsste man erst Result := TFont.Create machen, aber besser ist es so:
Delphi-Quellcode:
procedure StrToFont(const Name: string; Font: TFont);
begin
  Font.Name := Name;
end;

DymonD 6. Dez 2004 22:13

Re: ein String einem TFont zuweisen
 
Hi,
ok, erstens:
werden hier die ganzen Einstellungen in dem String gespeichert, wie Farbe und so oder nur die Schriftart? Ich brauche ja Farben, Größe, etc. -> siehe MSN Messenger

Ich kann natürlich auch mehrere Strings hintereinander schicken, aber das ist Dummfug.. würde schon gerne so machen:
Delphi-Quellcode:
// im Moment:
ClientSocket1.Socket.SendText(NickName + '#' + MyMessage);

// soll werden:
ClientSocket1.Socket.SendText(NickName + '#' + FontProfile + '#' + MyMessage);
Gruß, Dima

SirThornberry 6. Dez 2004 22:28

Re: ein String einem TFont zuweisen
 
Zitat:

Zitat von DymonD
Delphi-Quellcode:
procedure TEinstellungen.Button7Click(Sender: TObject);
begin
FontDialog1.Execute;
Label1.Font := FontDialog1.Font;
end;

richtiger wäre
Delphi-Quellcode:
  if FondDialog1.Execute then
    Label1.Font := FontDialog1.Font;
ansonsten würde die font auch dem Label zugewiesen werden wenn der Dialog abgebrochen wird.

jim_raynor 7. Dez 2004 05:50

Re: ein String einem TFont zuweisen
 
Zitat:

Zitat von DymonD
Hi,
ok, erstens:
werden hier die ganzen Einstellungen in dem String gespeichert, wie Farbe und so oder nur die Schriftart? Ich brauche ja Farben, Größe, etc. -> siehe MSN Messenger

Ich kann natürlich auch mehrere Strings hintereinander schicken, aber das ist Dummfug.. würde schon gerne so machen:
Delphi-Quellcode:
// im Moment:
ClientSocket1.Socket.SendText(NickName + '#' + MyMessage);

// soll werden:
ClientSocket1.Socket.SendText(NickName + '#' + FontProfile + '#' + MyMessage);
Gruß, Dima

Ja wo ist denn jetzt das Problem? Die Funktionen zum Konvertieren Font<->String wurden doch hier aufgezeigt. Um den String auseinanderzusplitten musst du dir nur mal Pos und Copy/Delete anschauen. Oder die Explode-Funktion aus der Codelib.

DymonD 8. Dez 2004 22:50

Re: ein String einem TFont zuweisen
 
Hi,
Das Problem ist, dass ich weiß nicht, was jetzt Sache ist! das hier:
Delphi-Quellcode:
function TEinstellungen.StringToFont(Value: String) : TFont;
begin
Result := TFont.Create(Self);
    begin
    // Schriftart
    Delete(Value, 1, 5); // 'Name=' entfernen
    Result.Name := Copy(Value, 1, pos(';', Value) - 1); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Farbe
    Delete(Value, 1, 7); // ';Color=' entfernen
    Result.Color := StrToInt(Copy(Value, 1, pos(';', Value) - 1)); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Größe
    Delete(Value, 1, 6); // ';Size=' entfernen
    Result.Size := StrToInt(Copy(Value, 1, pos(';', Value) - 1)); // Den String bis zum ';' kopieren'
    Delete(Value, 1, pos(';', Value) - 1); // Das kopierte Stück entfernen
    // Stil
    Delete(Value, 1, 8); // ';Style=[' entfernen
    if Value[1] = 'B' then begin
      Result.Style := Result.Style + [fsBold];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'I' then begin
      Result.Style := Result.Style + [fsItalic];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'U' then begin
      Result.Style := Result.Style + [fsUnderLine];
      Delete(Value, 1, 1);
      end;
    if Value[1] = 'S' then begin
      Result.Style := Result.Style + [fsStrikeOut];
      Delete(Value, 1, 1);
      end;
    end;
end;
oder
Delphi-Quellcode:
procedure StrToFont(const Name: string; Font: TFont);
begin
  Font.Name := Name;
end;
wogegen hier nur die Schriftart gespeichert wird. Oder soll ich die oben genannten Beispiele anwenden und mir keinen Kopf sondern einen elend langen Quelltext machen? :wall:
Besser wäre natürlich das:
Delphi-Quellcode:
FontToStr(MeinFont);
// bzw.
StrToFont(MeinString);
// also halt wie
StrToInt('16');
Gruß, Dima
:kotz:

jim_raynor 9. Dez 2004 06:22

Re: ein String einem TFont zuweisen
 
Nun soweit mir bekannt ist gibt es keine vorgefertigte Funktion dafür. Deshalb musst du wohl oder übel den langen Quelltext (wenn du alle Daten nutzen möchtest) benutzen. Allerdings kannst du ihn doch in eine Funktion auslagern (am besten in einer eigenen Unit). Dann kannst du von überall diese Funktion aufrufen.

DymonD 11. Dez 2004 11:09

Re: ein String einem TFont zuweisen
 
das heißt die beiden quellcodes werden funktionieren?
(muss noch delphi neu installieren :lol: )

gruß, dima

Jens Schumann 12. Dez 2004 18:56

Re: ein String einem TFont zuweisen
 
Liste der Anhänge anzeigen (Anzahl: 1)
Hallo,
ich habe hier noch eine Möglichkeit anzubieten.
TFont ist ein Nachfahre von TPersistent. Also muss man irgendwie das
Delphi-Streamingsystem benutzen können. Angeregt durch einen anderen
Thread (wie nicht mehr wo) habe ich jetzt folgenden Vorschlag.
Für die Lösung werden wir ObjectTextToBinary und ObjectBinaryToText verwenden.

Hier die Funktion, die das Objekt in einen String konvertiert
Delphi-Quellcode:
Type
  TPersistentDummyComponent = class(TComponent)
  private
    FPersistent: TPersistent;
  published
    property Persistent : TPersistent read FPersistent write FPersistent;
  end;
...
function PersitentToString(Persistent : TPersistent): string;
var
  BinStream      : TMemoryStream;
  StrStream      : TStringStream;
  s              : string;
  FPersitentDummy : TPersistentDummyComponent;
begin
  FPersitentDummy:=TPersistentDummyComponent.Create(Nil);
  BinStream := TMemoryStream.Create;
  try
    FPersitentDummy.Persistent:=Persistent;
    StrStream := TStringStream.Create(s);
    try
      BinStream.WriteComponent(FPersitentDummy);
      BinStream.Seek(0, soFromBeginning);
      ObjectBinaryToText(BinStream, StrStream);
      StrStream.Seek(0, soFromBeginning);
      Result:= StrStream.DataString;
    finally
      StrStream.Free;
    end;
  finally
    FPersitentDummy.Free;
    BinStream.Free
  end;
end;
Die Funktion erwartet einen Parameter der Klasse TPersistent. Da TFont ein Nachfahre von
TPersistent ist, ist das auch kein Problem.
Da die Methode WriteComponent eine Komponente als Parameter erwartet, können wir den
Parameter Persistent nicht direkt verwenden. Dafür habe ich mir eine Dummyklasse (TPersistentDummyComponent) gebastelt. Diese Klasse hat die published (nur published properties werden automatisch gestreamt) property Persistent. Nach
Delphi-Quellcode:
FPersitentDummy.Persistent:=Persistent;
hängt unser Paramter (also das Objekt, das wir in einen String verwandel wollen) an TPersistentDummyComponent. Dann wird ein bisschen getreamt und anschließend mit ObjectBinaryToText ein String daraus gemacht.
Die Funktion StringToPersitent geht jetzt den umgekehrten Weg. Value ist das Objekt als String
und der Parameter Persistent eine Referenz auf ein gültiges Objekt. Mit dieser Funktion kan das Objekt aus dem String wieder hergestellt werden.
Delphi-Quellcode:
function StringToPersitent(Value: string; Persistent : TPersistent): TPersistent;
var
  StrStream : TStringStream;
  BinStream : TMemoryStream;
  FPersitentDummy : TPersistentDummyComponent;
begin
  FPersitentDummy:=TPersistentDummyComponent.Create(Nil);
  FPersitentDummy.Persistent:=Persistent;
  StrStream := TStringStream.Create(Value);
  try
    BinStream := TMemoryStream.Create;
    try
      ObjectTextToBinary(StrStream, BinStream);
      BinStream.Seek(0, soFromBeginning);
      Result:=(BinStream.ReadComponent(FPersitentDummy) as TPersistentDummyComponent).Persistent;
    finally
      BinStream.Free;
    end;
  finally
    FPersitentDummy.Free;
    StrStream.Free;
  end;
end;
Die Funktionen finden sich in der unit PersistentStr.pas.

Beispiel -> siehe Anlage

Ach ja - man natürlich nicht nur TFont in einen String konvertieren, sondern auch jeden Nachfahren von TPersistent.

DymonD 12. Dez 2004 22:06

Re: ein String einem TFont zuweisen
 
hi,
o-kay, thx, ich versuche was damit anzufangen ;-)

danke für die mühe!!!!!!!
gruß, Dima

Interceptor 12. Dez 2004 23:15

Re: ein String einem TFont zuweisen
 
Ich glaub ich hab da was schönes für dich :???:
Exakt das selbe Problem wie du hatte ich vor einiger Zeit auch, bis ich auf dieses schöne Stück Code gestoßen bin :wink:

Font -> String
Delphi-Quellcode:
function FontToString(Font: TFont): string;
begin
  Assert(Assigned(Font));
  // name, size, bold, italic, underline, strikethrough, colour
  Result := Format('%s,%d,%d%d%d%d,%s', [Font.Name, Font.Size,
    Integer(fsBold in Font.Style), Integer(fsItalic in Font.Style),
      Integer(fsUnderline in Font.Style), Integer(fsStrikeOut in Font.Style),
      ColorToString(Font.Color)]);
end;
String -> Font
Delphi-Quellcode:
procedure StringToFont(Str: string; Font: TFont);
const
  SEP = ',';
var
  i: Integer;
begin
  Assert(Assigned(Font));
  i := Pos(SEP, Str);
  if i = 0 then raise EConvertError.Create(EXCEPT_MSG1);
  Font.Name := Copy(Str, 1, i - 1);
  Delete(Str, 1, i);
  i := Pos(SEP, Str);
  if i = 0 then raise EConvertError.Create(EXCEPT_MSG1);
  Font.Size := StrToInt(Copy(Str, 1, i - 1));
  Delete(Str, 1, i);
  if Pos(SEP, Str) <> 5 then raise EConvertError.Create(EXCEPT_MSG1);
  Font.Style := [];
  if Str[1] = '1' then
    Font.Style := Font.Style + [fsBold];
  if Str[2] = '1' then
    Font.Style := Font.Style + [fsItalic];
  if Str[3] = '1' then
    Font.Style := Font.Style + [fsUnderline];
  if Str[4] = '1' then
    Font.Style := Font.Style + [fsStrikeOut];
  Delete(Str, 1, 5);
  Font.Color := StringToColor(Str);
end;
Hoffe ich konnte helfen!

Schöne Vorweihnachtszeit,
Interceptor

DymonD 13. Dez 2004 13:39

Re: ein String einem TFont zuweisen
 
Hi,
Mann, ich werde ja bombardiert mit Beiträgen! :lol:
Danke euch!! Ich werde natürlich alle Funktionen in eine Unit sammeln und zum Download anbieten.

Frohe Weihnachten & einen Guten Rutsch!!


Alle Zeitangaben in WEZ +1. Es ist jetzt 19:33 Uhr.

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz