Menge von Integerzahlen schnell u. einfach merken?

[Horst_]

Hallo,

wenn der Wertebereich der Intgervariablen bekannt und klein ist (Bleibt dem Anwender überlassen ob 1000 oder 100 mio klein ist) legt man nur ein Feld für den Wertebereich an und zählt das jeweiige vorkommen. Dann sind die Daten sogar sortiert.

Gruß Horst

[BloodySmartie]

Das erinnert mich an das Buch "Perlen der Programmierkunst".

Problematik: Sortiere eine Menge an 8-stelligen Telefonnummern, entferne doppelte Zahlen und das bitte in minimaler Zeit und mit minimalem Speicherverbrauch.

Lösung: ein Bit-Array, dessen Index die Tel-Nr. darstellt und dessen Wert einfach nur anzeigt, ob sie in der Menge vorhanden ist oder nicht. Ums Sortieren und um Dubletten muss man sich gar nicht kümmern.

[Tyrael Y.]

Zitat:

Zitat von SirThornberry

ich persönlich würde ein Array nehmen. Allerdings ist genau so gut auch eine TList. Nichts mit ableiten etc. Die TList verwaltet Pointer welche 32 bit groß sind. Integer sind ebenfalls 32bit groß. Entsprechend kann man durch einen einfachen Cast auch Integer darin speichern. Denn letztendlich ist es eine Interpretationssache ob man das was im Speicher steht als Integer, Pointer, String etc. ansieht.

So ist es...wenn du zu faul bist das Casten in Integer selbst zu übernehmen, dann google mal nach TIntegerList....ist eine gaaaanz einfache und auch selbst schnell getippte Ableitung von TList.


Edit:
Hier für faule...es kann natürlich noch erweitert werden.

Delphi-Quellcode:

unit IntegerList;

interface

uses
  Classes;

type
  TIntegerListSortCompare = function (Item1, Item2: Pointer): Integer;
  TIntegerList = class(TList)
  private
    function Get(Index: Integer): Integer; reintroduce;
    procedure Put(Index: Integer; const Value: Integer); reintroduce;
  public
    function Add(Item: Integer): Integer; reintroduce;
    function Extract(Item: Integer): Integer; reintroduce;
    function IndexOf(Item: Integer): Integer; reintroduce;
    procedure Insert(Index: Integer; Item: Integer); reintroduce;
    function Last: Integer; reintroduce;
    function Remove(Item: Integer): Integer; reintroduce;
    procedure Sort(Compare: TIntegerListSortCompare); reintroduce;
    property Items[Index: Integer]: Integer read Get write Put; default;
  end;

implementation

{ TIntegerList }

function TIntegerList.Add(Item: Integer): Integer;
begin
  Result := inherited Add(Pointer(Item));
end;

function TIntegerList.Extract(Item: Integer): Integer;
begin
  Result := Integer(inherited Extract(Pointer(Item)));
end;

function TIntegerList.Get(Index: Integer): Integer;
begin
  Result := Integer(inherited Items[Index]);
end;

function TIntegerList.IndexOf(Item: Integer): Integer;
begin
  result := inherited IndexOf(Pointer(Item));
end;

procedure TIntegerList.Insert(Index, Item: Integer);
begin
  inherited Insert(Index, Pointer(Item));
end;

function TIntegerList.Last: Integer;
begin
  Result := Integer(inherited Last);
end;

procedure TIntegerList.Put(Index: Integer; const Value: Integer);
begin
  inherited Items[Index] := Pointer(Value);
end;

function TIntegerList.Remove(Item: Integer): Integer;
begin
  Result := inherited Remove(Pointer(Item));
end;

procedure TIntegerList.Sort(Compare: TIntegerListSortCompare);
begin
  inherited Sort(TListSortCompare(Compare));
end;

end.

[PeterPanino]

Zitat:

Zitat von Tyrael Y.

So ist es...wenn du zu faul bist das Casten in Integer selbst zu übernehmen, dann google mal nach TIntegerList....ist eine gaaaanz einfache und auch selbst schnell getippte Ableitung von TList.[/delphi]

Kommt darauf an, wofür man die Liste braucht. Die Ausgangsanforderung war ja: Schnell und einfach mal ein paar Integers merken.

Trotzdem vielen Dank an alle für die nützlichen Beiträge!

[Tyrael Y.]

Zitat:

Zitat von PeterPanino

Kommt darauf an, wofür man die Liste braucht. Die Ausgangsanforderung war ja: Schnell und einfach mal ein paar Integers merken.

Trotzdem vielen Dank an alle für die nützlichen Beiträge!

120% der Anforderungen erfüllt würde ich sagen :D

es ist schnell, einfach und zudem lassen sich die Integer gut verwalten. ;)