Sierpinski-dreieck

[Schauer]

Guten Abend

Ich habe ein Problem.

Im Unterricht sollen wir das Sierpinsky-Dreieck programmieren.
( http://www.bjoernmuenstermann.de/Fra...ki_dreieck.gif )

Genauer: Wir sollen eine Stufe eingeben, die besagt wie tief die Dreiecke reichen.
( bsp:
Stufe= 0 --> nur das äußere Dreieck
Stufe= 1 --> ein Dreieck hineingezeichnet
usw. )

Ich hatte mir nun erstmal nur die Dreiecke einige Stufen mit "move to" und "line to" gezeichnet. Um einen möglichen Rhytmus in der Änderung der Werte zu finden.

Folgendermaßen sieht es dann aus:

a= image1.widht
b= image1.height

moveto(a,2/3b)
lineto(1/2a,0)
lineto(0,2/3b)
lineto(a,2/3b)___
moveto(1/4a,1/3b)
lineto(2/4a,2/3b)
lineto(3/4a,1/3b)
lineto(1/4a,1/3b)___
moveto(1/8a,3/6b)
lineto(2/8a,4/6b)
lineto(3/8a,3/6b)
lineto(1/8a,3/6b)___
moveto(1/16a,7/12b)
lineto(2/16a,8/12b)
lineto(3/16a,7/12b)
lineto(1/12a,7/12b)___

und so geht es weiter.
( ___ bedeutet, dass dort ein Dreieck fertig gezeichnet ist )

die Werte verändern sich, pro Dreieck, immer auf folgende Weise:

für a:

Zähler:
1
2
3
1
Nenner:
multipliziert sich bei jeder neuen Tiefe mit 2

für b

Zähler:
2*Zähler der vorherigen Stufe
2*Zähler der vorherigen Stufe+1
2*Zähler der vorherigen Stufe
2*Zähler der vorherigen Stufe

Nenner:
multipliziert sich bei jeder neuen Tiefe mit 2


Ich hoffe ihr versteht wie ich es meine.

Leider passt sich das äußerste Dreieck nicht in dieses System ein.
Darum dachte, ich schreibe es so:

if tiefe=0
then
moveto(a,2/3b)
lineto(1/2a,0)
lineto(0,2/3b)
lineto(a,2/3b)
else
// jetzt kommt das Problem : WIE SCHREIBE ICH DIESEN ALGORYTHMUS???


Also. Ich hoffe ihr könnt mir helfen. Vielleicht seht ihr auch einen Fehler in meiner Überlegung und sagt mir wie ich es besser machen kann. Vielleicht kennt ihr auch einen einfacheren Ansatz.
Ein anderes Problem, ist auch, dass sich diese Dreiecke die gezeichnet werden immer nur weiter in die linke Ecke zeichen. Kennt ihr eine Möglichkeit, dass sich das in jede freie Stelle zeichnen lässt?

Ich hoffe auf schnelle Antwort :/

MfG Schauer

[alleinherrscher]

Hier die schnelle Antwort - Das Sierpinski Dreieck basiert auf Rekursion. D.h. die Funktion, die die Zeichnung übernimmt ruft sich selbst auf:

Delphi-Quellcode:

procedure Sierpinski(a,b,c:TPoint;Rekursionstiefe:integer;aCanvas:TCanvas);
{
 Sierpinski Dreieck (Rekursiv)
 Algorithmus von Alleinherrscher ([url]www.delphipraxis.net[/url])
 28.10.2009
}
var new_a,new_b,new_c:TPoint;
begin

with acanvas do
begin
   moveto((a.x),(a.y));
   lineto((b.x),(b.y));
   lineto((c.x),(c.y));
   lineto((a.x),(a.y));
end;

new_c.x:=(a.x+b.x ) div 2;
new_c.y:=(a.y+b.y)  div 2;

new_a.x:=(b.x+c.x ) div 2;
new_a.y:=(b.y+c.y)  div 2;

new_b.x:=(a.x+c.x) div 2;
new_b.y:=(a.y+c.y) div 2;

if Rekursionstiefe>0 then
begin
   Sierpinski (a,new_c,new_b,Rekursionstiefe-1,aCanvas);
   Sierpinski (new_c,b,new_a,Rekursionstiefe-1,aCanvas);
   Sierpinski (new_b,new_a,c,Rekursionstiefe-1,aCanvas);
end;

end;

Die Funktion ist schwer nachzuvollziehen, wenn man sie nicht selber programmiert hat. Sie funktioniert wie folgt:

Aufzurufen ist die Funktion als so:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var a,b,c:TPoint;
    width:integer;
    top,left:integer;
begin

 width:=200;
 top:=300;
 left:=10;

 //Eckpunkte des äußeren Dreiecks:
 a.x:=left;
 a.y:=top;
 b.X:=width+a.x;
 b.y:=top;
 c.X:=width div 2+left;
 c.y:=round(top-sin(60/360*2*Pi)*width);

 Sierpinski(a,b,c,5,Image1.canvas);
end;

Sie berechnet die Mittelpunkte aller Seiten des Dreiecks (new_a,new_b,new_c) und verbindet diese zu einem Dreieck.
So wird das äußere Dreieck in 4 gleich große Dreiecke aufgeteilt. Nun wird die Zeichnen Funktion erneut aufgerufen mit den Koordinaten der 3 außenliegenden Dreiecke (das in der mitte liegende Dreieck soll ja leer bleiben)

Hoffe, das ist verständlich ;)

//edit: Wäre das nicht was für die Code Library? *stolz sei* :bouncing4:

[Schauer]

Slso soweit komm ich mit, auch wenn ich einzelne Befehle noch nicht kenne, aber ich danke dir wirklich sehr.
Ich werd, sobald ich wieder Zugriff auf mein Programm habe versuchen das in die Tat umsetzen.


Du hast jetzt width einen Wert zugeordnet

( Erinnerung:
width:=200;
top:=300;
left:=10; )

So, ich würde das gern unabhängig von der Größe des Imagefensters machen.
Könntest du das also vllt umschreiben?

MfG Schauer

//edit: Was ist code libary :D ? ( sry )

[alleinherrscher]

:D sry... ich habe in buttonclick width, top, etc. neu deklariert, d.h. in dieser einzelnen Prozedur entspeicht width nicht der Formularbreite sondern ist nur eine Integer-Variable wie jede andere...aber ich machs mal neu, etwas übersichtlicher:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var a,b,c:TPoint;
    Laenge_Dreiecksseite:integer;
    x_Linker_Unterer_Punkt_des_Dreiecks,y_Linker_Unterer_Punkt_des_Dreiecks:integer;
    top,left:integer;
begin

Laenge_Dreiecksseite:=200;
y_Linker_Unterer_Punkt_des_Dreiecks:=300;
x_Linker_Unterer_Punkt_des_Dreiecks:=10;

//Eckpunkte des äußeren Dreiecks:
a.x:=x_Linker_Unterer_Punkt_des_Dreiecks;
a.y:=y_Linker_Unterer_Punkt_des_Dreiecks;
b.X:=Laenge_Dreiecksseite+a.x;
b.y:=a.y;
c.X:=Laenge_Dreiecksseite div 2+a.x;
c.y:=round(top-sin(60/360*2*Pi)*Laenge_Dreiecksseite);

Wenn du noch Fragen zu irgendeinem Befehl hast, sag bitte bescheid!

Ach und: Die Codelibrary ist eine Ansammlung von Algorithmen und sonstigen nützlichen Funktionen/Komponenten etc. die man in Delphi so gebrauchen kann.

[Schauer]

Also jetzt siehts für mich richtig Verständlich :)

Wie gesagt, wenn ich wieder zugang zu meinem Projekt habe, werde ich es versuchen zu übernehmen.

Ich danke für dir die ausführliche Angabe.

Die Code-libary,.. wo finde ich die?

[fkerber]

Hi!

Entweder über die Menüleiste oben oder direkt hier:
http://www.delphipraxis.net/code_library.html


Grüße, Frederic

[Schauer]

Also, ich hab mir das eben nochmal genau angeguckt.

Dein Abschluss deines Buttons heißt:

"Sierpinski(a,b,c,5,Image1.canvas); "

Das heißt ja, dass du deine erste Darstellung, die Sierpinski-prozedur aufrufst.

Was bedeutet darin jetzt die 5 ?
Sorry, falls das jetzt etwas dumm klingt.

Morgen kann ich sagen, ob es geklappt hat.
Danke trotzdem ;)

[alleinherrscher]

Hi! ;) die 5 ist die rekursionstiefe...anders gesagt: "wieviele Dreiecke werden ineinander gezeichnet"