Projekte rein halten von Compilaten

[DelphiManiac]

Hallo,

ich würde gerne mein Projektordner ohne DCU's und sonstigen Compilaten verwalten.

Also angenommen ich habe ein

Projekt1
.. MainGUI.dfm
.. MainGUI.pas
.. Datei1.pas
.. Datei2.pas

Hintergrund ist, dass ich oft Backups mache aber die Compilate nicht mit backupen will.
Gut, ich könnte eine Ausnahme für das Backup erstellen, aber das will ich ungern machen...

Vielen Dank
DM

[sakura]

Es gibt in den Projektoptionen [STRG]+[F11] die Möglichkeit Zielverzeichnisse (auch für DCUs) anzugeben.

...:cat:...

[_frank_]

ich habe in mein Backupscript (welches in jedem projekt-ordner liegt) entsprechende lösch-befehle drin. das kannst du auch einfach durch exe,dll o.ä. erweitern

hier das komplette script, falls es jemand interessiert:

Code:

@echo off

cd %~dp0

rem removing backups
del /S *.~*
del /S *.dcu
del /S *.map
del /S *.drc
del /S *.ddp
del /S *.cfg
del /S *MemoryManager*.txt
del /S _bak_\*.*
rmdir _bak_

goto getfoldername
:DirsUp
pushD ..
:getfoldername
rem getting name of current folder

rem replace spaces
set dir=%cd: =#%

rem parsing last foldername
for %%i in (%dir:\=,%) do set folder="%%i"

rem replace back to spaces
set folder=%folder:#= %
rem remove quotes
set folder=%folder:~1,-1%

rem echo %folder%
rem pause
rem checking for svn-managed project
if "%folder%"=="trunk" goto DirsUp

set zipname="%folder%.zip"
set _7za="D:\system\7-zip\7za.exe"
set exclude=-x!*.svn* -x!*.zip

popd
%_7za% u -r -tzip %exclude% %zipname% .\

pause

Gruß Frank