Typüberprüfung mit generic Interface

[Stevie]

Hi,

habe folgenden Ausdruck, den ich von C# in Delphi umsetzen möchte:

Code:

public ServiceType ResolveService<ServiceType>(string id) where ServiceType : IService
{
    ...
    IService resolvedService = dict[id];
    if (!(resolvedService is ServiceType))
    {
        throw new InvalidCastException();
    }
    ...
}

Das sieht bisher wie folgt aus:

Delphi-Quellcode:

function TServiceLocator.ResolveService<ServiceType>(id: string): ServiceType;
var
  resolvedService: IService;
begin
  ...
  resolvedService := dict[id];
  if not (resolvedService is ServiceType) then
  begin
    raise Exception.Create('Invalid Cast');
  end;
  ...
end;

Das Problem ist, dass der is Operator nicht bei Interfaces funktioniert. Ok, also Supports benutzt:

Delphi-Quellcode:

if not Supports(resolvedService, ServiceType) then

Geht auch nicht:

Code:

[DCC Fehler] E2250 Es gibt keine überladene Version von 'Supports', die man mit diesen Argumenten aufrufen kann

Hat jemand eine Idee, wie ich die Überprüfung übersetzt bekomme?

[himitsu]

Nur, da ich das hier grade fand
und noch keine Lösung da stand.

Hab selber sowas gebraucht und bastelte mir dabei Folgendes.
Man sieht auch noch schrittweise Ableitung, von dem was mann wollte, bis zu dem, was der Compiler hinbekommt.

Delphi-Quellcode:

uses
  System.SysConst, System.SysUtils;

type
  TMyClass = class
  private
    FIntf: IInterface;
  public
    property Intf: IInterface read FIntf;
    function GetIntf<I: IInterface>: I; inline;
  end;

function TMyClass.GetIntf<I>: I;
begin
  //Result := FIntf as I;

  //if FIntf.QueryInterface(I, Result) <> S_OK then
  //  raise EIntfCastError.Create(SIntfCastError);

  if FIntf.QueryInterface(PTypeInfo(TypeInfo(I)).TypeData.Guid, Result) <> S_OK then
    raise EIntfCastError.Create(SIntfCastError);
end;

Die "Typ-Prüfung" wird bereits beim Parsen erledigt und nicht erst bei der Verwendung, somit kann man sowas nicht direkt verwenden,
da der generische Typ, zu dieser dieser Zeit ja noch nicht existiert, bzw. noch nicht bekannt ist.

Auch sowas wie

Delphi-Quellcode:

SizeOf(Result)

geht da oftmals nicht. (hier eventuell schon, da der Grundtyp des Generics vorgegeben ist)


[edit]
Manchmal kann man es sich auch bissl umständlicher machen. :stupid: (zum Glück hab ich nicht gleich mit TRttiContext nach dem Vögelchen geworfen)

Delphi-Quellcode:

  if FIntf.QueryInterface(GetTypeData(TypeInfo(I)).Guid, Result) <> S_OK then
    raise EIntfCastError.Create(SIntfCastError);