RichEdit drucken

[gangs-taas]

hey,
könnt ihr mir bei eine code sagen warum der nicht funktioniert ?

ich möchte mein RichEdit drucken und habe hier hier einen code gefunden.
Ich hab das so verstanden das das hier klappen müsste

Delphi-Quellcode:

begin
  // Create a printer selection dialog
  printDialog := TPrintDialog.Create(Form1);

  // If the user has selected a printer (or default), then print!
  if printDialog.Execute then
  begin
    myPrinter := Printer;
    with myPrinter do
    begin
      h := RichEdit1.Handle;
      Printer.BeginDoc;
      PrintRichEditIntoRect(h, Rect(25, 20, 25, 20), -PageRect_MM);
      Printer.EndDoc;
    end;
  end;
end;

aber er sagt das er nicht weiß was "PrintRichEditIntoRect" ist ...
welche unit muss ich dafür einbinden ?

eigl. ist die unit printers eingebunden ...

[DeddyH]

Du musst die Funktion ja auch in Deinen Code einfügen. Sie steht ja auf der verlinkten Seite.

[gangs-taas]

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var
  printDialog : TPrintDialog;
  myPrinter   : TPrinter;
  i, y : integer ;
  h: THandle;


begin
  // Create a printer selection dialog
  printDialog := TPrintDialog.Create(Form1);

  // If the user has selected a printer (or default), then print!
  if printDialog.Execute then
  begin
    myPrinter := Printer;
    with myPrinter do
    begin
      h := RichEdit1.Handle;
      Printer.BeginDoc;
      PrintRichEditIntoRect(h, Rect(25, 20, 25, 20), -PageRect_MM);
      Printer.EndDoc;
    end;
  end;
end;

das hier ist mein code
da ist das doch drin ...
wenn ich auf den button drucken klick soll der drucken ...

oder seh ich das falsch ?

[DeddyH]

Nochmal, schau Dir auf der Seite mal den ersten pinken Kasten an, da steht die Funktion samt einiger Konstantendeklarationen drin. Das muss natürlich auch in Deinen Code.

Zitat:

Delphi-Quellcode:

uses
  Windows, RichEdit;

const
  PageRect_Twips = 144000;  // 100 * twips/inch
  PageRect_Points = 7200;   // 100 * pt/inch
  PageRect_MM = 2540;       // 100 * mm/inch
  PageRect_Printer = 0;

function PrintRichEditIntoRect(RichEditHandle: HWND; const PageRect: TRect;
  RectScaling: Integer = PageRect_Printer; StartPos: Integer = 0;
  EndPos: Integer = -1): Integer;
var
  Range: TFormatRange;
  mm, lpx, lpy, pox, poy: Integer;
begin
  Range.hdc := Printer.Handle;
  Range.hdcTarget := Range.hdc;

  // Get printer resolution
  lpx := 100 * GetDeviceCaps(Range.hdc, LOGPIXELSX);
  lpy := 100 * GetDeviceCaps(Range.hdc, LOGPIXELSY);

  // Convert to device coordinates
  if RectScaling <> PageRect_Printer then
  begin
    // Get physical printing offset
    pox := GetDeviceCaps(Range.hdc, PHYSICALOFFSETX);
    poy := GetDeviceCaps(Range.hdc, PHYSICALOFFSETY);

    if RectScaling < 0 then
    begin
      Range.rc.Left := MulDiv(PageRect.Left, lpx, -RectScaling) - pox;
      Range.rc.Top  := MulDiv(PageRect.Top,  lpy, -RectScaling) - poy;
      Range.rc.Right  := GetDeviceCaps(Range.hdc, PHYSICALWIDTH) -
        MulDiv(PageRect.Right,  lpx, -RectScaling);
      Range.rc.Bottom := GetDeviceCaps(Range.hdc, PHYSICALHEIGHT) -
        MulDiv(PageRect.Bottom, lpy, -RectScaling);
    end
    else
    begin
      Range.rc.Left   := MulDiv(PageRect.Left,   lpx, RectScaling) - pox;
      Range.rc.Top    := MulDiv(PageRect.Top,    lpy, RectScaling) - poy;
      Range.rc.Right  := MulDiv(PageRect.Right,  lpx, RectScaling) - pox;
      Range.rc.Bottom := MulDiv(PageRect.Bottom, lpy, RectScaling) - poy;
    end;
  end
  else
    Range.rc := PageRect;

  // Convert to twips
  Range.rc.Left   := MulDiv(Range.rc.Left,   144000, lpx);
  Range.rc.Top    := MulDiv(Range.rc.Top,    144000, lpy);
  Range.rc.Right  := MulDiv(Range.rc.Right,  144000, lpx);
  Range.rc.Bottom := MulDiv(Range.rc.Bottom, 144000, lpy);

  Range.rcPage := Range.rc;
  Range.chrg.cpMin := StartPos;
  Range.chrg.cpMax := EndPos;

  mm := SetMapMode(Printer.Handle, MM_TEXT);
  try
    SendMessage(RichEditHandle, EM_FORMATRANGE, 0, 0);
    Result := SendMessage(RichEditHandle, EM_FORMATRANGE, 1, Integer(@Range));
    if Result < 0 then
      Result := SendMessage(RichEditHandle, WM_GETTEXTLENGTH, 0, 0);
  finally
    SendMessage(RichEditHandle, EM_FORMATRANGE, 0, 0);
    SetMapMode(Printer.Handle, mm);
  end;
end;

[gangs-taas]

oO okay
dachte man muss die beispiele von einander unabhängig betrachten :-D

danke

[gangs-taas]

hey,
ich weiß zwar das dieser threat eigl. schon nicht mehr aktuell ist, aber ich habe da noch eine frage zu.
und möchte dafür nicht noch einen extra thread aufmachen ....


also das eine RichEdit kann ich ja jetzt problemlos drucken,
aber warum kann ich nicht 3 auf die kleiche seite drucken ?
ich wollte den text in die mitte und oben das datum und unten die seitenanzhal.

ich hab mir gedacht, dass es doch eigl. geh'n müsste

Delphi-Quellcode:

      begin
        REdit1 := RichEdit1.Handle;
        Re_Datum := Datum.Handle;
        Re_Seitenzahl := Seitenzahlen.Handle;
        Printer.BeginDoc;
        PrintRichEditIntoRect(REdit1, Rect(25, 20, 25, 20), -PageRect_MM);
        PrintRichEditIntoRect(Re_Datum, Rect(160, 20, 20, 10), PageRect_MM) ;
        PrintRichEditIntoRect(Re_Seitenzahl, Rect(102, 265, 20, 10), PageRect_MM) ;
        Printer.EndDoc;
      end;

aber er druckt trotzdem nur RichEdit1 und nicht das datum und auch nicht die Seitenzahl ...

woran liegt das ?

[gangs-taas]

*push*

[Progman]

Das einfachste wäre, Datum und Seitenzahl ins Richedit mit einzufügen. Dann wird das auch mit gedruckt ;)

[gangs-taas]

aber ich möchte da ja an eine andere stelle auf der Seite drucken
nämlich einmal unter dem eigl. feld und einmal neben dem feld
nicht in dem Feld ....

das muss doch auch gehn ?!

[DeddyH]

Wieso nicht ganz einfach über Printer.Canvas.TextOut?