Delphi-PRAXiS
Seite 25 von 35   « Erste     15232425 2627     Letzte » 

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Software-Projekte der Mitglieder (https://www.delphipraxis.net/26-software-projekte-der-mitglieder/)
-   -   himXML (gesprochen himix ML) (https://www.delphipraxis.net/130751-himxml-gesprochen-himix-ml.html)

himitsu 28. Aug 2010 19:17

AW: himXML (gesprochen himix ML)
 
Von den üblichen/"unterstützten" Codierungen nur das, da Windows ein bissl rumzickt und ich dafür keine eigene (De)Codierung integriert hab.

So wie du es jetzt hast, wird das UTF-16 mit durch's UCS2 (Unicode) geschleift. Und solange keine "exotischen" höheren Zeichen über #32767 vorkommen sollte es keine Probleme geben.

Ansonsten ist im aktuellen Code keine Objekt-Serialisierung vorhanden, da es einige Problemchen mit der Deserialisierung gab.
Records und Variants können aber serialisiert werden, wobei die Recordserialisierung demnächst auch noch um die Möglichkeiten der neuen Delphi 2010-RTTI aufgemotzt wird.

Wobei ich derzeit das ganze Projekt umgestalte, da endlich das Problem der sich selbsthaltenden Kreizreferenzen bei Interfaces gelöst ist und somit Interfaces wieder verwendet werden können ... dafür gibt es hier auch eine "coole" selbsentwickelte Neuerung, wo ich die Interfaces ein bissl "mishandle".

RWarnecke 28. Aug 2010 19:37

AW: himXML (gesprochen himix ML)
 
Das hört sich ja richtig gut. Bin schon auf die neue Version gespannt.

geskill 8. Okt 2010 11:45

AW: himXML (gesprochen himix ML)
 
hey himitsu,
benutze deine XML Lib nun schon eine Weile, bislang habe ich diese immer direkt ins Programm eingebunden, jedoch benutze ich in meinem Programm viele Plugins, wodurch sich eine bpl zur Zentralen Einbindung der Komponente lohnte. Nun klappts jedoch nicht mehr so richtig mit dem lesen und schreiben. Ich nutze die hoffentlich aktuelle v0.99d.

Wenn ich z.b. eine XML Datei speichern möchte (existiert bereits, ANSI Codiert, nur XML Header enthalten [<?xml version="1.0" ?>] ) kommt dieser Fehler:
Zitat:

[EXMLException] TXMLFile.SaveToStream:
invalid value

TXMLFile.AssembleTree:
error on line 0 and col 22 (at byte position 0)

TXWriter.SetVer:
unknown xml version
Mit diesem Schnippsel hat es eigentlich immer ganz gut geklappt:
Delphi-Quellcode:
  XMLDoc := TXMLFile.Create;
  try
    with XMLDoc do
    begin
      LoadFromFile(WebsiteSettingsFile);
      // Active := True;
      Options := Options + [xoNodeAutoIndent];
      DefaultTextIndent := #9;
    end;

    // optionen setzten

    XMLDoc.SaveToFile(WebsiteSettingsFile);
  finally
    XMLDoc.Free;
  end;
Das komische ist auch, dass es beim ersten mal klappt, wenn ich dann jedoch die Datei nochmal abspeichern will bekomme ich diesen Fehler -,-

himitsu 8. Okt 2010 12:46

AW: himXML (gesprochen himix ML)
 
Kann's hier nicht ausprobieren.
Werd' es mir aber die nächsten Tage mal ansehn, wenn ich wieder daheim bin.

Nja, aktuell ... joar, von den öffentlichen Versionen ist es schon die Aktuelle.

Aber ertsmal sehn woran es liegt, vom Leseverhalten, hat die interne Version, theoretisch keine großen Änderungen diesbezüglich bekommen.
(bin "nur" dabei den Kern, also sozusagen die internen Verwaltungssachen komplett umzustellen und die Schnittstelle/Interfaces ein bissl zu optimieren)

Medium 9. Okt 2010 02:19

AW: himXML (gesprochen himix ML)
 
Moin Himi!

Erstmal ganz ganz heissen Dank für dieses Prunkstück! Damit lässt sich wirklich komfortabel arbeiten.

Bis auf... ;)
Ich möchte ganz gerne zwei (benachbarte) Nodes vertauschen, jedoch habe ich Probleme mit der Insert()-Funktion. Diese lässt scheinbar die Fäden des eingefügten Nodes baumeln, oder so etwas in diese Richtung. Ziel ist es einen Node nach oben oder unten wandern lassen zu können.

Delphi-Quellcode:
// Alle Nodes haben ein Attribut "ID", welches in den Tags der Listbox-Items wieder auftaucht.
// Dadurch kann ich querindizieren, egal was wo in welcher Liste genau an welcher internen Array-
// Position steht.
var
  n, f: TXMLNode;
  fi, iid, fiid: Integer;
begin
  iid := lbElements.ListBoxItems[lbElements.ItemIndex].Tag; // ID-Attribut des Nodes zum selektierten Listbox-Eintrag ermitteln
  fiid := lbElements.ListBoxItems[lbElements.ItemIndex+1].Tag; // Auch die ID des in der Listbox folgenden Eintrags
  n := CurrentFrameXML.RootNode.Nodes['#Element>ID='+IntToStr(iid)]; // Node zur ID finden
  f := CurrentFrameXML.RootNode.Nodes['#Element>ID='+IntToStr(fiid)]; // Auch zum nächsten

  fi := CurrentFrameXML.RootNode.Nodes.IndexOf(f); // Index im internen Array zum Folgeknoten ermitteln
  CurrentFrameXML.RootNode.Nodes.Insert(CurrentFrameXML.Nodes.CloneNode(n), fi); // An diese Stelle eine Kopie von "n" einfügen
  CurrentFrameXML.RootNode.Nodes.Delete(n); // Das alte "n" killen
  XMLToListBox(CurrentFrameXML); // Die flache knotenstruktur in ne LB werfen
end;
Das ganze funktioniert nur so lange, wie der Folgeknoten "f" nicht schon vorher einmal verschoben wurde! Dann nämlich wird dieser in der Zeile "fi := ..." nicht mehr gefunden, und die gesamte Struktur ist dahin. (Der Node an sich wird gefunden, sein Index allerdings nicht mehr.) Genauer gesagt wird dann an Index -1 ge-inserted, wodurch nur noch dieser Node in der Liste ist. So als würde der RootNode geleert, und dieser als einziger eingefügt.

Die Listbox wird in der Reihenfolge des internen Arrays vom RootNode befüllt, so dass in der Listbox benachbarte Einträge auch im RootNode benachbarten Knoten entsprechen sollten.

Wat ist da los? Oder geht das 100x einfacher, und es ist für mich nur zu spät geworden heut abend? :)

xZise 9. Okt 2010 11:30

AW: himXML (gesprochen himix ML)
 
Moin Medium,
irgendwie fehlt mir das einfügen des Knoten f. Aktuell schreibst du vor den Knoten f den Knoten n. Aber den Knoten f setzt du nicht an die Position, wo der Noten n vorher war oder?

MfG
Fabian

Medium 9. Okt 2010 18:17

AW: himXML (gesprochen himix ML)
 
Da es ja ein Insert(), kein Replace() ist, sollte der ja eigentlich einfach nur verrutschen :gruebel:

xZise 10. Okt 2010 12:35

AW: himXML (gesprochen himix ML)
 
Moin,
wenn du allerdings in der Liste mehrere Nodes zwischen n und f hast.
Zum Beispiel:
Code:
abc n opq f ghi
Dann sieht das danach so aus:
Code:
abc n opq n f ghi
Code:
abc opq n f ghi
Aber ein austauschen sieht für mich so aus:
Code:
abc f opq n ghi
MfG
Fabian

Medium 10. Okt 2010 13:19

AW: himXML (gesprochen himix ML)
 
Das ist nicht gegeben. n unf f stehen sowohl in der Listbox, als auch im XMLNode direkt hintereinander. Dessen bin ich mir sicher, da ich die Listbox bei jeder Änderung im XML immer frisch aus dem Node befülle, und dabei nicht auf XMLNode.NextNode zurückgreife, sondern wirklich per Index durch XMLNode.Nodes[i] iteriere. f ist immer der Folgeknoten von n (deswegen f :) ).
Auf diese Weise habe ich mit TList auch schon öfter gearbeitet, was okay war. Die Funktion die ich damit realisieren will ist einfach, dass man mit 2 Buttons "hoch" und "runter" ein Item pro Klick um einen Platz rauf oder runter wandern lassen kann. Dies innerhalb der Listbox allein reicht jedoch nicht, sondern muss schon in der Datenhaltung darunter ebenfalls passieren, dem XML.

Edit: Um das eigentliche Problem nochmal zu verdeutlichen: Ein via Insert() eingefügter Node wird nachher nicht mehr im Array des Elternknotens gefunden. Sowohl ParentNode.IndexOf(n) als auch n.Index liefern -1, obgleich ich den Knoten per n := ParentNode.Nodes['#NodeName>Attribut1=aValue'] ermittelt habe.

Meine Verschiebung geht daher, aber auch nur, wenn kein beteiligter Knoten zuvor schon ein mal verschoben wurde.

Besonders ärgerlich dabei: Ein Haltepunkt in der Insert() Funktion in der himXML.pas wird zur Laufzeit deaktiviert. Ich kann also garnicht nachvollziehen, was da genau passiert - oder auch nicht :( Sogar mit F7 reinsteppen tut nicht, der Debugger hüpft einfach drüber.

himitsu 10. Okt 2010 20:48

AW: himXML (gesprochen himix ML)
 
@geskill: kommst auch gleich dran

@Medium:
die 1 vor die 3 verschieben
Delphi-Quellcode:
n := XML.RootNode.Nodes['#Element>ID=1'];
f := XML.RootNode.Nodes['#Element>ID=3'];
XML.RootNode.Nodes.Insert(n, f, True);
oder die 1 ausschneiden und vor der 3 wieder einfügen
Delphi-Quellcode:
n := XML.RootNode.Nodes.Remove('#Element>ID=1');
f := XML.RootNode.Nodes['#Element>ID=3'];
XML.RootNode.Nodes.Insert(n, f, True);
Ich würde aber Ersteres bevorzugen, denn falls was beim Einfügen schief geht (Exception), dann würde f wild in der Gegend rumliegen (Speicherleck).

bzw, die 1 hinter die 3 verschieben
Delphi-Quellcode:
n := XML.RootNode.Nodes['#Element>ID=1'];
f := XML.RootNode.Nodes['#Element>ID=3'];
XML.RootNode.Nodes.Insert(n, f);
oder die 1 ausschneiden und nach der 3 wieder einfügen
Delphi-Quellcode:
n := XML.RootNode.Nodes.Remove('#Element>ID=1');
f := XML.RootNode.Nodes['#Element>ID=3'];
XML.RootNode.Nodes.Insert(n, f);

Nun aber noch 2 kleine Fehlerkorrekturen:
- In TXMLNodeList.Remove das "not" entfernen
- und nach dem Insert waren wirklich ein paar Zeiger fehlerhaft
Delphi-Quellcode:
    Function TXMLNodeList.Insert(Node, RNode: TXMLNode; previousR: Boolean = False): TXMLNode;
      Begin
        If not (Node is TXMLNode) Then
          Raise EXMLException.Create(ClassType, 'Insert', @SInvalidNode);
        If (Assigned(_Parent) and (_Parent.InnerText <> '')) or (Assigned(_FirstNode)
            and ((_FirstNode.NodeType = xtCData) or (Node.NodeType = xtCData))) Then
          Raise EXMLException.Create(ClassType, 'Insert', @SIsTextNode, _Parent.Name);
        If Assigned(RNode) and (not (RNode is TXMLNode) or (RNode.ParentList <> Self)) Then
          Raise EXMLException.Create(ClassType, 'Insert', @SNodeNotInList);
        If Assigned(Node.ParentList) Then Node := Node.ParentList.Remove(Node);
        Inc(_NodesCount);
        If previousR Then Begin
          If not Assigned(RNode) Then RNode := _FirstNode;

          If not Assigned(_FirstNode) or (_FirstNode = RNode) Then _FirstNode := Node;
          If not Assigned(_LastNode)                         Then _LastNode := Node;
          If Assigned(RNode) Then Begin
            If Assigned(RNode.InnerPrev) Then RNode.InnerPrev.InnerNext := Node;
            Node.InnerPrev := RNode.InnerPrev;
            Node.InnerNext := RNode;
            RNode.InnerPrev := Node;
          End;
        End Else Begin
          If not Assigned(RNode) Then RNode := _LastNode;

          If not Assigned(_FirstNode)                        Then _FirstNode := Node;
          If not Assigned(_LastNode) or (_FirstNode = RNode) Then _LastNode := Node;
          If Assigned(RNode) Then Begin
            If Assigned(RNode.InnerNext) Then RNode.InnerNext.InnerPrev := Node;
            Node.InnerNext := RNode.InnerNext;
            Node.InnerPrev := RNode;
            RNode.InnerNext := Node;
          End;
        End;
        Node.CheckCrypted(True);
        Result := Node;
        DoNodeChange(Result, xcAddetNode);
      End;


Alle Zeitangaben in WEZ +1. Es ist jetzt 14:35 Uhr.
Seite 25 von 35   « Erste     15232425 2627     Letzte » 

Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf