Property TFont in neuer Kompo klappt nicht

[Nalincah]

Wie kann ich in ner neuen Kompo ne Eingenschaft vom Typ TFont hinzufügen. Im grunde das gleiche wie die Eigenschaft "Font" beim Button oder nem Label. Bei mir klappt das nicht.

Immer wenn ich im OI bei meiner Kompo die Font ändern will kommt das:

Zitat:

nil kann nicht zu TFont zugewiesen werden

Mein Sourcecode (Ausschnitte):

Delphi-Quellcode:

type TCSTyp = (tAdresse, tRechnung, tLieferung);
       TCSAdressLabel = class(TCSQRRichText)
       private
         FUeberschriftFont:TFont;
       public
         constructor Create(AOwner:TComponent);override;
         destructor Destroy;override;
       published
         property UeberschriftFont : TFont read FUeberschriftFont Write FUeberschriftFont;
       end;

[choose]

Wenn Du das direkte Beschreiben einer Exemplarvariablen zulässt, ist die Referenz auf das zuvor erzeugte Exemplar verloren. Darüber hinaus ist nicht klar, wo das zugewisene Exemplar letztlich wann freigegeben wird:

Delphi-Quellcode:

myFont:= TFont.Create;
try
  AnObject.Font:= myFont;
  AnotherObject.Font:= myFont;
finally
  FreeAndNil(myFont);
end;

Verwende stattdessen eine transparente Zuweisung der Form

Delphi-Quellcode:

TMyClass = class
private
  FFont: TFont;
  procedure SetFont(const AValue: TFont);
public
  property Font: TFont
    read  FFont
    write SetFont;
//...

procedure TMyClass.SetFont(const AValue: TFont);
begin
  FFont.Assign(AValue);
end;

wobei Du das Exemplar hinter FFont einmalig im Konstruktor erzeugst, bzw im Destruktor zerstörst.

[Nalincah]

Zitat:

Zitat von choose

wobei Du das Exemplar hinter FFont einmalig im Konstruktor erzeugst, bzw im Destruktor zerstörst.

Was meinst du damit?

[choose]

Irgendwo muss FFont mit einem Objekt "belegt" werden. Das sollte, wie bei Objekten, die aus anderen Objekten zusammengesetzt (aggregiert) sind, innerhalb des Konstruktors geschehe. zB so:

Delphi-Quellcode:

constructor TMyClass.Create;
begin
  inherited;
  FFont:= TFont.Create;
  //.. some more initialization code
end;

Das Exemplar sollte dann spätestens im Destruktor wieder freigegeben werden

Delphi-Quellcode:

destructor TMyClass.Destroy;
begin
  FreeAndNil(FFont);
  inherited;
end;

[Nalincah]

AHHH. Vielen Dank. Ich wollt erst das AValue anstatt FFont im Constructor erstellen :wall: Klappte natürlich nicht