Buchstabensuche !aller! Felder

[Lotus]

Folgendes Problem.. ich moechte eine Suchfunktion machen (nur für Buchstaben).. diese funktion soll mir alle Stellen (Felder) von a liefern an denen der Buchstabe = dem gesuchtem ist!
ich hab dann diese function geschrieben er meint dauernd fehler aber ich erkenne ihn nirgends!!!

Delphi-Quellcode:

function suche2(buchstabe:string):integer;
var i2:integer;
begin
for i2:=1 to nf do begin
  if a[i2] <> buchstabe[1] then Inc(i2) // <--- Hier soll Fehler sein
  else begin
  suche2:=suche2 + i2 + ',';
  Inc(i2);
  end
  end
end;

hoffe ihr könnt mir helfen

[DeddyH]

In for-Schleifen darfst Du die Zählvariable nicht innerhalb der Schleife ändern.

[mkinzler]

Du könntest die Schleife aber z.B. in eine While-Schleife umbauen.

[DeddyH]

Dann wird es aber spätestens an der Zeile

Delphi-Quellcode:

suche2:=suche2 + i2 + ',';

scheitern ;)

[mkinzler]

Ja, er sollte sich mal die Grundlagen von Delphi ansehen.

[Thorben_Ko]

sucht mal in der OH nach Pos und nach PosEx

gruss Thorben

[Lotus]

hm.. wie kann ich denn sonst "alle" werte überprüfen.. also nehmen wir mal an ich habe 5 Felder
1 A
2 V
3 A
4 A
5 S

und ich will jetzt nach A suchen.. jetzt möchte ich das er mir ausgibt 1, 3 und 4
das wollte ich mit dieser funktion erreichen.. mir faellt jetzt aber nix ein wie das funktionieren würde

[DeddyH]

Entweder ein String als Rückgabe, dann geht es so, wie Du gecodet hast, oder z.B. eine TList als Var-Parameter übergeben.

[RWarnecke]

Nimm diese Funktion und rufe diese in einer For_Schleife auf oder in einem repeat...until Block auf :

Delphi-Quellcode:

function PosN(Substring, Mainstring: string; n: Integer): Integer;
begin
  if Pos(substring, mainstring) = 0 then begin
    posn := 0;
    Exit;
  end else begin
    if  n = 1 then posn := Pos(substring, mainstring)
    else begin
      posn := Pos(substring, mainstring) + posn(substring, Copy(mainstring,
         (Pos(substring, mainstring) + 1), Length(mainstring)), n - 1);
    end;
  end;
end;

Diese Funktion gibt Dir die Position des Suchstrings aus. Wird der Suchstring nicht gefunden ist das Ergebnis 0.

[Lotus]

hm.. als string wiedegeben? is das nich ein wiederspruch in sich weil doch das feld integer ist.. oder kann ich da sagen inttostr?
hm.. mit Tlist habe ich noch nie gearbeitet.. delphi hilfe war auch nich gerade überhaeuft mit infos.. könntet ihr mir da vllt ein paar infos zuschieben?

@Rwarnecke
danke für diesen code.. allerdings verstehe ich diesen nicht ganz und möchte ihn daher nicht blind benutzen.. mir wäre es lieber wenn ich alles genau verstehe.. allerdings faengts schon bei sub und mainstring an...

[DeddyH]

So geht' s auch:

Delphi-Quellcode:

type  TMyArray = array of integer;

function SeekChar(cArr: array of char;c: char): TMyArray;
var i: integer;
begin
  SetLength(Result,0);
  for i := Low(cArr) to High(cArr) do
    if cArr[i] = c then
      begin
        SetLength(Result,Length(Result)+ 1);
        Result[Pred(Length(Result))] := i;
      end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var arr: TMyArray;
    i: integer;
    test: array[0..4] of char;
begin
  test[0] := 'A';
  test[1] := 'V';
  test[2] := 'C';
  test[3] := 'A';
  test[4] := 'A';
  arr := SeekChar(test,'A');
  for i := Low(arr) to High(arr) do
    ShowMessage(inttostr(arr[i]));
  SetLength(arr,0);
end;

[Lotus]

das is ja noch viel komplizierter -.-

[DeddyH]

Soll ich' s Dir erklären?

[Lotus]

wäre sehr sehr nett

[RWarnecke]

Zitat:

Zitat von Lotus

@Rwarnecke
danke für diesen code.. allerdings verstehe ich diesen nicht ganz und möchte ihn daher nicht blind benutzen.. mir wäre es lieber wenn ich alles genau verstehe.. allerdings faengts schon bei sub und mainstring an...

Substring und MainString sind Variablen. SubString ist der String der gesucht wird im Mainstring. N ist die Position die gesucht werden soll vom Substring. Ein kleines Beispiel :

Delphi-Quellcode:

function PosN(Substring, Mainstring: string; n: Integer): Integer;
begin
  if Pos(substring, mainstring) = 0 then begin
    posn := 0;
    Exit;
  end else begin
    if  n = 1 then posn := Pos(substring, mainstring)
    else begin
      posn := Pos(substring, mainstring) + posn(substring, Copy(mainstring,
         (Pos(substring, mainstring) + 1), Length(mainstring)), n - 1);
    end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  text : string;
  ergebnis : string;
  zaehler : integer;
begin
  text := 'AVAAS';
  zaehler := 1;
  repeat
    if posn('A', text, zaehler) > 0 then
      ergebnis := ergebnis + IntToStr(posn('A', text, zaehler)) + ', ';
    zaehler := zaehler + 1;
  until posn('A', text, zaehler) = 0;
  Label1.Caption := ergebnis;
end;

Das habe ich nur so runtergetippt. Sollte aber funktionieren. Ein kleiner Tipp von mir, schaue Dir wirklich mal die Befehle Pos und PosEx in der Online-Hilfe genaustens an.

Edit:
Für das Beispiel brauchst Du ein Label und einen TButton. Das ganze kann man sicherlich auch noch eleganter in einer For-Schleife machen.

Edit 2:
Erklärung von der Variable "n" hinzugefügt.

[DeddyH]

Also, zunächst definiere ich ein dynamisches Array als Datentyp.

Delphi-Quellcode:

type  TMyArray = array of integer;

Ein dynamisches Array hat keine vorgegebene Größe (deshalb ja "dynamisch"), sondern kann den Umständen entsprechend wachsen. Die Deklaration als Typ ist deshalb nötig, damit ich es als Rückgabewert einer Funktion nutzen kann (sonst würde der Compiler meckern).
Nun zur Funktion:

Delphi-Quellcode:

function SeekChar(cArr: array of char;c: char): TMyArray;
var i: integer;
begin
  SetLength(Result,0);
  for i := Low(cArr) to High(cArr) do
    if cArr[i] = c then
      begin
        SetLength(Result,Length(Result)+ 1);
        Result[Pred(Length(Result))] := i;
      end;
end;

Sie erwartet als Parameter wieder ein dynamisches Array von Zeichen sowie das zu ermittelnde Zeichen. Rückgabewert ist der selbst definierte Datentyp (siehe oben). Mit SetLength setze ich den Speicherbedarf initial auf 0. Nun gehe ich das übergebene Array in einer Schleife durch (die Funktionen Low und High dienen der Emittlung der Größe des übergebenen Array) und mache bei einem Treffer Folgendes:
- Vergrößern des Rückgabearrays um ein Element
- Befüllen des letzten Elements mit dem Index der Fundstelle (da der Index eines dynamischen Arrays immer mit 0 beginnt, hat das letzte Element den Index Length - 1 oder anders formuliert Pred(Length)).
Die Methode Button1Click dient nur zur Verdeutlichung, wie man die Funktion nutzen kann.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var arr: TMyArray;
    i: integer;
    test: array[0..4] of char;
begin
  test[0] := 'A';
  test[1] := 'V';
  test[2] := 'C';
  test[3] := 'A';
  test[4] := 'A';
  arr := SeekChar(test,'A');
  for i := Low(arr) to High(arr) do
    ShowMessage(inttostr(arr[i]));
  SetLength(arr,0);
end;

Zuerst wird ein Array of Char befüllt, dann die Funktion aufgerufen, nun folgt die Ausgabe der Fundstellen in einer Schleife und zu guter Letzt setze ich die Länge des Rückgabearrays wieder auf 0 und gebe somit dessen Speicher frei.
That' s it.

[Lotus]

Delphi-Quellcode:

      posn := Pos(substring, mainstring) + posn(substring, Copy(mainstring,
         (Pos(substring, mainstring) + 1), Length(mainstring)), n - 1);

um diesen code geht es mir speziell! hab mir hilfe zu pos angeschaut.. nur versteh ich diese zeilen nich ganz

[RWarnecke]

Zitat:

Zitat von Lotus

Delphi-Quellcode:

      posn := Pos(substring, mainstring) + posn(substring, Copy(mainstring,
         (Pos(substring, mainstring) + 1), Length(mainstring)), n - 1);

um diesen code geht es mir speziell! hab mir hilfe zu pos angeschaut.. nur versteh ich diese zeilen nich ganz

Hier wird die erste Position vom Substring im Mainstring ermittelt. Zu dieser Zahl wird dann durch nochmaligen Aufruf der Funktion PosN die nächste Position ermittelt mit dem Befehl Copy. Was dieser Befehl macht kannste ebenfalls in der Online-Hilfe nachschauen.

[Lotus]

pos funktioniert aber halt nur auf strings.. was is wenn ich die ganze zeit aber mit chars arbeite?

[RWarnecke]

Den Befehl Pos kannst Du auch nur für einzelne Buchstaben oder Zeichen nutzen.

[Lotus]

da.. aber doch nur wenn der string aus einem buchstaben oder einem zeichen besteht oder ich angebe string[1]..
allerdings habe ich in der hilfe gelesen das pos die variable string benötigt.. wie gesagt ich hab aber char und nicht string!

[RWarnecke]

Schaue Dir doch bitte mal die Grundlagen von den verschiedensten Typen an. Du kannst ein einzelnes Zeichen als String oder als Char weitergeben. Es kommt immer darauf an, was Du damit machen willst. Willst Du mehrere Zeichen aus einem Text rausnehmen und dann zusammenfügen, musst Du es als String deklarieren. Wenn Du aber auch jedes Zeichen reagieren willst, also irgendeine Bedingung dran knüpfst, dann kannst Du es als Char deklarieren.

Ich hoffe ich habe es einigermaßen verständlich erklärt. Aber die Grundlagentutorials hier aus dem Forum solltest Du Dir vielleicht mal anschauen.

[Lotus]

gerne.. nur wo finde ich diese denn oO?

[fkerber]

Hi!

Anfängertutorials findest du bspw. auch unter http://www.dsdt.info


Eine Bitte noch:
Könntest du deinem Thread einen anderen Titel geben, sodass man "von außen" erkennen kann, um was es genau geht?
Das wäre super!


Ciao, Frederic

[RWarnecke]

Zitat:

Zitat von fkerber

Eine Bitte noch:
Könntest du deinem Thread einen anderen Titel geben, sodass man "von außen" erkennen kann, um was es genau geht?

Dieses kannst Du erreichen indem Du Deinen ersten Beitrag editierst.

Weitere Tutorials findest Du unter :

[dp]Grundlagen, Anfänger[/dp]