RC4 verschlüsselt keinen Punkt im String

[Nicolai1234]

Hallo. Ich benutze für eine RC4 Verschlüsselung die Unit aus der CodeLibrary von Hagen.

Wenn ich nun den String

Code:

mail.domain.tld

verschlüsseln möchte, geht das auch ihne Fehler. Beim entschlüsseln dagegen kommt nach dem 2. Punkt im String ein Fehler.
Woran kann sowas liegen?

[DP-Maintenance]

Dieses Thema wurde von "sakura" von "Programmieren allgemein" nach "Sonstige Fragen zu Delphi" verschoben.
Das ist doch eine Delphi-Frage.

[sakura]

Setze bitte noch die korrekte Sprach-Info (also Personality) - das ist doch eine Delphi-Frage :zwinker:

...:cat:...

[shmia]

Mach doch mal eine Testfunktion zum Beweisen des Fehlers.
Das nennt man übrigens Unit Tests
Hier mal eine grobe Vorlage:

Delphi-Quellcode:

procedure Teste_RC4;
var
   s, t : string;
begin
   s := 'ein Teststring ohne Punkt';
   t := RC4_encode(s);

   // entschlüsselter String muss gleich dem Orginal sein
   Assert(s = RC4_decode(t));

   // 2. Test
   s := 'mail.domain.de';
   t := RC4_encode(s);

   // entschlüsselter String muss gleich dem Orginal sein
   Assert(s = RC4_decode(t));
end;

[Nicolai1234]

Das brauch idch nicht wirklich, denn ich weiß ja, dass es da einen Fehler gibt. Also habe ich es ja schn "bewiesen"...

[shmia]

Zitat:

Zitat von Nicolai1605

Das brauch idch nicht wirklich, denn ich weiß ja, dass es da einen Fehler gibt. Also habe ich es ja schn "bewiesen"...

Du hast es nicht kapiert! :wall:
Softwarefehler müssen immer bewiesen werden.

Es nützt rein gar nichts, wenn du weisst, dass da ein Fehler ist.
Man braucht ein "Testbett" um den Fehler dann auch auszumerzen.
Wenn eine Testbett vorhanden ist, wird die Fehlersuche um Welten vereinfacht.

Das ist übrigens der Unterschied zwischen einem Coder und einem Softwareentwickler:

• Der Coder hackt irgendwas in die Tastatur bis es irgenwie funkt
• Der Softwareentwickler denkt gründlich nach, schreibt zuerst ein Testbett und dann seinen Code;
  er testet seine Software bis alle Fehler eliminiert sind.

[Binärbaum]

Zitat:

Zitat von shmia

Der Softwareentwickler ... testet seine Software bis alle Fehler eliminiert sind.

Wirklich alle Fehler? Dann sind das bei Microsoft wohl auch nur alles Coder :mrgreen:
Um sicher zu gehen, dass alle Fehler eliminiert sind, muss man (mathematisch) beweisen, dass das Programm fehlerfrei ist. Das Testen alleine reicht nur, um zu zeigen, dass Fehler vorhanden sind, nicht jedoch um zu zeigen, dass sie nicht vorhanden sind. :wink:

MfG
Binärbaum

[negaH]

WO in der CodeLibrary findest du einen Source der RC4_Encode() und RC4_Decode() benutzt ?
Link wenn möglich, undbevor man meint das der Fehler in dem Code anderer liegt sollte man bei sich suchen, meinst du nicht ?

Gruß Hagen

[Nicolai1234]

Zitat:

Zitat von negaH

...und bevor man meint das der Fehler in dem Code anderer liegt sollte man bei sich suchen, meinst du nicht ?

Ich wollte ja nicht sagen, dass der Fehler bei dir liegt, aber ich habe halt diese Unit benutzt und habe das gesagt.

Die Unit ist hier:
http://www.delphipraxis.net/internal...ct.php?t=30830

Mehr hab ich nicht behauptet :roll:

[negaH]

Ja richtig, und WO steht dort was von RC4_Encode() und RC4_Decode() ?
Ich muß ziemlich taub auf meinen Augen sein.

Ok, Spaß beiseite: dein obiges Beispiel hat keinerlei Bezug auf den RC4 Code den man in der CodeLib finden kann. In der CodeLib findet man auch Anwendungsbeispiele die garnatiert funktionieren. Falls du diesen Source verwendet haben solltest so kann ich dir garantieren das es nicht an den RC4 Funktionen liegen kann.

Und schwups, wären wir bei einem aussagekräftigem Beispiel, in Source, das deine Behauptungen real untermauert.

Gruß Hagen

[Nicolai1234]

???

Ich habe nirgends ein Codebeispiel gemacht. Das war jemand anders.

[negaH]

Ok shit, es war Shima's Beispiel sehe ich gerade, auch gut und sorry.

Trotzdem, mach eines und ich werde es analysieren.

Der von mir gemachte RC4 Source läuft bei mir schon 3 Jahre in verschiedenen Anwendungen, und nicht nur in Delphi Programmen sondern zb. auch auf Palm Handhelds die mit PocketStudio und CodeWarrior programmiert wurden. Bisher keine Fehler und deshalb gehe ich mal davon aus das du irgendwo einen Fehler gemacht haben musst.

Desweiteren sagst du zwar WAS du ver/entschlüsseln willst, nur nützt dasüberhaupt nichts wenn man das Passwort nicht dazu hat. Bedenke: anderes Passwort + "mail.schummel.de" ergibt andere Verschlüsselung, entschlüsselt wird also auch anders.

Gruß Hagen

[Nicolai1234]

Oh sorry. ich sehe gerade, dass ich das vor einiger Zeit mal etwas erweitert habe und da wird wahrscheinlich der Fehler liegen:
Ganz unten habe ich damals die funtionen Encode und Decode hinzugefügt. Kannst du da mal schauen? Da muss der Fehler eigentlich sein.

Delphi-Quellcode:

unit HagEnCode;

//Encode -> verschlüsseln
//Decode -> entschlüsseln


// Code written by Hagen ([url]http://www.delphipraxis.net/topic12881,15.html[/url]) 

// unit created by maximov 29.07.2004 

interface 

type 
  TRC4Context = record 
    D: array[Byte] of Byte; 
    I,J: Byte; 
  end; 
  
procedure RC4Init(var RC4: TRC4Context; const Key: String);
procedure RC4Code(var RC4: TRC4Context; const Source; var Dest; Count: Integer); overload;
function  RC4Code(var RC4: TRC4Context; const Value: String): String; overload;
function  RC4Code(const Value, Password: String): String; overload;
procedure RC4Done(var RC4: TRC4Context);
function encode(S, PW: string): string;
function decode(S, PW: string): string;


procedure RC4Seed(const Seed: String); 
function TRC4Random: Cardinal; 

implementation 

type  
  PByteArray = ^TByteArray; 
  TByteArray = array[0..($FFFF shr 1)-1] of byte; 

var 
  RC4Random: TRC4Context; 


function RC4Code(var RC4: TRC4Context; const Value: String): String; overload; 
var 
  Count: Integer; 
begin 
  Count := Length(Value); 
  SetLength(Result, Count); 
  RC4Code(RC4, Value[1], Result[1], Count); 
end; 

function RC4Code(const Value, Password: String): String; overload; 
var 
  RC4: TRC4Context; 
begin 
  RC4Init(RC4, Password); 
  try 
    Result := RC4Code(RC4, Value); 
  finally 
    RC4Done(RC4); 
  end; 
end; 


procedure RC4Init(var RC4: TRC4Context; const Key: String); 
var 
  R,S,T,K: Byte; 
  U,L: Integer; 
begin 
  L := Length(Key); 
  with RC4 do 
  begin 
    I := 0; 
    J := 0; 
    for S := 0 to 255 do D[S] := S; 
    R := 0; 
    U := 0; 
    for S := 0 to 255 do 
    begin 
      if U < L then K := PByteArray(Key)[U] else K := 0; 
      Inc(U); 
      if U >= L then U := 0; 

      Inc(R, D[S] + K); 
      T    := D[S]; 
      D[S] := D[R]; 
      D[R] := T; 
    end; 
  end; 
end; 

procedure RC4Code(var RC4: TRC4Context; const Source; var Dest; Count: Integer); 
var 
  S: Integer; 
  T: Byte; 
begin 
  with RC4 do 
    for S := 0 to Count -1 do 
    begin 
      Inc(I); 
      T := D[I]; 
      Inc(J, T); 
      D[I] := D[J]; 
      D[J] := T; 
      Inc(T, D[I]); 
      TByteArray(Dest)[S] := TByteArray(Source)[S] xor D[T]; 
    end; 
end; 

procedure RC4Done(var RC4: TRC4Context); 
begin 
  FillChar(RC4, SizeOf(RC4), 0); 
end; 





procedure RC4Seed(const Seed: String); 
begin 
  RC4Init(RC4Random, Seed); 
end; 

function TRC4Random: Cardinal; 
type 
  PRC4Cast = ^TRC4Cast; 
  TRC4Cast = record 
    FirstSBOX: Cardinal; 
  end; 

begin 
// verschlüssele die dynamsiche SBOX von RC4Random.D mit sich selber und gebe die 4 ersten Bytes
// als Zufallswert zurück !! 
  RC4Code(RC4Random, RC4Random.D, RC4Random.D, SizeOf(RC4Random.D)); 
  Result := PRC4Cast(@RC4Random).FirstSBOX; 
end;

function encode(S, PW: String): string;
var x: TRC4Context;
  str1, str2: string;
begin
  str1 := s;
  setLength(str2,length(str1));

  RC4Init(x,pw);
  RC4Code(x, str1[1], str2[1], Length(str1)); // verschlüsseln
  Rc4Done(x);

  result := str2;
end;

function decode(S, PW: string): string;
var x: TRC4Context;
  str2, str3: string;
begin
str2 := s;
setLength(str3,length(str2));

  RC4Init(x, pw);
  RC4Code(x, str2[1], str3[1], Length(str2)); // entschlüsseln
  Rc4Done(x);

  result := str3;

end;

initialization 
  RC4Seed('5C103319-9C6F-4F88-BBDC-752779958047'); 
  
finalization 

end.

[negaH]

Ich kann erstmal keine Fehler erkennen. Poste dein Passwort und deinen nicht korrekt zu entschlüsselenden String, vorher brauch ich garnicht anfangen zu testen, nochmal: Passwort und Testvektoren

Allerdings würde ich deinen Code anders "schreiben", du benötigst keine separate Funktion zur Verschlüsselung und Entschlüsselung mit RC4.

Delphi-Quellcode:

function RC4Encode(const Value, Password: String): String; overload;
begin
  Result := RC4Code(Value, Password);
end;

function RC4Decode(const Value, Password: String): String; overload;
begin
  Result := RC4Code(Value, Password);
end;

wie du siehst

Delphi-Quellcode:

function RC4Code(const Value, Password: String): String; overload;

macht schon alles was du benötigst und deine separaten Encode()/Decode() Funktionen sind überflüssig. Ich würde sogesehen garnichts neu "schreiben" sondern einfach nur die Funktionen direkte benutzen wie sie sind.
Zudem, schaue dir mal RC4Code(const Value, Password: String) ganz genau an. Du erkennst das die Parameter als const deklariert wurden, du erkennst das nach einer lokalen var Deklaration ein Zeileumbruch und 2 Zeichen Einrückungen existieren, du erkennst das eine "allozierte" Resource wie var RC4: TRC4Context durch ein try finally Block auch geschützt wieder freigegeben wird, du erkennst das diese Funktion auf modulare Subfunktionen zurückgreift -> sprich modular programmiert wurde, Du erkennst eine ordentliche Namensgebung samt Groß-Kleinschreibung in den Parametern und Variablen. Alles in allem erkennst du einen sauberen Pascal Programmierstil.
Das soll jetzt nicht als Kritik oder Besserwisserisch rüberkommen, sondern als Hinweise darauf woran du bei deinem Programmierstil noch arbeiten könntest.

Besonders weil in deinem Posting ganz oben als Kommentar MEIN Name auftaucht und ein anderer Leser dieses Postings meinen könnte ICH hätte die Funktionen encode() und decode() programmiert. Ehrlich gesagt würde mich das beleidigen :)

Gruß Hagen