Prüfen ob Treiber geladen wurde

[Codewalker]

Hallo zusammen.

Ich würde gerne wissen, ob eine bestimmte Treiberdatei (C:\Windows\System32\bla.sys) geladen wurde, d.h. der Treiber aktiv ist und nicht nur die Datei auf der Festplatte liegt. Habt ihr eine Idee, wie man das anstellen könnte?

Grüße

[himitsu]

Das Einfachste ist, den Treiber anzusprechen, wenn er antwortet, dann ist er geladen.

[Codewalker]

Zitat:

Zitat von himitsu

Das Einfachste ist, den Treiber anzusprechen, wenn er antwortet, dann ist er geladen.

Wie soll ich das anstellen? Der Treiber ist nicht von mir, sondern Teil einer Software - geht das dann auch?

[Astat]

Hallo Codewalker, anbei Sample.

Delphi-Quellcode:

uses
  windows,
  SysUtils;

function EnumDeviceDrivers(lpImageBase: PPointer; cb: DWORD;
  var lpcbNeeded: DWORD): BOOL; stdcall; external 'psapi.dll'
    name 'EnumDeviceDrivers';

function GetDeviceDriverBaseName(ImageBase: Pointer; lpBaseName: PChar;
  nSize: DWORD): DWORD; stdcall; external 'psapi.dll'
    name 'GetDeviceDriverBaseNameA';

var
  lpcbNeeded: DWORD;
  ppArray: PPointerArray;
  szDriver: PChar;
  i: integer;
  count: integer;
begin
  if not EnumDevicedrivers(nil, 0, lpcbNeeded) then
    RaiseLastWin32Error;

  GetMem(ppArray, lpcbNeeded);
  try
    if EnumDevicedrivers(@ppArray[0], lpcbNeeded, lpcbNeeded) then begin
      count := lpcbNeeded div 4;
      GetMem(szDriver, MAX_PATH);
      try
        for i := 0 to count -1 do begin
          if GetDevicedriverBaseName(ppArray[i], szDriver, MAX_PATH) = 0 then
            RaiseLastWin32Error;
          writeln(inttohex(dword(ppArray[i]), 8) + ' - ' + szDriver);
        end;
      finally
        freemem(szDriver);
      end;
    end;
  finally
    freemem(ppArray);
  end;
  readln;
end.

lg. Astat

[Codewalker]

Hallo Astat.
Danke, dein Sample klappt einwandfrei :thumb: . Ich habs gestern noch mit WMI versucht, aber darüber kommt man nicht an die nötigen Infos (zumindest will WMI sie mir nicht sagen :mrgreen: ).