[Sharemem+DLL] String wird nicht korrekt erzeugt.

[QuickAndDirty]

Hallo
ich habe ein Problem mit Strings die direkt aus einer DLL geladen werde.
Es klappt eigentlich immer ausser in einer Konstellation, welche ich in einem
Testprojekt isolieren konnte.

Sharemem ist in der DLL und dem Projekt an erster stelle in den USES, daran liegt es nicht!!!

Wie es aussieht wird der lokale String irgendwie nicht erzeugt so das die zuweisung auch nicht klappt,
als würde die compiler magic für die Strings versagen.

Vermutlich antwortet sowieso niemand auf das Problem, aber hier der Source für beide Test Projekte.

Hauptprojekt

Delphi-Quellcode:

program StringTester;

uses
  sharemem,
  Forms,
  Stringtest in 'Stringtest.pas' {Testform};

{$R *.res}

begin
  Application.Initialize;
  Application.CreateForm(TTestform, Testform);
  Application.Run;
end.

Unit des Projekts

Delphi-Quellcode:

unit Stringtest;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  PBookmarkInfo = ^TBookmarkInfo;
  TBookmarkInfo = Record
    RecordID : Integer;
    BookmarkStr : String;
  end;

  PRecordInfo = ^TRecordInfo;
  TRecordInfo = record
    RecordIDStr: String;//Alternativ wenn Recno nicht unterstützt wird.
    RecordID: Pointer;
    BookmarkStr:String;//Alternativ wenn Recno nicht unterstützt wird.
    Bookmark: Pointer;

  end;

  TGetString = Function :String;

  TTestform = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);

  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;


Const Datasize :integer = 100;//Einfach mal so als ersatz für GetDatasize

var
  Testform: TTestform;
  Buffer : Pointer;
  GetString : TGetString;
  lib:cardinal;

implementation

{$R *.dfm}

procedure TTestform.Button1Click(Sender: TObject);
Var testwert : string;
begin

  testwert := GetString; //String aus DLL!!!!!! über sharemem geholt
  //testwert := #1#2#3#4#5#6; //<-- dieser code geht auch nicht

  getmem(Buffer,Datasize + sizeof(TRecordInfo));
  Fillchar(Buffer^,Datasize + sizeof(TRecordInfo), #0);
  With PRecordInfo(Pointer(integer(Buffer) + Datasize))^ do
  begin
    GetMem(Bookmark , sizeof(TBookmarkInfo) );

    PBookmarkInfo(bookmark)^.BookmarkStr := testwert; //<---hier passiert eine
                                                      //    Zugriffsverletzung,
                                                      
  end;
end;

procedure TTestform.FormCreate(Sender: TObject);
begin
  lib := Loadlibrary('Stringtestdll');
  @GetString := getProcAddress(lib,'GetString');
end;

procedure TTestform.FormDestroy(Sender: TObject);
begin
  FreeLibrary(lib);
end;

end.

Das dazugehörge TEST DLL

Delphi-Quellcode:

library Stringtestdll;

{ Wichtiger Hinweis zur DLL-Speicherverwaltung: ShareMem muss sich in der
  ersten Unit der unit-Klausel der Bibliothek und des Projekts befinden (Projekt-
  Quelltext anzeigen), falls die DLL Prozeduren oder Funktionen exportiert, die
  Strings als Parameter oder Funktionsergebnisse übergeben. Das gilt für alle
  Strings, die von oder an die DLL übergeben werden -- sogar für diejenigen, die
  sich in Records und Klassen befinden. Sharemem ist die Schnittstellen-Unit zur
  Verwaltungs-DLL für gemeinsame Speicherzugriffe, BORLNDMM.DLL.
  Um die Verwendung von BORLNDMM.DLL zu vermeiden, können Sie String-
  Informationen als PChar- oder ShortString-Parameter übergeben. }
  

uses
  sharemem,
  SysUtils,
  Classes;

{$R *.res}

Function GetString : String;
Begin
  result := #6#2#3#4#5#6;
end;

Exports
  GetString;

begin
end.

Ich will gerne das das irgendwie funktioniert, bekomme aber immer eine AV !!!
Die IDE die ich verwende ist Delphi7.

[nuclearping]

Warum verwendest du String statt PChar?

[QuickAndDirty]

Weil ich mich da nicht um die Freigabe kümmern muss.
Der besagte String ist im original ein Bookmarkstring aus einem TDataset.

Warum funzt das mit der borlndmm.dll nicht in diesem fall!!!

[QuickAndDirty]

Ich probiere gerade etwas rumm es kann sein das es nicht mal am dll liegt sondern an sharemem.

OK so geht es auch nicht. Obwohl der String nicht aus der DLL geholt wird.

es scheint so zu sein das sharemem die Strings wenn eine DLL geladen ist nicht mehr korrekt verwalten kann.
kann das sein? Warum?

Delphi-Quellcode:

unit Stringtest;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  PBookmarkInfo = ^TBookmarkInfo;
  TBookmarkInfo = Record
    RecordID : Integer;
    BookmarkStr : String;
  end;

  PRecordInfo = ^TRecordInfo;
  TRecordInfo = record
    RecordIDStr: String;//Alternativ wenn Recno nicht unterstützt wird.
    RecordID: Pointer;
    BookmarkStr:String;//Alternativ wenn Recno nicht unterstützt wird.
    Bookmark: Pointer;

  end;

  TGetString = Function :String;

  TTestform = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);

  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;


Const Datasize :integer = 100;//Einfach mal so als ersatz für GetDatasize

var
  Testform: TTestform;
  Buffer : Pointer;
  GetString : TGetString;
  lib:cardinal;

implementation

{$R *.dfm}

procedure TTestform.Button1Click(Sender: TObject);
Var testwert : string;
begin
  testwert := #1#2#3#4#5#6;  // Das hier geht nicht wenn auch eine DLL geladen
                             // wird und sharemem aktiv ist

  getmem(Buffer,Datasize + sizeof(TRecordInfo));
  Fillchar(Buffer^,Datasize + sizeof(TRecordInfo), #0);
  With PRecordInfo(Pointer(integer(Buffer) + Datasize))^ do
  begin
    GetMem(Bookmark , sizeof(TBookmarkInfo) );

    PBookmarkInfo(bookmark)^.BookmarkStr := testwert; //<---hier passiert eine
                                                      //    Zugriffsverletzung,
                                                      //    allerdings nur wenn
                                                      //    eine DLL geladen ist
                                                      //    und Sharemem aktiv ist;
  end;
end;

procedure TTestform.FormCreate(Sender: TObject);
begin
  lib := Loadlibrary('Stringtestdll'); // Ohne den Code gehts
end;

procedure TTestform.FormDestroy(Sender: TObject);
begin
  FreeLibrary(lib);                          // Ohne den Code gehts
end;

end.

[nuclearping]

Ich würde mich persönlich nicht so darum bemühen, unbedingt mit Strings und DLLs arbeiten zu wollen. Du reservierst doch auch Speicher für "Bookmark", um dessen Freigabe du dich auch kümmern mußt. Und in dem Zug kannst du dann auch den PChar aus der DLL freigeben.

[QuickAndDirty]

Ich weiß nur nicht ob Bookmarkstrings sich hin und her umwandeln lassen und dann noch die Information enthalten.
Zu dem weiß ich nicht mal wann die Bookmarks nicht mehr genutzt werden weil das in der Hand der Datalink Objekte liegt.

Und außerdem liegt der Fehler ja scheinbar gar nicht an den Strings aus der DLL sondern am Sharemem der
die Lokalen variablen nicht vernünftig initialisiert.

Du weißt nicht zufällig eine Lösung?

[nuclearping]

Ne, leider nicht. Außer eben nicht mit Strings zu arbeiten. ;)

[himitsu]

Du könntest es mit WideString versuchen, der läuft nicht über den Delphi-Memory-Manager, also auch nicht über ShareMem

WideSrings kapseln einen OLE-String ... bzw. es ist so Einer und die Speicherreservierungen werden von Delphi einfach nur an die entsprechenden WinAPI-Funktionen weitergeleitet.
Diese Strings werden also von der Ole32.dll (glaub ich) behandelt (Speicher reservieren, freigeben, kopieren usw.)

[QuickAndDirty]

Hm...kriege ich die Problemlos hin und her konvertiert? Und sind die Bookmark informationen eines Bookmarkstrings
einzig und allen in seinem Text Anteil gespeichert?

Wie bekomme ich überhaupt Zugang zu den Informationen des String objects wie z.b. RefCount, Assigned...etc.
Evtl. reicht es ja aus den String manuell zu erzeugen...wenn ich nur wüsste wie das geht.

Ausprobiert hat das Projekt keiner , oder?

[nuclearping]

Wie sieht denn so ein "Bookmarkstring" aus?

[himitsu]

ganz Ehlich, in Verbindung mit diesem Problem solltest du nicht auf die Innere Struktur eingehen (falls sich mal was ändert gibt's Progleme)

aber so als Tipp: System.PStrRec

insgesamt ist es besser/einfacher, wenn du garnicht erst versuchst solche Typen wir Strings, dynamische Arrays und Objecte über solche grenzen hinweg zu nutzen ... gibt hier zwar genug Thread, wo man mit aller gewalt sowas versucht, aber hier wären mit einem PChar viel Arbeit gespart.

[QuickAndDirty]

Zitat:

Zitat von nuclearping

Wie sieht denn so ein "Bookmarkstring" aus?

#0#0#10#111#0#0#0#23#0#0#0#0
Mit variabler länge und Inhalt

[QuickAndDirty]

Zitat:

Zitat von himitsu

ganz Ehlich, in Verbindung mit diesem Problem solltest du nicht auf die Innere Struktur eingehen (falls sich mal was ändert gibt's Progleme)

aber so als Tipp: System.PStrRec

insgesammt ist es besser/einfacher, wenn du garnicht erst versuchst solche Typen wir Strings, dynamische Arrays und Objecte über solche grenzen hinweg zu nutzen ... gibt hier zwar genug Thread, wo man mit aller gewalt sowas versucht, aber hier wären mit einem PChar viel Arbeit gespart.

Würde sharemem den normalen String in der Anwendung initialisieren, wäre das schon vollkommen ausreichend...
der Fehler geschieht ja auch wenn ich nur Sharemem eingebunden habe.

[himitsu]

die Lösung: du solltest den Speicher für die String-Variable richtig Initialisieren :warn:

Delphi-Quellcode:

GetMem(Bookmark^, sizeof(TBookmarkInfo));
FillChar(Bookmark^, sizeof(TBookmarkInfo), 0);
// oder halt gleich "New" - siehe Anhang

Das Problem ist nicht der übergebene String, sondern der nicht vorhandene, aber angeblich existierende alte String, welchen Delphi versucht freizugeben, bevor es den neuen String da reinspeichert.

und das nächste mal bitte alle Dateien zusammen anhängen ... wir müssen ja nicht mehr arbeit haben, als nötig, um da mal rein zu sehn :zwinker:

[QuickAndDirty]

Na da bin ich mal gespannt was ich da wieder falsch gemacht habe...
Danke schon mal im voraus.

[QuickAndDirty]

@himitsu :
Der angehängte Code verursacht doch die selbe Access Violation.
Wie sollte die unit denn richtiger weise aussehen?

[QuickAndDirty]

Ok, habs glaube ich, das mit new war ne gute idee.

Delphi-Quellcode:

procedure TTestform.Button1Click(Sender: TObject);
Var testwert : string;
begin

  testwert := GetString; //String aus DLL!!!!!! über sharemem geholt
  //Testwert := #1#2#3#4#5#6; //<-- dieser code geht

  getmem(Buffer,Datasize + sizeof(TRecordInfo));
  Fillchar(Buffer^,Datasize + sizeof(TRecordInfo), #0);
  With PRecordInfo(Pointer(integer(Buffer) + Datasize))^ do
  begin
    //GetMem(Bookmark , sizeof(TBookmarkInfo) );
    //FillChar(Bookmark^, sizeof(TBookmarkInfo), 0);
    New(PBookmarkinfo(Bookmark));

    PBookmarkInfo(bookmark)^.BookmarkStr := testwert;
  end;
end;

Warum zum teufel geht das? und Getmem nicht?

[himitsu]

GetMem reserviert nur Speicher

New reserviert und initialisiert den Speicher

ein dynamische Arrays und Strings müssen initialisiert werden, da die Speicherverwaltung dieser Strukturen sonst falsche Daten bekommt, as zu Fehlern führt.


wenn man weiß, wie initialisert werden muß, kann man es auch selber machen.

Delphi-Quellcode:

procedure TTestform.Button1Click(Sender: TObject);
Var testwert : string;
begin

  testwert := GetString; //String aus DLL!!!!!! über sharemem geholt
  //Testwert := #1#2#3#4#5#6; //<-- dieser code geht

  getmem(Buffer,Datasize + sizeof(TRecordInfo));
  Fillchar(Buffer^,Datasize + sizeof(TRecordInfo), #0);
  With PRecordInfo(Pointer(integer(Buffer) + Datasize))^ do
  begin
    GetMem(Bookmark , sizeof(TBookmarkInfo) );
    FillChar(Bookmark^, sizeof(TBookmarkInfo), 0);
    //New(PBookmarkinfo(Bookmark));

    PBookmarkInfo(bookmark)^.BookmarkStr := testwert;
  end;
end;

[QuickAndDirty]

Also bei mir geht nur new
der andere Code schmeiß trotzt initialisierung mit fill char Fehler.


EDIT:
DOCH NICHT.

[himitsu]

hmm, eigentlich sollte beides gehn (bei mir lief Beides ... aber nur mal kurz unter D7 getestet)

[QuickAndDirty]

ja doch geht beides...
Du hast mir den Tag, wahrscheinlich sogar die Woche gerettet...

Wer hätte das gedacht, das ich Speicher in den ich nur Reinschreiben will
trotzt dem nullen muss...tja Strings machens möglich...

Vielen Dank für eure Mühen Himitsu und NuklearPing.