BrushCopy - nur schneller (Scanline+Pointer)

[LDericher]

Also, ich versuche eine Möglichkeit zu finden, ein Bitmap (abgelegt in einer selbstdefinierten Listenstruktur) in ein anderes zu kopieren und dabei eine Farbe auszulassen, nämlich die, die in der oberen linken Ecke sitzt.
Mit dem Pixelzugriff funktioniert das auch einigermaßen:

Delphi-Quellcode:

procedure TForm1.MapToImagePix(Aug:TBitmap);
var
  I,
  J:integer;
  T:TColor;
  BMP:TBitmap;
begin
BMP:=List.CurrentContent as TBitmap;
T:=BMP.Canvas.Pixels[1, 1];
for I:=0 to(BMP.Height-1)do
   begin
   for J:=0 to(BMP.Width-1)do
      begin
      if(BMP.Canvas.Pixels[J, I]<>T)
        then Aug.Canvas.Pixels[J, I]:=BMP.Canvas.Pixels[J, I];
      end;
   end;
end;

Der ist mir allerdings zu langsam, da der Mist viel zu oft ausgeführt werden wird :wink:
Also hab ich mir eine Version gebaut, die auf Pointern basiert:

Delphi-Quellcode:

type
{...}
  TPixRec=record
    B,
    G,
    R:Byte;
    end;
  PPixRec=^TPixRec;
{...}
procedure TForm1.MapToImagePoi(Aug:TBitmap);
var
  I,
  J:integer;
  P,
  Q,
  T:PPixRec;
  BMP:TBitmap;
begin
BMP:=List.CurrentContent as TBitmap;
T:=BMP.ScanLine[1];
inc(T);
for I:=0 to(BMP.Height-1)do
   begin
   P:=BMP.ScanLine[I];
   Q:=Aug.ScanLine[I];
   for J:=0 to(BMP.Width-1)do
      begin
      if((P^.R<>T^.R)and(P^.G<>T^.G)and(P^.B<>T^.B))then
        begin
        Q^.R:=P^.R;
        Q^.G:=P^.G;
        Q^.B:=P^.B;
        end;
      inc(P);
      inc(Q);
      end;
   end;
end;

Nur irgendwie tut die nicht ganz, was sie soll: Es werden willkürlich einige Pixel von BMP nicht übernommen, wie man im Demoprojekt sieht.
Links die Version mit Pixeln, rechts die Pointervariante.

MfG,
Euer LDer.

P.S. Edit: Bevor ihr sagt, ich sollte das ganze erstmal in ne neue Unit auslagern, um dann nen OOP-Header drumzuschrauben: Das habe ich vor, aber erst, wenn ich sicher sein kann, dass meine Methode funktioniert ;)

[LDericher]

Wasn los mit euch? :D
Liegts am Sonntag? Habt ihr frei? :D
Sonst wisst ihr doch auf alles ne Antwort! :dp: :dp: :dp:

Naja, ich warte weiterhin gespannt auf einen Hinweis :-P

Gruß von eurem LDer^^

[LDericher]

Okay, ich habs selbst hingekriegt:

Das hier:

Delphi-Quellcode:

if((P^.R<>T^.R)and(P^.G<>T^.G)and(P^.B<>T^.B))

musste durch das hier:

Delphi-Quellcode:

if(P^.R<>T^.R)or(P^.G<>T^.G)or(P^.B<>T^.B)

ersetzt werden... So was blödes :wall:
Und trotzdem Danke auch wenns niemand gesehn hat^^

Bis Bald,
Der LDer

[sx2008]

Warum machst du daraus nicht ein ganz normale Prozedur, die zwei TBitmap als Übergabeparameter bekommt?
Warum arbeitet du so umständlich mit der Variablen "T" anstatt den Rot-, Grün und Blauanteil in einzelne Variablen zu übernehmen?
Das Pixel ganz links oben hat die Koordinaten [0,0] und nicht [1,1].
Ist das ein Versehen oder Absicht?

[himitsu]

Zitat:

Zitat von LDericher

Wasn los mit euch? :D
Liegts am Sonntag? Habt ihr frei? :D

Was'n mit dir los?
Oder hast die Reglung mit dem Puschen vergessen?



Du weißt aber, daß die [1]+Inc(T) nicht die obere linke Ecke ist?
Dieses ist 1 Pixel rechts über der unteren linken Ecke

Delphi-Quellcode:

var C: LongInt;

T := BMP.ScanLine[1];
Inc(T);
C := PLongInt(T)^ and $00FFFFFF;
for I := BMP.Height - 1 downto 0 do
   begin
   P := BMP.ScanLine[I];
   Q := Aug.ScanLine[I];
   for J := BMP.Width - 1 downto 0 do
      begin
      if PLongInt(P)^ and $00FFFFFF <> C then
          begin
          PWord(Q)^ := PWord(P)^;
          Q.R:=P.R;
          end;
      inc(P);
      inc(Q);
      end;
   end; 

// oder

      if PLongInt(P)^ and $00FFFFFF <> C then
          begin
          PLongInt(Q)^ := (PLongInt(Q)^ and $FF000000) or (PLongInt(P)^ and $00FFFFFF);
          end;

// oder     var C2: LongInt;

      C2 := PLongInt(P)^ and $00FFFFFF;
      if C2 <> C then
          begin
          PLongInt(Q)^ := (PLongInt(Q)^ and $FF000000) or C2;
          end;

Wer jetzt wegen dem letzen Pixel Angst hat, bezüglich des einen zusätzlich gelesenen Bytes und einem Zugriffsfehler ... keine Angst, im Bitmap ist der Speicher auf ganze Integer-Grenzen reserviert und notfalls wird aufgerundet.

[brechi]

Warum verwendest du denn die WinAPI nicht?

http://www.winprog.org/tutorial/transparency.html