IE-Favoriten

[synex]

erstmal ich weis nicht ob das Forum das richtige ist, sonst bitte verschieben.

Also ich würde gerne in einem Programm die Möglichkeit einbinden, einen Favoriten auszuwählen. Also ein Fenster wo ich dann durch die Favoritenordner navigieren kann und mir einen Favoriten aussuchen kann. Jetzt hab ich mal das Internet durchsucht und folgenden Tipp gefunden:

Delphi-Quellcode:

uses 
  ShlObj, ActiveX; 

function GetIEFavourites(const favpath: string): TStrings; 
var 
  searchrec: TSearchRec; 
  str: TStrings; 
  path, dir, FileName: string; 
  Buffer: array[0..2047] of Char; 
  found: Integer; 
begin 
  str := TStringList.Create; 
  // Get all file names in the favourites path 
  path  := FavPath + '\*.url'; 
  dir   := ExtractFilepath(path); 
  found := FindFirst(path, faAnyFile, searchrec); 
  while found = 0 do 
  begin 
    // Get now URLs from files in variable files 
    Setstring(FileName, Buffer, GetPrivateProfilestring('InternetShortcut', 
      PChar('URL'), nil, Buffer, SizeOf(Buffer), PChar(dir + searchrec.Name))); 
    str.Add(FileName); 
    found := FindNext(searchrec); 
  end; 
  // find Subfolders 
  found := FindFirst(dir + '\*.*', faAnyFile, searchrec); 
  while found = 0 do 
  begin 
    if ((searchrec.Attr and faDirectory) > 0) and (searchrec.Name[1] <> '.') then 
      str.Addstrings(GetIEFavourites(dir + '\' + searchrec.Name)); 
    found := FindNext(searchrec); 
  end; 
  FindClose(searchrec); 
  Result := str; 
end; 

procedure FreePidl(pidl: PItemIDList); 
var 
  allocator: IMalloc; 
begin 
  if Succeeded(SHGetMalloc(allocator)) then 
  begin 
    allocator.Free(pidl); 
    {$IFDEF VER100} 
    allocator.Release; 
    {$ENDIF} 
  end; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
  pidl: PItemIDList; 
  FavPath: array[0..MAX_PATH] of Char; 
begin 
  if Succeeded(ShGetSpecialFolderLocation(Handle, CSIDL_FAVORITES, pidl)) then 
  begin 
    if ShGetPathfromIDList(pidl, FavPath) then 
      ListBox1.Items := GetIEFavourites(StrPas(FavPath)); 
    // The calling application is responsible for freeing the PItemIDList-pointer 
    // with the Shell's IMalloc interface 
    FreePIDL(pidl); 
  end; 
end;

So weit so gut in der Listbox stehen jetzt die ganzen URLs irgendwie ungeordnet drinnen. Ich will ja aber den namen des Favoriten und die dazugehörige URL haben und außerdem am besten so geordnet wie sie auch im IE sind. Leider hab ich erhlichgesagt kein schimmer was da vor sich geht bei dem oben geschriebenen Codeschnipsel und von daher bin ich recht ratlos :cry:

Wäre echt super wenn mr einer dabei weiterhelfen könnte

[Daniel B]

Hallo,

da wirst Du aber mit grosser Warscheinlichkeit mit der ListBox nicht glücklich. Du solltest das ganze mit dem TreeView machen. Da hat man eben die Knotenpunkte zur Verfügung, mit denen man praktisch wie in der ganzen Ordner-Struktur runnavigieren kann. Eventuell würde noch die ListView in Frage kommen, aber TreeView wäre schon praktischer. Aber bei der ListBox sehe ich im Moment noch schwarz.

Grüsse, Daniel :hi:

[synex]

Ich hab das jetzt einfach mal so aus der Webseite rauskopiert und da stand das eben so. Wie kann ich denn rausfinden wie ich die anordnen soll beim treeview? Und wie find ich die Namen der Favoriten raus?

Aber trotzdem danke

[Daniel B]

Hallo,

falls Du die Jedis hast, schau dochmal auf dem Reiter Jv Utils und dort nach der Komponente JvFavoritesButton. Vielleicht tut es der auch schon, aber der zeigt auch nur die ganzen Ordner und Links wie ne Art Startmenü an. Die url bekommst Du damit nicht.

Grüsse, Daniel :hi:

[Duffy]

Hallo synex,
ich kann mich Daniel nur anschließen, falls Du das suchst, was im Anhang ist.
bye

[synex]

nene also tut mir leid aber es geht um Folgendes:

Ich will in einem Popup-Menü die Auswahl "Neu aus Favoriten" bereitstellen. D.h. Man klickt dort, sucht sich einen Favoriten aus und die URL wird in nen ValueListEditor geschrieben. Von daher hilft mir der Button nur zur Not weiter. Aber die URL muss schon sein sorry.

trotzdem: wo finde ich den diese "Jedis" ??

[Daniel B]

Hallo,

Zitat:

Zitat von synex

trotzdem: wo finde ich den diese "Jedis" ??

http://jvcl.sourceforge.net

Grüsse, Daniel :hi:

[synex]

ah vielen dank! Werd ich mir dann bald mal anschauen.

Ich habe grade auf torry.net die TFavoritesMenu v.1.1-Komponente dl hier gefunden. Die tut genau das was ich will, sie listet die Favoriten auf und bei nem Klick darauf gibt sie die URL wieder. Aber ich krieg sie nicht ans Laufen :(((( Die EXE-Demo dabei zeigt wies mal aussehen soll, aber beim Code dazu krieg ich immer den Fehler dass er die Klasse nicht finden kann.
Kann mir da vielleicht noch einer weiterhelfen? Ich weis das gehört nicht in das Thema hier aber ich glaub ich mach was falsch beim Installieren der Komponente.

[Daniel B]

Hallo,

in dem Demo-code steht nur:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  FavoritesMenu.Refresh;
end;

procedure TForm1.FavoritesMenuUrlClick(Sender: TObject; Url: String);
begin
  Messagedlg('Click: ' + Url, mtinformation, [mbok], 0);
end;

Hast Du es genau damit versucht, oder anders?

Grüsse, Daniel :hi:

[synex]

ich hab genau den demo-code compilieren wollen. Und da sagt er mir die klasse wurde nicht gefunden

kannst du mir vielleicht sagen wie genau du die Komponente installiert hast?? Weil ich glaube daran liegts bei mir

[Daniel B]

Hallo,

ich habe die Komponente nicht installiert, sondern nur mal die Exe angeschaut wie und was da passiert und in der Unit1 den Code angeschaut womit das ganze funktioniert. Und da stehen nur die zwei kurzen Prozeduren drin.

Grüsse, Daniel :hi:

[synex]

hast du mal probiert die unit dann zu compilieren?? Weil es ja daran scheitert bei mir.

Und sonst allgemein: Es gibt ne *.dcu und ne *.pas Datei, wie installier ich das?

[Daniel B]

Hallo,

ich habe es versucht, doch irgendwas ist in Delphi jetzt kaputt! Alle Komponenten werden jetzt auf einmal angezeigt, also auch die für CLX und das ist jetzt ein riesen Salat bei mir.
Da im Zip-File es auch eine .dcu gibt, das ist bereits die kompilierte .pas, verusch dochmal die Unit einfach nur in den Uses aufzunehmen. Vielleicht muss man gar keine Komponente in den Sinne aufs Formular setzen, sondern einfach nur die unit einbinden und so nur die Funktionen/Prozeduren daraus aufrufen.

Grüsse, Daniel :hi:

[synex]

ich habe die Unit ja unter die uses aufgenommen, aber er meinte die Klasse sei nicht gefunden worden. Wenn ich das Demo-Projekt öffne und laufen lase, funktioniert es obwohl die Klasse icht gefunden wurde ?!?

Wenn ich das von Hand selber machen will, compiliert er erst gar nicht :(

[synex]

weis denn keiner rat?

[eddy]

Hallo synex,

ich habe wohl die selbe Quelle gefunden. Mein Ziel war es, den Menüpunkt Favoriten des Internetexplorers nachzubilden, um die entsprechenden Links wählen zu können.

Dazu habe ich die Quelle ein wenig umgearbeitet, vielleicht nicht optimal, aber erstmal funktionsfähig.

Code:

//original übernommen
procedure FreePidl(pidl: PItemIDList);
var
  allocator: IMalloc;
begin
  if Succeeded(SHGetMalloc(allocator)) then begin
    allocator.Free(pidl);
    {$IFDEF VER100}
    allocator.Release;
    {$ENDIF}
  end;
end;

procedure TFTermin.GenIEFavourites(const favpath: string; var m : TMenuItem);
const
  mxcaplen = 80;
var
  searchrec: TSearchRec;
  link, lcap, // link capture
  path, dir, FileName: string;
  Buffer: array[0..2047] of Char;
  i,
  found: Integer;
  NewItem: TMenuItem;
begin
  // Get all file names in the favourites path
  path := IncludeTrailingBackslash(FavPath);
  dir := ExtractFilepath(path);
  found := FindFirst(path + '*.url', faAnyFile, searchrec);
  while found = 0 do begin
    // Get now URLs from files in variable files
    Setstring(FileName, Buffer, GetPrivateProfilestring('InternetShortcut',
              PChar('URL'), nil, Buffer, SizeOf(Buffer), PChar(dir + searchrec.Name)));
    link := FileName;
    lcap := searchrec.Name;
    //.url .de entfernen
    i := pos('.', lcap);
    if i > 0 then lcap := copy(lcap, 1, i-1);
    NewItem := TMenuItem.Create(m);
    NewItem.Bitmap.LoadFromFile(Execpath + 'FavoFile.BMP');
    NewItem.Caption := lcap;
    //Länge kürzen
    if length(NewItem.Caption) > mxcaplen
        then NewItem.Caption := copy(NewItem.Caption, 1, mxcaplen-3) + ' ...';
    // mit einem Click auf den Eintrag wird die angewählte Seite geladen
    NewItem.OnClick := LadeWebPageausFavoriten1Click;
    m.Add(NewItem);
    found := FindNext(searchrec);
  end;
  // Unterverzeichnisse einbeziehen
  found := FindFirst(dir + '*.*', faAnyFile, searchrec);
  while found = 0 do begin
    if ((searchrec.Attr and faDirectory) > 0) and (searchrec.Name[1] <> '.') then begin
      NewItem := TMenuItem.Create(m);
      NewItem.Bitmap.LoadFromFile(Execpath + 'Ordner.BMP');
      NewItem.Caption := SearchRec.Name;
      if length(NewItem.Caption) > mxcaplen
        then NewItem.Caption := copy(NewItem.Caption, 1, mxcaplen-3) + ' ...';
      m.Add(NewItem);
      GenIEFavourites(dir + searchrec.Name, NewItem);
    end;
    found := FindNext(searchrec);
  end;
  FindClose(searchrec);
end;

procedure TFTermin.FavoritenMenerzeugen1Click(Sender: TObject);
var
  pidl: PItemIDList;
  FavPath: array[0..MAX_PATH] of Char;
  NewItem: TMenuItem;
begin
  if Succeeded(ShGetSpecialFolderLocation(Handle, CSIDL_FAVORITES, pidl)) then begin
    if ShGetPathfromIDList(pidl, FavPath) then begin
      { zuerst Trennlinie erzeugen }
      NewItem := TMenuItem.Create(Self);
      NewItem.Caption := '-';
      Favoriten1.Add(NewItem);  //Favoriten1 : TMenuItem im OI definiert
      { neuen Eintrag in Menü FENSTER einfügen }
      GenIEFavourites(StrPas(FavPath), Favoriten1);
    end;
    FreePIDL(pidl);
  end;
end;

procedure TFTermin.LadeWebPageausFavoriten1Click(Sender: TObject);
begin
  if (Sender is TMenuItem )then begin
    s := (Sender as TMenuItem).Hint;
    if s <> '' then begin
      cbWeb.Text := s;
      sbGoWeb.Click;
    end;
  end;
end;

mfg
eddy