Frage zum Indexer - Verständnisprobleme

[tomsson74]

Frage zum Indexer - Verständnisprobleme

Hallo zusammen

in einer TObjectList speichere ich besitmmte Objekte. Damit ich nicht beim Zugriff auf diese Liste nicht jedes mal ein Typecast machen muss, habe ich die Setter- und Getter-Methode so überlagert, dass sie direkt das richtige Objekt liefert.

Delphi-Quellcode:

   TODBCTableList = class(TObjectList)
   private
     function GetItem(AIndex: Integer): TODBCTable;
     procedure SetItem(AIndex: Integer; AValue: TODBCTable);
   public
     property Items[AIndex : Integer]: TODBCTable read GetItem write SetItem;
   end;

(...)

   function TODBCTableList.GetItem(AIndex: Integer): TODBCTable;
   begin
     Result := TODBCTable(inherited Items[AIndex]);
   end;

   procedure TODBCTableList.SetItem(AIndex: Integer; AValue: TODBCTable);
   begin
     inherited Items[AIndex] := AValue;
   end;

Jetzt kann ich mit einer for schleife auf die Objekte zugreifen (angenommen, meine Klasse hätte die Variablen "Name" und "Bezeichnung"):

Delphi-Quellcode:

Tables := TODBCTableList.Create;

(...) // "Tables" füllen

for I := 0 to Tables.Count - 1 do begin
   Memo1.Lines.Add(Tables.Items[I].Name);
   Memo1.Lines.Add(Tables.Items[I].Bezeichnung);
end;

Und jetzt kommt meine Frage. Eher zufällig bin ich drauf gekommen, dass man statt

Delphi-Quellcode:

Tables.Items[I].Name

auch

Delphi-Quellcode:

TODBCTable(Tables[I]).Name

schreiben kann, also ohne den "Umweg" über "Items" nehmen zu müssen.
Warum geht das ? Das sieht aus wie eine art namenloser Indexer. Ich habe mir die Klasse TObjectList als auch TList (von der TObjectList abgeleitet wurde) angeschaut und natürlich nichts derartiges gefunden.

Aber wenn es schon so funktioniert, kann ich dann dafür auch "meinen" Objekt-Typ als Rückgabewert erzwingen, damit ich auch die gekürzte Schreibweise ohne Typecast nutzen kann ?

Delphi-Quellcode:

Tables[I].Name

[Sir Rufo]

Sollte doch gehen,

schau doch mal deine definition an

Delphi-Quellcode:

property Items[AIndex : Integer]: TODBCTable

cu

Oliver

[tomsson74]

Ja, der Rückgabewert ist ja auch ein TODBCTable-Objekt, wenn ich über "Items" gehe. Aber das ist ja nicht mein Problem.

Die Definition

Delphi-Quellcode:

property Items[AIndex : Integer]: TODBCTable

sagt doch aus, dass ich

Delphi-Quellcode:

TODBCTableList.Items[Index]

schreiben muss, um als Rückgabewert ein TODBCTable-Objekt zu erhalten.

Ich würde aber gerne

Delphi-Quellcode:

TODBCTableList[Index]

schreiben.

Das funkioniert aber nur mit Typecast, also so:

Delphi-Quellcode:

TODBCTable(TODBCTableList[Index])

/Thomas

[Andreas L.]

Zitat:

Ich würde aber gerne

Delphi-Quellcode: markieren
TODBCTableList[Index]


schreiben.

Einfach default der Eigenschaftsdefinition anhängen:

Delphi-Quellcode:

property Items[AIndex : Integer]: TODBCTable read GetItem write SetItem; default;

[tomsson74]

Mensch, da tippe ich soviel Text und die Antwort ist dann ein Einzeiler :D

Danke, so klappt es wunderbar - wieder mal was dazu gelernt.

Damit ist die Frage beantwortet.


/Thomas

[Andreas L.]

Zitat:

Zitat von tomsson74

Danke, so klappt es wunderbar - wieder mal was dazu gelernt.

Gerne :-)