Wie eine Prozedur mit Parametern per Syncronize() aufrufen?

[BlueStarHH]

Hallo alle zusamen!

Ich habe mir folgende Thread-Klasse erstellt:

Delphi-Quellcode:

TSendMailsProgress = procedure(Sender: TObject; MailNr, MailsLeft: Integer; TimeRunning, TimeLeft: TTime) of object;

TMailSendThread = class(TThread)
private
  FOnSendMailsProgress: TSendMailsProgress;
public
  procedure Execute; override;

  property OnSendMailsProgress: TSendMailsProgress read FOnSendMailsProgress write FOnSendMailsProgress;
end;

procedure TMailSendThread.Execute;
var
  MailNr, MailsLeft: Integer;
  TimeRunning, TimeLeft: TTime;
begin

  while not Terminated do
  begin
    //Hier passiert auch noch was. Gelöscht, damit es übersichtlicher ist.
    //Z.B. werden MailNr, MailsLeft, TimeRunning, TimeLeft hier gefüllt.

    if Assigned(FOnSendMailsProgress) then
      FOnSendMailsProgress(Self, MailNr, MailsLeft, TimeRunning, TimeLeft);
  end;

end;

Ich möchte nun die Methode OnSendMailsProgress über Synchronize aufrufen, da dort Interkationen mit der VCL/GUI stattfinden. Wie kann ich dies tun? Ich habe es wie folgt probiert:

Delphi-Quellcode:

procedure TMailSendThread.Execute;
var
  MailNr, MailsLeft: Integer;
  TimeRunning, TimeLeft: TTime;

  procedure DoSendMailsProgress;
  begin
    if Assigned(FOnSendMailsProgress) then
      FOnSendMailsProgress(Self, MailNr, MailsLeft, TimeRunning, TimeLeft);
  end;

begin

  while not Terminated do
  begin
    //Hier passiert auch noch was. Gelöscht, damit es übersichtlicher ist.
    //Z.B. werden MailNr, MailsLeft, TimeRunning, TimeLeft hier gefüllt.

    Syncronize(DoSendMailsProgress); //<-- FEHLER !!!!!
  end;

end;

Dort wird der Fehler "Inkompatible Typen: Methodenzeiger und reguläre Prozedur" angezeigt. Ersetze ich die Zeile mit dem Fehler durch

Delphi-Quellcode:

Synchronize(@DoSendMailsProgress); // @-Zeichen beachten

erscheint der Fehler "Inkompatible Typen: TThreadMethod und Pointer".

Wer hat eine Lösung? Danke!

[Apollonius]

Packe DoSendMailsProgress als Methode in die Klasse und speichere MailNr, MailsLeft, TimeRunning und TimeLeft als Felder.

[BlueStarHH]

Zitat:

Zitat von Apollonius

Packe DoSendMailsProgress als Methode in die Klasse und speichere MailNr, MailsLeft, TimeRunning und TimeLeft als Felder.

Gibt es keine andere Möglichkeit? Ich habe noch 7 andere Events mit zusammen 24 Parametern. Das wird doch dann irgenwie unübersichtlich und ist auch nicht mehr schönes OOP.

[DeddyH]

Du brauchst ja eine Methode und diese ist nunmal Teil einer Klasse.

[himitsu]

Das ist eigentlich das Standardvorgehen bei solchen Problemen.

Du kannst dir ja die zusammengehörigen Felder/DoIrgendwasProzeduren in der Threaddefinition übersichtlich gruppieren.

[Apollonius]

Anonyme Methoden sind doch etwas feines...

[DeddyH]

Zitat:

Zitat von Apollonius

Anonyme Methoden sind doch etwas feines...

In Delphi 5?

[himitsu]

Delphi-Quellcode:

type TMailSendThread = Class(TThread)
  ....
  private
    FSendMailsProgress: record
      OnSendMailsProgress: TSendMailsProgress;
      MailNr, MailsLeft: Integer;
      TimeRunning, TimeLeft: TTime;
    end;
    procedure DoSendMailsProgress
  end;

procedure TMailSendThread.DoSendMailsProgress;
begin
  with FSendMailsProgress do
    if Assigned(OnSendMailsProgress) then
      FOnSendMailsProgress(Self, MailNr, MailsLeft, TimeRunning, TimeLeft);
end;

[BlueStarHH]

Zitat:

Zitat von Apollonius

Anonyme Methoden sind doch etwas feines...

Wie würde man es damit machen? Demnächst muss das Delphi 5 hier mal durch 2009 ausgewechselt werden ;-)

[Apollonius]

Allen Bauer erklärt das hier ganz gut. In der Kurzfassung:

Delphi-Quellcode:

Synchronize(procedure
begin
  if Assigned(FOnSendMailsProgress) then
    FOnSendMailsProgress(Self, MailNr, MailsLeft, TimeRunning, TimeLeft); 
end);

Das kannst du dann direkt in die Execute-Methode schreiben.