FileStream + Strings speichern

[ok.de]

Hallo!

Mein Problem ist folgendes: Ich versuche in einen FileStream dynamische Strings abzuspeichern, indem ich vor dem eigentlichen String dessen Länge abspeichere. Allerdings bekomme ich beim Auslesen verschiedene Fehlermeldungen, z.Z. sind es AVs. Hier ein bisschen Code:

Delphi-Quellcode:

type
  TTrainerDataData = record
    nr: Integer;
    kat: String;
    frage: String;
    awA: String;
    awB: String;
    awC: String;
    lsg: Char;
  end;
  TTrainerData = class
    dataSize: Integer;
    constructor create;
    function open(Datei: String):Boolean;
    function count:Integer;
    function getSize:Integer;
    procedure reset;
    function read:Boolean;
    function write:Boolean;
    procedure close;
  public
    Data: TTrainerDataData;
    f: TFileStream;
  end;

{...}

// SPEICHERN
function TTrainerData.write:Boolean;
var
  i: Integer;
begin
  result := TRUE;
  try
    f.Position := 0;
    f.Seek(0, soFromEnd);
    f.Write(data.nr, SizeOf(data.nr));

    i := Length(data.kat);
    f.Write(i, SizeOf(Integer));
    f.Write(data.kat, i);

    i := Length(data.frage);
    f.Write(i, SizeOf(Integer));
    f.Write(data.frage, i);

    i := Length(data.awA);
    f.Write(i, SizeOf(Integer));
    f.Write(data.awA, i);

    i := Length(data.awB);
    f.Write(i, SizeOf(Integer));
    f.Write(data.awB, i);

    i := Length(data.awC);
    f.Write(i, SizeOf(Integer));
    f.Write(data.awC, i);

    f.Write(data.lsg, SizeOf(data.lsg));
  except
    result := FALSE;
  end;
end;

// AUSLESEN
function TTrainerData.read:Boolean;
var
  size: Integer;
  i: Integer;
begin
  result := TRUE;
  try
    f.ReadBuffer(data.nr, sizeOf(data.nr));
    f.ReadBuffer(i, SizeOf(Integer));
    f.ReadBuffer(data.kat, i);
    f.ReadBuffer(i, SizeOf(Integer)); // Hier tritt eine AV auf
    f.ReadBuffer(data.frage, i);
    f.ReadBuffer(i, SizeOf(Integer));
    f.ReadBuffer(data.awA, i);
    f.ReadBuffer(i, SizeOf(Integer));
    f.ReadBuffer(data.awB, i);
    f.ReadBuffer(i, SizeOf(Integer));
    f.ReadBuffer(data.awC, i);
    f.ReadBuffer(data.lsg, SizeOf(data.lsg));
  except
    result := FALSE;
  end;
end;

Ich rufe die Funktion folgendermaßen auf:

Delphi-Quellcode:

    for i := 0 to anz-1 do begin
      Application.ProcessMessages;
      if Abbrechen or fehler then
        break;
      try
        with TrainerStream.TrainerData do begin
          read; // Aufruf
          if not(data.lsg in ['a'..'c']) OR (data.nr = 0) OR (data.frage = '')
              OR (data.awA = '') OR (data.awB = '') OR (data.awC = '') then begin
            ergText := 'Die Datei hat ein ungültiges Format.';
            fehler := TRUE;
            break;
          end;
        end;
      except
        ergText := 'Die Datei hat ein ungültiges Format.';
        fehler := TRUE;
        break;
      end;
    end;

Danke im Vorraus.

[himitsu]

data.awB zeigt nicht auf die Stringdaten, sondern einen internen Zeiger ...
wenn du den einfac so überschreibst, und so die innere Struktur zerstörst, dann dreht da auch schonmal was durch :zwinker:

data.awB[1] = Position des ersten Zeichens und damit der Anfang des enthaltenen Textes.

Delphi-Quellcode:

f.ReadBuffer(data.nr, sizeOf(data.nr));
f.ReadBuffer(i, SizeOf(Integer));
SetLength(data.kat, i);
f.ReadBuffer(data.kat[1], i);
f.ReadBuffer(i, SizeOf(Integer));
SetLength(data.frage, i);
f.ReadBuffer(data.frage[1], i); 
...

Beim Speichern speicherst du ohne die [1] nur den Zeiger und irgendwas anderes und nicht den Text.

außerdem mußt du die länge des Strings vorm Reinladen des Textes setzen.

dabei mußt du aber aufpassen, daß ein String nie leer ist. (außer du machst eine Abfrage rein)

Delphi-Quellcode:

f.ReadBuffer(i, SizeOf(Integer));
SetLength(data.kat, i);
if i > 0 then f.ReadBuffer(data.kat[1], i);

(dieses ebenso beim Speichern)

[ok.de]

Funktioniert super, vielen dank!

Aber ich versteh noch nicht ganz, warum ich nur das erste Zeichen speichern darf :?: Dann dürfte ich doch auch nur das erste Zeichen auslesen können?? Was versteh ich da falsch?

[himitsu]

Nee nee, nicht NUR das erste Zeichen ... AB dem ersten Zeichen.

Intern sind Strings, dynamische Arrays und Objekte erstmal nur eine 4-Byte-Variable, welche erst auf die eigentlichen Daten zeigt.

Bei Parametern bzw. bei @VariablenName zeigt das also erstmal nur auf den internen Zeiger.
Es wird alles delphiintern geregelt, man muß sich da um nix kümmern, aber will man man an die Daten, dann muß man eben beachten, daß die Variable eigentlich nur eine Art Pointer ist und man sie somit erstmal irgendwie dereferenzieren muß :angel: