cdecl-Callback und TForm

[Gloegg_FHBI]

Hallo Leute,

Ich sitze grade an einem Programm, welches ein Messgerät (angeschlossen über USB) benutzen soll. Zur Steuerung des Messgerätes habe ich vom Hersteller eine DLL bekommen, diese exportiert 3 Funktionen:

Delphi-Quellcode:

PDWORD = ^DWORD;
PFloatArray = ^TFloatArray;
TFloatArray = array[0..31] of Single;

TDLL_ShowData = procedure (aData : PFloatArray); cdecl;

function InitNeXusDevice(aFunc : TDLL_ShowData) : DWORD; cdecl; external 'NeXusDLL.dll';
function StartNeXusDevice(aSampleRate : PDWORD) : DWORD; cdecl; external 'NeXusDLL.dll';
function StopNeXusDevice : DWORD; cdecl; external 'NeXusDLL.dll';

Die Callback-Funktion sieht folgendermaßen aus:

Delphi-Quellcode:

procedure cbNexus(aData : PFloatArray); cdecl;
var
  i : integer;
  fa : TFloatArray;
begin
  fa := aData^;
  for i := 0 to 31 do
  begin    
    Form3.OnData(nil, i, fa[i], Time-fStartTime);
  end;
end;

Die Methode Form3.OnData macht nichts weiter, als die Daten in ein Memo zu schreiben:

Delphi-Quellcode:

procedure TForm3.OnData(Sender: TObject; aChannel: integer; aValue: single; aTime: TTime);
begin
  memo1.Lines.Add(Format('%i: %10.2f',[aChannel, aValue]));
end;

Das Problem ist nun, das der Zugriff auf Form3 zu einer AV führt. Schreibe ich die Messwerte einfach nur in eine Datei oder ins Eventlog läuft alles.
Woran könnte das liegen?

[sirius]

Wo und wie erzeugst du denn Form3? Ist das eine globale Variable?

[HeikoAdams]

Setz doch mal nen Haltepunkt auf

Delphi-Quellcode:

Form3.OnData(nil, i, fa[i], Time-fStartTime);

und schau im Debugger nach, ob Form3 initialisiert (<> nil) ist.

[himitsu]

Und wieder diese allseits beliebte Frage:
Du greifst da auf die VCL drauf zu ... In welchem Context läuft aber diese Callback-Prozedur?


Auch wenn es nix mit dem Problem zu tun hat.
Man muß ja nicht immer alles eins zu eins übersetzen ...
und darf auch entsprechend die passenden Delphi/Sprach-Features ausnutzen :angel:

Delphi-Quellcode:

type 
  TFloatArray   = packed array[0..31] of Single;  // packed: sicher ist sicher
  TDLL_ShowData = procedure(const aData : TFloatArray); cdecl;

function InitNeXusDevice(aFunc : TDLL_ShowData) : LongWord; cdecl;
  external 'NeXusDLL.dll';

function StartNeXusDevice(var aSampleRate : LongWord) : LongWord; cdecl;
  external 'NeXusDLL.dll';

function StopNeXusDevice : LongWord; cdecl;
  external 'NeXusDLL.dll';

[Gloegg_FHBI]

Hallo und danke für die schnellen Antworten.

Leider kann ich auf den Rechner, an dem das MEssgerät angeschlossen ist, nur per Teamviewer zugreifen. Haltepunkte kann ich deshlab keine setzen...
Aber ich hab mir mit

Delphi-Quellcode:

if assigned(Form3) then

geholfen und Form3 ist initialisiert und kann benutzt werden.

Form3 ist das einzige Formular der Applikation und besteht im wesentlichen aus 2 Knöpfen (Start, Stop) und einem Memo.


Wie kriege ich denn jetzt die DLL dazu im Kontext der VCL zu laufen?

[sirius]

Zitat:

Zitat von Gloegg_FHBI

Wie kriege ich denn jetzt die DLL dazu im Kontext der VCL zu laufen?

Das Memo macht eigentlich kaum riskante Sachen (meist nur ein Haufen an Sendmessages), aber zur Absicherung kannst du ja folgendes implementieren:

Delphi-Quellcode:

const WM_Nexus=WM_User;


procedure cbNexus(aData : PFloatArray); cdecl; 
begin
  sendmessage(Form3.Handle,WM_Nexus,0,integer(aData));  //Das Handle von Form3 könnte man auch noch irgendwo zwischenspeichern
end;


//und in Form3 machst du folgendes:
type
  TForm3=class(TForm)
   ...
  private
   procedure WMNexus(var msg:TMEssage);message WM_Nexus; //hier könnte man TMEssage noch anpassen, ist aber nur Comfort
  ...



procedure TForm3.WMNexus(var msg:TMEssage);
var 
  aData: PFloatArray; 
  i : integer; 
  fa : TFloatArray; 
begin 
  aData:=PFloatArray(msg.lParam);
  fa := aData^;  //warum hier nochmal kopieren?
  for i := 0 to 31 do 
  begin    
    OnData(nil, i, fa[i], Time-fStartTime); 
  end; 
end;

[himitsu]

Zitat:

Zitat von Gloegg_FHBI

Wie kriege ich denn jetzt die DLL dazu im Kontext der VCL zu laufen?

praktisch gesehn ... garnicht

- man kann die Abarbeitung z.B. via Synchronize
in den Hauptthread verlegen (hier nicht so leicht möglich)

- man kann den zugriff auf gemeinsame Daten sperren
(ist mit der VCL nicht leicht möglich)

- du kannst die Daten erstmal irgendwo in einer Liste zwischenspeichern
und dann im Haupthtread (Timer oder Eventgesteuert) dieses auslesen und dort ins Memo einfügen




für Lezteres gibt es mehrere Möglichkeiten

- SendMessage (oder auch Synchronize)
man brauch nicht extra Speicher anlegen, da er direkt weitergegeben wird,
aber solange bis sich der Haupthtread der Abarbeitung annimmt, wartet der andere Thread
und auch wärend der Haupthtrad dann arbeitet

- PostMessage
man kopiert die Daten irgendwo hin und gibt (eventuell samt Datenzeiger) denm Haupthtread nur eine Nachricht, die Abarbeitung hier geht danach sofort weiter
und der Haupthtread nimmt sich, sobald er Zeit hat, diese Nachricht/Message und fügt es ins Memo ein

- passend zu PostMessage oder Eventsteuerung hab ich mir auch noch das gebastelt
http://www.delphipraxis.net/internal...t.php?t=167796
da kann man die Daten kurzzeitig einlagern und dann im Hauptthread wieder rausholen
über 'nen threadsicheren Zugriff auf die Daten kümmert sich dann die Klasse


hier steht euch noch einiges dazu
http://www.delphipraxis.net/internal...t.php?t=167688

[Gloegg_FHBI]

Ok, das mit dem SendMessage klappt jetzt wunderbar, Vielen Dank!

Würde das auch statt mit einer Applikation mit einem Dienst funktionieren?
Letztendlich sollen die Daten nämlich übers Netzwerk verschickt werden und dafür habe ich bereits einen Dienst geschrieben, der die Daten sammelt und dann diese dann an verschiedene Clients schickt.
Dienste haben ja nun kein Fenster mehr, an das man die Message schicken kann, oder?

[sirius]

(/me hat noch nie Dienst programmiert)
Ich würde dann gleich in Richtung Sockets gehen.

[Gloegg_FHBI]

Ja, das hab ich mir auch schon gedacht, immerhin ist der tcp-server ja eh schon im dienst integriert, dann kann der auch gleich noch vom lokalen rechner die daten bekommen.