TreeView - Node rauf / runter schieben ?

[moelski]

Moin !

Hat jemand ein Quellcode Schnipsel, um in einem normalen TreeView einen Node nach oben / unten zu verschieben und zwar nur auf einer Ebende.

Bsp:
Test 1
--- Node 1
--- Node 2
--- Node 3

Dann also z.B. Node 3 selektieren, Button "UP" drücken und man hat eben die Reihenfolge 1 / 3 / 2. Das eben für rauf und runter.

[taaktaak]

Moin, Moin.
Soll es unbedingt mit 'nem Button funktionieren? Bei den Schweizern gibt es hier ein Beispiel die Aufgabe mit DragAndDrop zu lösen.

[moelski]

Moin !

Drag & Drop geht schon. Aber da kann man eben noch nicht die Position mit festlegen. Es wird immer hinten angehängt.

Drum würde ich gerne über einen Button die Reihenfolge anpassen können.

[Hawkeye219]

Moin Dominik,

hier ist der gewünschte Schnipsel:

Delphi-Quellcode:

procedure MoveTreeNode (const aTreeView  : TTreeView;
                        const aNode      : TTreeNode;
                        const aDirection : Integer);
var
  Sibling : TTreeNode;
begin
  if (aNode = nil) then
    Exit;

  if (aDirection < 0)
    then Sibling := aNode.getPrevSibling
    else Sibling := aNode.getNextSibling;

  if (Sibling = nil) then
    Exit;

  aTreeView.Items.BeginUpdate;
  try
    if (aDirection < 0) then
      aNode.MoveTo (Sibling, naInsert)
    else
      Sibling.MoveTo (aNode, naInsert);
  finally
    aTreeView.Items.EndUpdate;
  end;
end;

// Anwendung

MoveTreeNode (TreeView1, TreeView1.Selected, -1); // Knoten nach oben schieben
MoveTreeNode (TreeView1, TreeView1.Selected, +1); // Knoten nach unten schieben

Gruß Hawkeye

[moelski]

Ich kann nur eins sagen :

DANKE ! :thumb: :thumb: