Mit SaveToFile Daten an eine Datei anhängen?

[meierotto]

Bin immer noch bei RichEdit :?

Ist es möglich, mit SaveToFile den Inhalt eines Richedit-Feldes an eine vorhandene Datei anzuhängen?
Und wenn nein, wie könnte ich das sonst realisieren?
Mit append hab ichs schon versucht, leider habe ich es so aber noch nicht hinbekommen, dass die Formatierungen mitgespeichert werden.

Dank im Voraus! :)

[Flocke]

Öffne einen TFileStream mit der Datei, mach ein Seek ans Ende und benutze SaveToStream.

[alzaimar]

Das wird nicht gehen (denke ich). Ich glaube, Du musst den Inhalt der Datei in ein TRichMemo einlesen, den Text hinten ran kleben und dann alles wieder abspeichern... Du kannst Dir auch die RTF-Datei parsen (naja, die Präambel extrahieren reicht), dann den Text hintenran und alles mit der Präambel zusammen wieder abspeichern: RTF ist ja nur Text...

[meierotto]

:wiejetzt: Bitte, bitte, könnt ihr das nochmal etwas genauer erklären? Am besten mit Delphi-Code?

[freak4fun]

Hallo :hi:

Von welchen Typ ist denn die Datei, an die du den Text aus deinem RichEdit ranhängen möchtest. Das wäre auch noch recht hilfreich. :)

MfG
freak

[meierotto]

:hi: Hallo zurück freak4fun

Es handelt sich um eine RTF-Datei.

[Flocke]

.... uuups, das hab' ich ja voll verpeilt.

Du nimmst am besten ein zweites RichEdit-Control (versteckt) und diese Routine:

Delphi-Quellcode:

uses
  RichEdit;

// Hilfsroutine für AddRtfFromStream
function _AddRtfCallback(dwCookie: Longint; pbBuff: PByte;
  cb: Longint; var pcb: Longint): Longint; stdcall;
begin
  try
    Result := 0;
    pcb := TStream(dwCookie).Read(pbBuff^, cb);
  except
    Result := 1;
  end;
end;

// Ersetzt die aktuelle Auswahl durch den Inhalt des Streams
procedure AddRtfFromStream(RichEdit: TCustomRichEdit; Stream: TStream);
var EditStream: TEditStream;
begin
  EditStream.dwCookie := LongInt(Stream);
  EditStream.dwError := 0;
  EditStream.pfnCallback := @_AddRtfCallback;

  RichEdit.Perform(EM_STREAMIN, SF_RTF + SFF_SELECTION, LongInt(@EditStream));
  if EditStream.dwError <> 0 then
    raise Exception.Create('RichEdit operation fehlgeschlagen!');
end;

Und dann gehst du etwa wie folgt vor (Pseudocode):

Delphi-Quellcode:

RichEdit2.LoadFromFile(DieAlteDatei);
RichEdit1.SaveToStream(TemporärerMemoryStream);
AddRtfFromStream(RichEdit2, TemporärerMemoryStream);
RichEdit2.SaveToFile(DieNeueDatei);

[meierotto]

:? Ups. Sorry Flocke. Vielleicht hätte ich noch erwähnen sollen, dass ich mit dem Jedi-Richedit arbeite. Und damit läuft dein angegebener Vorschlag leider nicht :(

[Flocke]

Ist ja noch einfacher, JvRichEdit hat nämlich die Eigenschaft "StreamMode".

Delphi-Quellcode:

RichEdit2.LoadFromFile(DieAlteDatei);
RichEdit1.SaveToStream(TemporärerMemoryStream);
RichEdit2.StreamMode := RichEdit2.StreamMode + [smSelection];
RichEdit2.LoadFromStream(TemporärerMemoryStream);
RichEdit2.StreamMode := RichEdit2.StreamMode - [smSelection];
RichEdit2.SaveToFile(DieNeueDatei);

[Nachtrag]

An sich müsste mein alter Vorschlag auch laufen, du musst dann nur den Typen von TCustomRichEdit auf TJvRichEdit ändern.

Oder alternativ so:

Delphi-Quellcode:

// Ersetzt die aktuelle Auswahl durch den Inhalt des Streams
procedure AddRtfFromStream(RichEditHandle: THandle; Stream: TStream);
var EditStream: TEditStream;
begin
  EditStream.dwCookie := LongInt(Stream);
  EditStream.dwError := 0;
  EditStream.pfnCallback := @_AddRtfCallback;

  SendMessage(RichEditHandle, EM_STREAMIN, SF_RTF + SFF_SELECTION, LongInt(@EditStream));
  if EditStream.dwError <> 0 then
    raise Exception.Create('RichEdit operation fehlgeschlagen!');
end;

und dann aufrufen mit AddRtfFromStream(RichEdit2.Handle, TemporärerMemoryStream);

[meierotto]

:oops: Nochmal ups Flocke
Was ich auch nicht erwähnt habe - ich muss im Moment mit Delphi 7 arbeiten. Kann es sein, dass es dort TEditStream nicht gibt? Mit TMemoryStream habe ich es probiert, da überschreibt er aber alles, was vorher eingelesen wurde.
Bei mir funktioniert es übrigens mit Copy-Paste wie folgt:

Delphi-Quellcode:

RichEdit2.Lines.Append(chr(13));  //Ans Ende springen
RichEdit1.SelectAll;
RichEdit1.CopyToClipboard;
RichEdit2.PasteFromClipboard;

Deine vorgeschlagene Möglichkeit mit den Streams wäre aber mit Sicherheit besser, wenns bei mir nur funktionieren würde. :wink:

[freak4fun]

Hallo :hi:,
TEditStream gibt es in Delphi7 nicht, da hast du recht. ;)
Da sieht man mal wieder wie wichtig es ist, so viel Angaben wie Möglich zu machen, um Missverständnisse zu vermeiden. Dadurch kann man sich viel Arbeit, Nerven und Zeit sparen. :mrgreen:

MfG
freak

[Flocke]

Delphi-Quellcode:

uses RichEdit;

Diese Zeile übersehen?
Diese Unit gibt's schon bei Delphi 5 und da drin ist TEditStream definiert.

[meierotto]

Natürlich musste nur meine Uses-Klausel erweitert werden :thumb:

Aber... :wall: folgender Fehler folgt: "Inkompatible Typen TStream und _editstream"

Sorry, dass ich langsam ans Aufgeben denke, aber ist die Copy-Paste-Methode eigentlich unsicher?

[Flocke]

Also noch einmal komplett:

Delphi-Quellcode:

uses
  RichEdit;

// Hilfsroutine für AddRtfFromStream
function _AddRtfCallback(dwCookie: Longint; pbBuff: PByte;
  cb: Longint; var pcb: Longint): Longint; stdcall;
begin
  try
    Result := 0;
    pcb := TStream(dwCookie).Read(pbBuff^, cb);
  except
    Result := 1;
  end;
end;

// Ersetzt die aktuelle Auswahl durch den Inhalt des Streams
procedure AddRtfFromStream(RichEditHandle: THandle; Stream: TStream);
var EditStream: TEditStream;
begin
  EditStream.dwCookie := LongInt(Stream);
  EditStream.dwError := 0;
  EditStream.pfnCallback := @_AddRtfCallback;

  SendMessage(RichEditHandle, EM_STREAMIN, SF_RTF + SFF_SELECTION, LongInt(@EditStream));
  if EditStream.dwError <> 0 then
    raise Exception.Create('RichEdit operation fehlgeschlagen!');
end;

procedure AlteDateiPlusInhaltGleichNeueDatei(const DieAlteDatei: string;
  RichEdit, TempRichEdit: TJvRichEdit; const DieNeueDatei: string);
var MemoryStream: TMemoryStream;
begin
  TempRichEdit.LoadFromFile(DieAlteDatei);
  TempRichEdit.SelStart := TempRichEdit.Perform(WM_GETTEXTLENGTH, 0, 0);

  MemoryStream := TMemoryStream.Create;
  try
    RichEdit.SaveToStream(MemoryStream);
    AddRtfFromStream(TempRichEdit.Handle, MemoryStream);
  finally
    MemoryStream.Free;
  end;

  TempRichEdit.SaveToFile(DieNeueDatei);
end;

[meierotto]

Ich bewundere deine Geduld, Flocke :angel2:
Mir geht sie leider aus. Es wird erstmal fehlerfrei compiliert.
kleine Korrektur:

Delphi-Quellcode:

TempRichEdit.SaveToFile(DieNeueDatei);

muss heißen:

Delphi-Quellcode:

TempRichEdit.Lines.SaveToFile(DieNeueDatei);

und so weiter...

Aber beim Ausführen der Prozedur AddRtfFromStream wird die Exception "RichEdit operation fehlgeschlagen!" erzeugt.

Mir gehts wie diesem kleinen Smilie :coder2:

Nochmal meine Frage: Was ist der Nachteil an der Copy-Paste-Methode?

[Flocke]

Das hat nur den Nachteil, dass du den Inhalt der Zwischenablage zerstörst (falls der User den noch braucht).

Probier doch mal zwei kleine Änderungen:

Delphi-Quellcode:

TempRichEdit.LoadFromFile(DieAlteDatei);

hast du ja bestimmt schon in

Delphi-Quellcode:

TempRichEdit.Lines.LoadFromFile(DieAlteDatei);

geändert.

Füge hier eine Zeile ein:

Delphi-Quellcode:

RichEdit.SaveToStream(MemoryStream);
MemoryStream.Position := 0; // <-- hier
AddRtfFromStream(TempRichEdit.Handle, MemoryStream);

Ich hab's hier nur mit 'nem TFileStream direkt aus der Datei probiert, da hab' ich die Neupositionierung wohl vergessen.

[meierotto]

:hello: Ein Hoch auf Flocke :hello:

Seine Geduld führte dazu, dass ich jetzt mein Copy-Paste-Prinzip über Bord werfen kann :hi: und das gleiche per Streaming erreiche.

Vielen Dank :spin2:

(Jetzt muss ichs nur noch nachvollziehen)

[Sors]

In Zeile

Delphi-Quellcode:

 EditStream.pfnCallback := @_AddRtfCallback;

kommt bei mir ein Fehler. *Variable erforderlich*. Woran liegt das?????

[Sors]

Komischerweise tritt der Fehler jetzt nicht mehr auf. *grübel*

habe trotzdem eine Frage. Und zwar kann mir jemand erklären was die Befehle

Delphi-Quellcode:

EM_STREAMIN EM_STREAMOUT SFF_SELECTION

machen?

[DeddyH]

Zitat:

Zitat von Win32 SDK

The EM_STREAMIN message replaces the contents of a rich edit control with the specified data stream.

EM_STREAMIN
wParam = (WPARAM) (UINT) uFormat;
lParam = (LPARAM) (EDITSTREAM FAR *) lpStream;


Parameters

uFormat

One of the following data formats:

Value Meaning
SF_TEXT Text
SF_RTF Rich Text Format (RTF)


Both data formats may be combined with the SFF_SELECTION flag. If the SFF_SELECTION flag is specified, the stream replaces the contents of the current selection. Otherwise, the stream replaces the entire contents of the control.
The SF_RTF format may be combined with the SFF_PLAINRTF flag. If the SFF_PLAINRTF flag is specified, language-specific RTF keywords in the stream are ignored. Only keywords common to all languages are streamed in.

lpStream

Pointer to an EDITSTREAM structure. The control reads (streams in) the data by repeatedly calling the function specified by the structure's pfnCallback member.



Return Values

Returns the number of characters read.

[RavenIV]

Zitat:

Zitat von Sors

Und zwar kann mir jemand erklären was die Befehle

Delphi-Quellcode:

EM_STREAMIN EM_STREAMOUT SFF_SELECTION

machen?

Das kann Dir die Delphi-Hilfe beantworten.
Den Cursor auf eines der Wörter setzen und F1 drücken.

Ansonsten ist Herr Google auch immer sehr hilfsbereit.