Delphi-PRAXiS
Seite 1 von 2  1 2   

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Object-Pascal / Delphi-Language (https://www.delphipraxis.net/32-object-pascal-delphi-language/)
-   -   Delphi Record in Record - Der linken Seite kann nichts zugewiesen.. (https://www.delphipraxis.net/146407-record-record-der-linken-seite-kann-nichts-zugewiesen.html)

Andreas L. 19. Jan 2010 13:25


Record in Record - Der linken Seite kann nichts zugewiesen..
 
Hi,

ich habe folgende records:

Delphi-Quellcode:
type
  TRec1 = record
    Enabled: Boolean;
    Text: String;
  end;

  TRec2 = record
    Feld1: TRec1;
    Feld2: TRec1;
  end;

...


var
  myRec: TRec2;
begin
  myRec.Feld1.Enabled := True;
end;
Warum erhalte ich jetzt die Meldung "Der linken Seite kann nichts zugewiesen werden.". Kann ich keinen Record als Feld eines Records verwenden?

MisterNiceGuy 19. Jan 2010 13:32

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Bin mir nicht ganz sicher, aber muss vor "TRec2 = record" nicht noch ein "type"?

p80286 19. Jan 2010 13:34

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Hallo Andreas,

Wenn es so ist, wie du geschrieben hast, dürfte der Fehler nicht auftauchen.
Wenn allerdings Die Records in einer Tlist stecken dann kann es schon passieren.

Gruß
K-H

Andreas L. 19. Jan 2010 13:35

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Zitat:

Zitat von MisterNiceGuy
Bin mir nicht ganz sicher, aber muss vor "TRec2 = record" nicht noch ein "type"?

Ne, braucht man nur einmal für alles was in type deklariert wird:
Delphi-Quellcode:
type
  TRec = record
    //
  end;

  TObj = class(TObject);

  TObjEvent = procedure() of object;
Man kann aber type optional an jeder der Deklarationen voranstellen. Behebt aber mein Problem nicht :(

EDIT:

Zitat:

Zitat von p80286
Wenn allerdings Die Records in einer Tlist stecken dann kann es schon passieren.

Der record wird als Feld einer Komponente eingeführt:

Delphi-Quellcode:
  TSomething = class(TComponent)
  private
    FRec: TRec2;
  published
    property Rec: TRec2 read fRec write FRec;
  end;
Und ich versuche von außen auf diese Eigenschaft zu zugreifen. Ich versuch mal das Feld als public zu definieren. Mal schauen was passiert...

EDIT2: Als public gehts auch nicht :wall:

s.h.a.r.k 19. Jan 2010 13:45

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Also irgendwas läuft bei dir schief :gruebel: habe den Code gerade in D2010 eingefügt, compiliert und alles hat funktioniert. Würde mich auch wundern, wenn das nicht funktionieren würde. Sicher, dass du es so gemacht hast, wie im ersten Post beschrieben?

Edit: Sorry, hab nicht komplett zu Ende gelesen.

Edit 2: Wenn du statt dem Record eine Klasse nutzen würdest, dann geht das, was du willst.

Und wenn ich eine public-Variable einfüge, so compiliert und funktioniert es bei mir!

Andreas L. 19. Jan 2010 13:51

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Hier mal mein original Code:
StartupListView.pas
Delphi-Quellcode:
type
  TStartupListViewColumn = record
    Visible: Boolean;
    Text: String;
  end;

  TStartupListViewColumns = record
    Name: TStartupListViewColumn;
    Status: TStartupListViewColumn;
    Command: TStartupListViewColumn;
    Location: TStartupListViewColumn;
    AppName: TStartupListViewColumn;
    AppManufacturer: TStartupListViewColumn;
    AppDescription: TStartupListViewColumn;
    FileName: TStartupListViewColumn;
    Parameters: TStartupListViewColumn;
  end;

  TStartupListView = class(TListView)
  private
    FVisibleColumns: TStartupListViewColumns;
    ...
  protected
    procedure SetVisibleColumns(Value: TStartupListViewColumns);
    procedure UpdateColumns;
    ...
  public
    ...
    property VisibleColumns: TStartupListViewColumns
      read FVisibleColumns write SetVisibleColumns;
  end;

...

procedure TStartupListView.SetVisibleColumns(Value: TStartupListViewColumns);
begin
  FVisibleColumns := Value;
  UpdateColumns;
end;

procedure TStartupListView.UpdateColumns;
begin
  Columns.BeginUpdate;
  try
    Columns.Clear;

    Columns.Add.Caption := FVisibleColumns.Name.Text;

    if FVisibleColumns.Status.Visible then
      Columns.Add.Caption := FVisibleColumns.Status.Text;

    if FVisibleColumns.Command.Visible then
      Columns.Add.Caption := FVisibleColumns.Command.Text;

    if FVisibleColumns.Location.Visible then
      Columns.Add.Caption := FVisibleColumns.Location.Text;

    if FVisibleColumns.AppName.Visible then
      Columns.Add.Caption := FVisibleColumns.AppName.Text;

    if FVisibleColumns.AppManufacturer.Visible then
      Columns.Add.Caption := FVisibleColumns.AppManufacturer.Text;

    if FVisibleColumns.AppDescription.Visible then
      Columns.Add.Caption := FVisibleColumns.AppDescription.Text;

    if FVisibleColumns.FileName.Visible then
      Columns.Add.Caption := FVisibleColumns.FileName.Text;

    if FVisibleColumns.Parameters.Visible then
      Columns.Add.Caption := FVisibleColumns.Parameters.Text;

  finally
    Columns.EndUpdate;
  end;
end;
Hauptunit, TStartupListView wird ganz normal auf die Form gezogen
Delphi-Quellcode:
procedure TfrmManager.ToolButton1Click(Sender: TObject);
begin
  StartupListView1.VisibleColumns.Name.Visible := True;
  StartupListView1.VisibleColumns.Status.Visible := True;
  StartupListView1.VisibleColumns.Command.Visible := True;
  StartupListView1.VisibleColumns.Location.Visible := True;
  StartupListView1.VisibleColumns.AppName.Visible := True;
  StartupListView1.VisibleColumns.AppManufacturer.Visible := True;
  StartupListView1.VisibleColumns.AppDescription.Visible := True;
  StartupListView1.VisibleColumns.FileName.Visible := True;
  StartupListView1.VisibleColumns.Parameters.Visible := True;

  StartupListView1.StartupList := damData.StartupList;
  StartupListView1.Refresh;
end;
Die Meldung wird bei jeden Schreib-Zugriff auf VisibleColumns ausgegeben.

Naja, wenn niemand mehr eine Idee hat, verwende ich halt ne Klasse.

uligerhardt 19. Jan 2010 13:53

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Bei so einer Frage solltest du schon den Code zeigen, der deinen Fehler erzeugt, und nicht oberflächlich ähnlichen, der aber problemlos kompiliert werden kann. :wall:

Schau mal hier.

s.h.a.r.k 19. Jan 2010 13:55

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Siehe meinen obigen Post -> Edit.

Willst du eigentlich, dass du über den Objektinspektor auf die Eigenschaften zugreifen kannst? Dann würde ich auf Klassen umsteigen. Da hast du imho eh eine bessere Handhabung.

Andreas L. 19. Jan 2010 13:59

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Zitat:

Zitat von uligerhardt
Bei so einer Frage solltest du schon den Code zeigen, der deinen Fehler erzeugt, und nicht oberflächlich ähnlichen, der aber problemlos kompiliert werden kann. :wall:

Der Beispiel-Code ist mit dem original Code identisch :wall: :wink:

Zitat:

hier
Bei so einen Aufwand kann ich mir gleich eine Klasse bauen bzw. werd ich das jetzt auch machen.

Zitat:

Zitat von s.h.a.r.k
Willst du eigentlich, dass du über den Objektinspektor auf die Eigenschaften zugreifen kannst?

Muss nicht unbedingt sein.

EDIT: Hab die records jetzt in Klasse umgebaut. Funktioniert alles super, danke an alle :thumb:

uligerhardt 19. Jan 2010 14:12

Re: Record in Record - Der linken Seite kann nichts zugewies
 
Zitat:

Zitat von Andreas L.
Der Beispiel-Code ist mit dem original Code identisch :wall: :wink:

Das halte ich für ein Gerücht. :P Wenn ich deinen Code aus dem ersten Posting zu einem kompletten Programm ergänze:
Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TRec1 = record
    Enabled: Boolean;
    Text: string;
  end;

  TRec2 = record
    Feld1: TRec1;
    Feld2: TRec1;
  end;

procedure Test;
var
  myRec: TRec2;
begin
  myRec.Feld1.Enabled := True;
end;

begin
  Test;
end.
kompiliert das ohne Fehler oder Warnungen.
Zitat:

Zitat von Andreas L.
Bei so einen Aufwand kann ich mir gleich eine Klasse bauen bzw. werd ich das jetzt auch machen.

ACK. Mit Records wirst du wohl keine elegante Lösung hinkriegen.


Alle Zeitangaben in WEZ +2. Es ist jetzt 07:12 Uhr.
Seite 1 von 2  1 2   

Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf