LDAP mit ADSI: alle Properties auslesen geht nicht?

[Phoenix]

Hi,

ich habe ein Problem aus dem LDAP bestimmte Werte auszulesen.

Im ersten Screenshot sieht man die Angaben im LDAP. Der Screenshot stammt aus dem Softerra LDAP Browser (cooles Tool übrigens).

Ich selber benutze folgenden Code, um die Detailinformationen zu einem Knoten im LDAP auszulesen:

Delphi-Quellcode:

uses ActiveX, ActiveDs_TLB, AdsHlp, Variants;

function MyLdapPersonenImport.getNodeInfo(obj: IAds): TMyLdapTreeNodeItem;
var
  properties: IAdsPropertyList;
  i,j: integer;
  prop: IAdsPropertyEntry;
  props: Array of IInterface;
  myProp: IAdsPropertyValue2;
  datatype: Integer;
  valueOle: OleVariant;
  value: String;
begin
   // create and initialize result Item
   result := TMyLdapTreeNodeItem.Create();
   result.Caption := obj.Name;

   result.Info.Clear;
   result.Info.Add(obj.Name);
   result.Info.Add(obj.Class_);

   obj.GetInfo();

   // get property list:
   if obj.QueryInterface(IAdsPropertyList, properties) = 0 then
   begin
         // read other properties:
      result.Info.Add('');
      result.Info.Add('Properties:');

      // position on first property
      properties.Reset;

      // enumerate properties and add them to the info text of the result:
      for i := 0 to properties.PropertyCount - 1 do
      begin
         if IUnknown(properties.Item(i)).QueryInterface(IAdsPropertyEntry, prop) = 0 then
         begin
            props := prop.Values;

            // a property can have multiple values, so enumerate through all of them:
            for j := 0 to Length(props) - 1 do
            begin
               if props[j].QueryInterface(IAdsPropertyValue2, myProp) = 0 then
               begin
                  datatype := ADSTYPE_UNKNOWN;
                  valueOle := myProp.GetObjectProperty(datatype);
                  value := VarToStr(valueOle);
                  result.Info.Add('   ' + prop.Name + '(' + IntToStr(datatype) + '): ' + value);
               end;
            end;
         end;
      end;
   end;
end;

TMyLdapTreeNodeItem ist ein ganz dummes Objekt, das nur ein paar Properties wie eben die Caption hat.
Das Property Info (wo hier Informationen mit result.Info.Add('wuppdi'); hinzugefügt werden) ist eine simple TStringList und deren Inhalt wird in MyLdapScreen rechts unten angezeigt.

Wie man auf MyLdapScreen.JPG erkennen kann, liest dieser Code jedoch nur die Properties aus dem LDAP, die im Softerra Browser als 'Textattribut' gekennzeichnet sind. Die 'Betriebsattribute', von denen ich zumindest mal structuralObjectClass benötige, werden hier in der PropertyList leider nicht aufgeführt.

Wie kann ich denn jetzt auch diese 'Betriebsattribute' auslesen? Das MSDN schweigt sich dazu leider aus, und auf der Agnisoft-Seite (von denen stammt die Unit AdsHlp) findet sich dazu leider auch nichts.

Edit Nachtrag: Ein

Delphi-Quellcode:

valueOle := obj.Get('structuralObjectClass');

klappt übrigens auch nicht. Das Property wird anscheinend nicht gefunden. Ich habe die Vermutung, dass ich an diese Dinger irgendwie anders rangehen muss, habe aber leider keinen Ansatzpunkt wonach ich suchen muss.

[Phoenix]

Habs grad selber hinbekommen: Ich muss diese Attribute einfach zusätzlich explizit abfragen.

Der Hinweis kam von hier: http://www.selfadsi.de/read.htm

Delphi-Quellcode:

 [...]
  obj.GetInfo();
  // hier liegt die Magie:
  obj.GetInfoEx(VarArrayOf(['structuralObjectClass']), 0);

Man kann jetzt noch hergehen, und das Schema des Objektes abfragen, und für jedes dieser Attribute im Schema ein weiteres Element in dem Variant Array of string anlegen, so dass man alles abfragt. Aber da man hier jedes Schema abfragen muss geht das freilich wieder auf die Performance, und das ist so schon nicht das schnellste. Man sollte sich also auf die Attribute beschränken, die man wirklich braucht.