StrToInt löst keine exception aus

[GoTo0815]

Delphi-Quellcode:

try
  i:= StrToInt(DBEdit20.Text);
except
  begin
    ShowMessage('Seriennummer Falsch! Bitte nochmals eingeben!');
    DBEdit20.SetFocus;
  end;
end;

Hallo, mein problem ist eigentlich ganz einfach zu beschreiben.

Wenn der String 'x00001' in das Editfeld eingetragen wird, dann löst das keine Exception aus, warum?

Gruß

Hendrik

[freak4fun]

Weil x keine Zahl ist. :)

MfG
freak

[Angel4585]

Habt iht mal seine Frage gelesen? Es löst KEINE Exception aus..
müsste es aber wenn ich StrToInt('x0001') ausführe

[mquadrat]

Also les ich falsch, oder die anderen? :D

Ich tippe, dass x00001 als Hexadezimalwert erkannt und entsprechend in das Dezimalsystem umgerechnet wird. Daher keine Exception.

[ste_ett]

Zitat:

Zitat von mquadrat

Ich tippe, dass x00001 als Hexadezimalwert erkannt und entsprechend in das Dezimalsystem umgerechnet wird. Daher keine Exception.

Und genauso ist es. :)

[mquadrat]

Und wenn ich mich noch mehr richtig erinner wird 00001 als Oktalzahl erkannt ;)

[Daniel G]

Aber durchaus ne interessante Sache. :zwinker:

Ohh...ne'n Kieler... :cheers:

[GoTo0815]

Aha, das ist ja schon mal interessant.

Aber wieso ist X ein Teil einer Hexadezimalzahl? Das geht doch nur bis 'F', oder.

Zudem ist sehr interessant, dass das Ergebnis von i = 1 ist.

Gruß

Hendrik aus Kiel :-)

[Klaus01]

x markiert das nun eine Hexazeizmalzahl kommt.
Hex(Basis16) 00001 ist auch nur 1.

x00011 sollte dann als Integer 17 geben

Grüße
Klaus

[Christian Seehase]

Moin Zusammen,

um die Aussage von Klaus noch etwas zu vervollständigen:
0x ist in C, was $ in Delphi ist, und der Delphi-Compiler erkennt das, dummerweise, auch als gültig an.

[sakura]

Hier mal die nötigen Codes, damit keine Hex-Werte als Ergebnis zugelassen werden ;-)

Delphi-Quellcode:

function ValNoHex(const s: String; var code: Integer): Longint;
var
  I: Integer;
  Negative: Boolean;
begin
  I := 1;
  code := -1;
  Result := 0;
  Negative := False;

  while (I <= Length(s)) and (s[I] = ' ') do
    Inc(I);

  if I > Length(s) then Exit;
  case s[I] of
    '-': begin
      Negative := True;
      Inc(I);
    end;
    '+': begin
      Inc(I);
    end;
  end;

  while I <= Length(s) do
  begin
    if (Result > (High(Result) div 10)) or (not (s[I] in ['0'..'9'])) then
    begin
      code := I;
      Exit;
    end;
    Result := Result * 10 + Ord(s[I]) - Ord('0');
    Inc(I);
  end;
  if Negative then
  begin
    Result := -Result;
  end;
  code := 0;
end;

function StrToIntNoHex(S: string): Longint;
var
  E: Integer;
begin
  Result := ValNoHex(S, E);
  if E <> 0 then raise EConvertError.CreateResFmt(@SInvalidInteger, [S]);
end;

function StrToIntDefNoHex(S: string; Default: LongInt): Longint;
var
  E: Integer;
begin
  Result := ValNoHex(S, E);
  if E <> 0 then
    Result := Default;
end;

Anstatt StrToInt und StrToIntDef nutze StrToIntNoHex und StrToIntDefNoHex :)

...:cat:...

[Hawkeye219]

Kleine Ergänzung:

Einige Zahlen außerhalb des Long-Bereichs werden nicht zurückgewiesen sondern falsch konvertiert. Die Abfrage

Code:

if (Result > (High(Result) div 10)) or (not (s[I] in ['0'..'9'])) then

greift erst ab dem Wert 2147483650, der Long-Bereich ist aber [-2147483648..2147483647].
Borland hat dies in der Systemroutine _ValLong (im Assembler-Teil!) durch eine Abfrage des Overflow-Flags kompensiert.

Der Fehler tritt aber lediglich an den Intervallrändern auf und dürfte nur für die Anwendungsfälle interessant sein, in denen der Long-Bereich exakt abgedeckt werden soll.

Gruß Hawkeye