Problem mit Integer zu Binär

[PierreB]

Moin,

mittels folgendem Code (Danke an Luckie :thumb: ) wandle ich Integerzahlen ins Binärformat um:

Code:

function IntToBin(Int: Integer): String;
var
  i : Integer;
begin
  Result := '';
  for i := 7 downto 0 do
  Result := Result + IntToStr((Int shr i) and 1);
end;

Es kunktioniert auch alles gut, nur leider steht dann bei der Ausgabe z.b. wenn ich 7 umrechne erhalte ich: 00000111. Wie kann ich aber die überflüssigen Nullen vor der eigentlichen Zahl löschen? Also das nur die "richtige" Zahl, in dem Falle 111 da steht ?

Vielen Dank,

[Matze]

Entweder im String direkt löschen (Delete, Pos) oder mittels Format.

[PierreB]

Ja, mit Pos und Delete hab ichs schonmal versucht, aber leider waren dann alle Nullen weg. Das Problem ist auch das, dass ich ja nicht weiß wann die "richtige" Zahl beginnt...

[s14]

Vielleicht geht's mit

Delphi-Quellcode:

While Pos('0', s) = 1 do Delete(s, 1, 1)

S ist natürlich der String.

[SubData]

Mit dieser Funktion macht er keine Nullen voran:

Delphi-Quellcode:

function DezToBin(Zahl: Int64): String;
begin
  Result:='';
  repeat
    if Zahl mod 2 =0 then
    begin
      Result := '0' + Result;
    end else
    begin
      Result := '1' + Result;
    end;
    Zahl := Zahl div 2;
  until Zahl = 0;
end;

[PierreB]

Code:

(Zahl: Int64)

Hm, is das Integer64 ? Gibs das in D3 schon ??
Mein D3 sagt undefinierter Bezeichner ! :(

[Matze]

Dann nimm doch einfach integer. ;)

[PierreB]

Ok, vielen Dank ! :thumb:

[czapie]

Zitat:

Das Problem ist auch das, dass ich ja nicht weiß wann die "richtige" Zahl beginnt

Na wenn du von links durchgehst, wenn die erste 1 kommt, bzw. wenn nur noch ein Zeichen übrig was null ist.

[Kedariodakon]

Hier was fixes...
glaub ich :zwinker:

Delphi-Quellcode:

Function   IntToBinString( Const Value:   Integer; Trim: Boolean = False ): String;
Var   i:         Byte;
Begin
   SetLength( Result, 32 );
   For   i := 31 Downto 0 Do Begin
      If ( Value And ( $80000000 Shr ( 31 - i ) )Shr i ) = 1
         Then Result[ 32 - i ] := '1'
         Else Result[ 32 - i ] := '0';
   End;
   If Trim Then Result := Copy( Result, Pos( '1', Result ), Length( Result ) );
End;

Bye

[Kedariodakon]

Noch besser:

Delphi-Quellcode:

Function IntToBinString( Const Value:   Integer; Trim: Boolean = False ): String;
Var i:   Byte;
Begin
   SetLength( Result, 32 );
   For   i := 31 Downto 0 Do Begin
      If ( Value And ( 1 Shl i ) Shr i ) = 1
         Then Result[ 32 - i ] := '1'
         Else Result[ 32 - i ] := '0';
   End;
   If Trim Then Result := Copy( Result, Pos( '1', Result ), Length( Result ) );
End;

Oder gleich so: :zwinker:

Delphi-Quellcode:

Function IntToBinString( Const Value:   Integer; Trim: Boolean = False ): String;
Var i:   Byte;
Begin
   SetLength( Result, 32 );
   For   i := 31 Downto 0 Do Begin
      Result[ 32 - i ] := Chr( ( Value And ( 1 Shl i ) Shr i ) + $30 );
   End;
   If Trim Then Result := Copy( Result, Pos( '1', Result ), Length( Result ) );
End;

viel Spass damit :mrgreen:

bye

[PierreB]

Wow, funzt gut.

Thanx ;)

Falls Interesse besteht, würde ich mein Programm auch in der DP veröffentlichen...

[negaH]

Delphi-Quellcode:

function Bin(Value: Cardinal): String;
const
  Digit: array[Boolean] of Char = ('0', '1');
begin
  Result := '';
  while Value <> 0 do
  begin
    Result := Digit[Odd(Value)] + Result;
    Value := Value shr 1;
  end; 
end;

Sorry, aber eure Sourcen sind manchmal echt vorn Ar... :) Soll keine Beleidigung sein sondern nur ein Hinweis darauf das man in PASCAL wirklich einfach und elegant programmieren kann.

Gruß Hagen