Objekt anhand der Klassenbezeichnung erzeugen

[SWE]

Gibt es die Möglichkeit ein Objekt anhand der Klassenbezeichnung zu erzeugen?
Beispiel:
Ich habe die Klassentypen TMeinObjekt1 und TMeinObjekt2.
Jetzt bräuchte ich eine Funktion die einen String entgegennimmt z.B. 'TMeinObjekt1' und eine Objektinstanz vom entsprechenden Typ zurückliefert.
Aber bitte nicht so:

Delphi-Quellcode:

   if str = 'TMeinObjekt1' then 
        Result := TMeinObjekt1.Create();

Da gibt es doch bestimmt eine intelligente Lösung die für alle Objekttypen gilt, oder?
Fragt mich bitte nicht, wofür ich es brauch. Ich weiß es selbst noch nicht, sondern will es erst mal nur so wissen.

Danke schon mal.

[Luckie]

Sollte es sich um eine Komponente handlen, gibt es FindComponent.

[Apollonius]

Hier geht es um Klassen, nicht Instanzen.

Einen sauberen Weg gibt es nicht, aber hier im Forum geistert eine Unit herum, mit der man alle Typinformationen in einem Modul auflisten kann. Damit ist es dann trivial, weil in den Typinformationen der Klasse auch die TClass gespeichert ist.

[Luckie]

Oh, sorry.

[uligerhardt]

Musst du wirklich alle Klassen behandeln oder nur welche, die du selber schreibst? In letzterem Falle würde ich einen Mechanismus a la RegisterClass machen. Schau dir mal an, wie das in der VCL implementiert ist.

HTH,
Uli.

[Hawkeye219]

Hallo,

shmia zeigt in einem Beitrag zur Code-Library, wie man die Funktion RegisterClass und FindClass einsetzen kann.

Gruß Hawkeye

[SWE]

Super, vielen Dank. Klappt wunderbar und reicht mir!

So ungefähr geht's:

Delphi-Quellcode:

// Test-Objekt
TMeinObjekt1 = class (TPersistent)
public
    strName : String;
end;

...

initialization 
  // Klasse registrieren
  RegisterClass(TMeinObjekt1); 
end;        

...

// Test-Prozedur
procedure Test();
var
    cls : TPersistentClass;
    obj : TObject;
begin
    // Klassenreferenz ermitteln
    cls := FindClass('TMeinObjekt1');
    // Objekt-Instanz erzeugen
    obj := cls.Create();
    // Da nicht das konkrete Objekt erzeugt wurde, wird hier gecasted
    TMeinObjekt1(obj).strName := 'Hallo';
    // Test-Ausgabe
    ShowMessage(TMeinObjekt1(obj).strName);
end;

[Pascal P]

Hi zusammen!
Ich versuche gerade ähnliches zu machen. Allerdings habe ich noch ein Problem.
Das Objekt erstellen ist ja so kein Problem. Allerdings wird nur mein Constructor der Basisklasse aufgerufen und nicht der des eigentlichen Objektes.

Delphi-Quellcode:

TBaseObjekt = class (TPersistent)
public
    strName : String;
    constructor Create; overload;
end; 

TBaseObjectClass = class of TBaseObject;

TExtendedObjekt = class (TBaseObjekt)
public
    constructor Create; overload;
end;

constructor TBaseObjekt.Create;
begin
  Self.strName := 'Base';
end;

constructor TExtendedObjekt.Create;
begin
  Self.strName := 'Extendet';
end;

procedure Test();
var
    cls : TPersistentClass;
    obj : TBaseObject;
begin
    // Klassenreferenz ermitteln
    cls := FindClass('TExtendedObjekt');
    // Objekt-Instanz erzeugen
    obj := TBaseObjectClass( cls ).Create();
    // Test-Ausgabe
    ShowMessage(TExtendedObjekt(obj).strName);
    // Die Ausgabe sollte dann Base sein
end;

Das Baseobjekt stellt bei mir eine eigene Classroot dar von der ich alles ableite. Ich weiss lediglich mittels eines Strings, hier TExtendedObject' welches Object ich erzeugen muss/will. Also kann ich mich nur auf den allgemeinen kleinsten Nenner, die TBaseObject, beziehen. Das erstellte Objekt ist auch vom Typ TExtendedObject. Jedoch eben nicht mit den für dieses Object initialisierten Werten, sondern denen der Basisklasse.

Hoffe konnte verständlich machen um was es mir geht und hoffe auf Hilfe.
Liebe Grüsse Pascal

[Hansa]

Was macht nochmal das overload ? :gruebel: Normaler Weg wäre override in der Deklaration und eventuell inherited aufrufen.

[Pascal P]

Ok, das Overload gehört da garnicht hin. Das war wohl zuviel kopiert und rumgebastelt.
Dient aber dazu um Methoden zu überladen.

Delphi-Quellcode:

  procedure MeineMethode( str : String );
  procedure MeineMethode( int : Integer ); overload;

  procedure MeineMethode( str : String );
  begin
    ShowMessage( str );
  end;

  procedure MeineMethode( int : Integer );
  begin
    MeineMethode( IntToStr( int ) );
  end;

Mehr macht das garnicht.

Mit inherited arbeite ich auch. Nur passiert eben folgendes. Ich initiiere ein Objekt einer Klasse die ich als String angebe (wenn sie denn gefunden wird).
Nur der Constructor wird eben von der Basisklasse verwendet. Ich kann ja zum derzeitigen Punkt nicht wissen um welchen Typ Klasse es sich dabei handelt.

[shmia]

Zitat:

Zitat von Pascal P

Allerdings wird nur mein Constructor der Basisklasse aufgerufen und nicht der des eigentlichen Objektes.

Du musst den Konstruktor virtuell machen!
Aus diesem Grund ist auch der Konstruktor von TComponent virtuell. Ansonsten würde das dynamische Laden von Komponenten aus dem DFM-Resourcen nicht funktionieren.

[Hansa]

Hilfe gut und schnell abgekupfert. :mrgreen: Sehe gerade in der Test-Prozedur, wo wird denn da überhaupt das gewünschte Objekt created ? Erzeuge das mal lieber direkt. Also so :

Delphi-Quellcode:

obj := TExtendedClass.Create;

[Vjay]

Aber müsste nicht der neue constructor den alten trotzdem (rein logisch gesehen) verdecken?

[Hansa]

Mit override wird der verdeckt. Den Constructor der Basisklasse kann man dann mit inherited explizit aufrufen.

[shmia]

Zitat:

Zitat von Vjay

Aber müsste nicht der neue constructor den alten trotzdem (rein logisch gesehen) verdecken?

Nicht, wenn der neue Konstruktor mit override deklariert wurde.
Dann muss aber auch die Signatur, also Anzahl und Datentypen der Übergabeparameter, immer so sein, wie das in der Basisklasse einmal festgelegt wurde.

Delphi-Quellcode:

TBaseObject = class(...)
  constructor Create; virtual;
  ...
end;
TExtendedObject = class(TBaseObject)
  constructor Create; override;
  ...
end;
TExtendedObject2 = class(TBaseObject)
  constructor Create; override;
  ...
end;

Man kann sich das alles aus der TComponent Hierarchie abschauen.

[Pascal P]

Irgendwie muss ich grad voll ends auf dem Schlauch stehen. Habe mal eben die Änderung mit virtual gemacht. gehen tut es aber noch immer nciht.
Mein Programmcode sieht nun in etwa so aus.

Delphi-Quellcode:

TBaseObjekt = class (TPersistent)
public
    strName : String;
    constructor Create; virtual;
end; 

TBaseObjectClass = class of TBaseObject;

TExtendedObjekt = class (TBaseObjekt)
public
    constructor Create;
end;

constructor TBaseObjekt.Create;
begin
  Self.strName := 'Base';
end;

constructor TExtendedObjekt.Create;
begin
  Self.strName := 'Extendet';
end;

procedure Test();
var
    cls : TPersistentClass;
    obj : TBaseObject;
begin
    // Klassenreferenz ermitteln
    cls := FindClass('TExtendedObjekt');
    // Objekt-Instanz erzeugen
    obj := TBaseObjectClass( cls ).Create();
    // Test-Ausgabe
    ShowMessage(TExtendedObjekt(obj).strName);
    // Die Ausgabe sollte dann Base sein
end;

Funktionieren tut es noch immer wie davor. Es wird der Constructor der Basisklasse verwendet und nicht der der eigentlichen Klasse.

[shmia]

Du hast das override beim Konstruktor der abgeleiteten Klasse vergessen!!

Delphi-Quellcode:

TExtendedObjekt = class (TBaseObjekt) 
public 
    constructor Create; override; // <==
end;

[Pascal P]

Argh, vor lauter Bäumen den Wald nicht mehr gesehen. Okey, danke nochmals. In einem kleinen Testprogramm funktioniert es jetzt.
Werd es dann mal versuchen vollends zu implementieren.

Vielen Danke. Wenn ich noch Probleme habe, meld ich mich nochmals :D

[SWE]

Du solltest natürlich nicht vergessen im Konstruktor Deiner abgeleiteten Klasse "inherited" aufzurufen:

Delphi-Quellcode:

constructor TExtendedObjekt.Create; 
begin 
  inherited;
  Self.strName := 'Extendet'; 
end;

[Pascal P]

Alles seit Freitag in Sack und pack, genau so wie ich es wollte.
Danke nochmals für die gute Hilfe.