OpenXML

[delphinia]

Hallo.

ich verwende obenXML

Das Problem was ich nu habe


ich wil eine XML speichern/erstellen die so aussieht

XML-Code:

<?xml version="1.0" encoding="UTF-8"?>

<daten name="MEINE DATEN">

 <bestand name="X1">
  <regal dat="1a">CD1</regal>
  <regal dat="1b">CD2</regal>
  <regal dat="1c">CD3</regal>
  <regal dat="1d">CD4</regal>
  <regal dat="1e">CD5</regal>
 </bestand>
 
 <bestand name="X2">
  <regal dat="2a">VH1</regal>
  <regal dat="2b">VH2</regal>
 </bestand>


 <bestand name="X3">
  <regal dat="3a">DC1</regal>
</bestand>

</daten>

Der Haken es sind die Inhalte "<regal dat="3a">DC1</regal>" variable unterschiedliche anzahl... (for scheife muss genutz werde)...
Wer kann mir dabei helfen??? Denn ich verzweifel solangsma auch was die Formatierung angeht....



MEIN Versuch bzw. die ersten Schritte. Aber das funzt ja hinten und vorne nicht....

Delphi-Quellcode:

procedure TFormular1.Button1Click(Sender: TObject);
var
  FDoc: TDomDocument;
  FNodeElement: TDomElement;
  FNodeText: TDomText;
  FNodeComment: TDomComment;
  s: string;
  Stream: TFileStream;

  node: TDOMElement;

  i, u: Integer;
  K: TDomNodeList;
begin
  FDoc := TDomDocument.Create(DomImplementation1);

  FNodeElement := TDomElement.Create(FDoc, 'daten');
  FDoc.AppendChild(FNodeElement);
  FNodeText := TDomText.Create(FDoc);
  FNodeText.NodeValue := #10#32#32;
  FDoc.FindFirstChildElement.AppendChild(FNodeText);

  with FDoc.FindFirstChildElement do
  begin
    SetAttribute('name', 'MEIN DATEN');
  end;





  FNodeElement := TDomElement.Create(FDoc, 'bestand');
  FDoc.FindFirstChildElement.AppendChild(FNodeElement);
  FNodeText := TDomText.Create(FDoc);
  FNodeText.NodeValue := #10#32#32;
  FDoc.FindFirstChildElement.ChildNodes.Item(1).AppendChild(FNodeText);




  FNodeElement := TDomElement.Create(FDoc, 'bestand');
  FDoc.FindFirstChildElement.AppendChild(FNodeElement);
  FNodeText := TDomText.Create(FDoc);
  FNodeText.NodeValue := #10#32#32;
  FDoc.FindFirstChildElement.ChildNodes.Item(2).AppendChild(FNodeText);


  u := 1;
  for i := 0 to 10 - 1 do
  begin

    FNodeElement := TDomElement.Create(FDoc, 'regal');
    FDoc.FindFirstChildElement.ChildNodes.Item(1).AppendChild(FNodeElement);



    with TDomElement(FDoc.GetElementsByTagName('bestand').Item(0).ChildNodes.Item(u)) do
    begin
      SetAttribute('dat', 'X' + IntToStr(i));
    end;

    u := u + 2;

    FNodeText := TDomText.Create(FDoc);
    FNodeText.NodeValue := #10#32#32#32#32;
    FDoc.FindFirstChildElement.ChildNodes.Item(1).AppendChild(FNodeText);


    FNodeText := TDomCDATASection.Create(FDoc);
    FNodeText.AppendData( 'CD' + IntToStr(i));
    FDoc.GetElementsByTagName('regal').Item(i).AppendChild(FNodeText);

  end;


  FNodeText := TDomText.Create(FDoc);
  FNodeText.NodeValue := #10;
  FDoc.FindLastChildElement.AppendChild(FNodeText);




  Stream := TFileStream.Create('test.xml', fmCreate);
  DomToXmlParser1.WriteToStream(FDoc, 'UTF-8', Stream);
  Stream.Free;

  FDoc.Free;
end;

[jaenicke]

Du brauchst doch gar nicht wieder die Nodes zu suchen mit FindFirstChildElement usw., die hast du doch schon und kannst die einfach zwischenspeichern. Dann wird das auch nicht so unübersichtlich.

Meinst du vielleicht so? ;-)

Delphi-Quellcode:

procedure TfrmMain.btnStartClick(Sender: TObject);
var
  DomDoc: TDomDocument;
  DataNode, CurStockNode, CurRackNode: TDomNode;
  i, j, StockCount, RackCount: Integer;
  CurNodeValue: String;
  FileContents: TFileStream;
begin
  CurNodeValue := #10;
  DomDoc := TDomDocument.Create(dimDomImplementation);

  // Node Daten
  CurNodeValue := CurNodeValue + #32#32;
  DataNode := DomDoc.AppendChild(TDomElement.Create(DomDoc, 'daten'));
  TDomElement(DataNode).SetAttribute('name', 'MEINE DATEN');
  DataNode.AppendChild(TDomText.Create(DomDoc)).NodeValue := CurNodeValue;

  StockCount := Random(3) + 3;
  for i := 1 to StockCount do
  begin
    // Node bestand Xi
    CurNodeValue := CurNodeValue + #32#32;
    CurStockNode := DataNode.AppendChild(TDomElement.Create(DomDoc, 'bestand'));
    TDomElement(CurStockNode).SetAttribute('name', 'X' + IntToStr(i));
    CurStockNode.AppendChild(TDomText.Create(DomDoc)).NodeValue := CurNodeValue;

    RackCount := Random(5) + 3;
    for j := 1 to RackCount do
    begin
      // Node regal
      CurRackNode := CurStockNode.AppendChild(TDomElement.Create(DomDoc, 'regal'));
      CurRackNode.AppendChild(TDomText.Create(DomDoc)).NodeValue := 'CD' + IntToStr(j);
      TDomElement(CurRackNode).SetAttribute('dat', IntToStr(i) + Chr(j + 96)); // a ist 97 ;-)
      if j = RackCount then // beim letzten Node schon die beiden Leerzeichen weniger
        Delete(CurNodeValue, Length(CurNodeValue) - 1, 2);
      CurStockNode.AppendChild(TDomText.Create(DomDoc)).NodeValue := CurNodeValue;
    end;
    if i = StockCount then
      Delete(CurNodeValue, Length(CurNodeValue) - 1, 2);
    DataNode.AppendChild(TDomText.Create(DomDoc)).NodeValue := CurNodeValue;
  end;

  FileContents := TFileStream.Create(ExtractFilePath(ParamStr(0)) + 'test.xml', fmCreate);
  dtxParser.WriteToStream(DomDoc, 'UTF-8', FileContents);
  FileContents.Free;

  DomDoc.Free;
end;

Ergebnis z.B.:

XML-Code:

<?xml version="1.0" encoding="UTF-8"?>
<daten name="MEINE DATEN">
  <bestand name="X1">
    <regal dat="1a">CD1</regal>
    <regal dat="1b">CD2</regal>
    <regal dat="1c">CD3</regal>
    <regal dat="1d">CD4</regal>
  </bestand>
  <bestand name="X2">
    <regal dat="2a">CD1</regal>
    <regal dat="2b">CD2</regal>
    <regal dat="2c">CD3</regal>
    <regal dat="2d">CD4</regal>
  </bestand>
  <bestand name="X3">
    <regal dat="3a">CD1</regal>
    <regal dat="3b">CD2</regal>
    <regal dat="3c">CD3</regal>
  </bestand>
  <bestand name="X4">
    <regal dat="4a">CD1</regal>
    <regal dat="4b">CD2</regal>
    <regal dat="4c">CD3</regal>
    <regal dat="4d">CD4</regal>
    <regal dat="4e">CD5</regal>
  </bestand>
  <bestand name="X5">
    <regal dat="5a">CD1</regal>
    <regal dat="5b">CD2</regal>
    <regal dat="5c">CD3</regal>
    <regal dat="5d">CD4</regal>
    <regal dat="5e">CD5</regal>
    <regal dat="5f">CD6</regal>
    <regal dat="5g">CD7</regal>
  </bestand>
</daten>