XMLDOMDocument formatiert abspeichern

[win568]

Hi Leute

Ich habe eine eigene XMLDOM Klasse geschrieben, die XML Dokumente lesen, bearbeiten und schreiben kann. Wenn ich nun ein XML Dokument lese und dort Knoten anfüge, werden diese beim Speichern nicht formatiert in das XML File geschrieben. Hier habe ich zwar eine Lösung:

Delphi-Quellcode:

function TBMDXMLDOMDocument.SaveToFile(const AFileName: String): Boolean;

  function WriteDocumentToStream(const ADocument: IXMLDOMDocument2; const AStream: IStream; AEncoding: string = 'UTF-8'): Boolean;
  var
    lWriter: IMXWriter;
    lReader: IVBSAXXMLReader;
  begin
    Result := FALSE;
    try
      // Setze die Properties des XML writer - einschließlich BOM, XML Deklaration und encoding
      lWriter := CoMXXMLWriter60.Create;
      lWriter.byteOrderMark := True;
      lWriter.omitXMLDeclaration := False;
      lWriter.Indent := True;
      lWriter.encoding := AEncoding;

      // Setze den XML writer auf den SAX content handler.
      lReader := CoSAXXMLReader60.Create;
      lReader.contentHandler := lWriter as IVBSAXContentHandler;
      lReader.dtdHandler := lWriter as IVBSAXDTDHandler;
      lReader.errorHandler := lWriter as IVBSAXErrorHandler;
      lReader.putProperty('http://xml.org/sax/properties/lexical-handler', lWriter);
      lReader.putProperty('http://xml.org/sax/properties/declaration-handler', lWriter);

      // Setze den Writer auf den Stream
      lWriter.output := AStream;

      // Nun parse das DOM mit dem SAX handler, und rufe den XML Writer auf
      lReader.parse(ADocument);

      // Schreibe
      lWriter.flush;
      Result := TRUE;
    except
    end;  
  end;

var
  lStream: TFileStream;
begin
  lStream := TFileStream.Create(AFilename, fmCreate or fmShareDenyWrite);
  try
    Result := WriteDocumentToStream(XMLDoc, TStreamAdapter.Create(lStream), Encoding);
  finally
    FreeAndNil(lStream);
  end;
end;

Jedoch hat diese Lösung das Problem, wenn die Datei UTF-8 kodiert ist, dass im XML File die Umlaute nicht mehr UTF-8 konform gespeichert werden. Warum habe ich noch nicht rausgefunden. :wall:

Rufe ich nur die Save Methode des XMLDOM Dokumentes auf, werden die Knoten unformatiert in das XML geschrieben und die Umlaute nicht mehr UTF-8 konform reingeschrieben.

Dem Anschein nach sind die Umlaute verdoppelt im Code:

• XML Tags vor dem Lesen:
  
  <bundesland art="3">Oberösterreich</bundesland>
  <land tld="at" iso_3166_alpha_3="AUT">Österreich</land>
  
  XML Tags nach dem Schreiben:
  
  <bundesland art="3">Oberösterreich</bundesland>
  <land tld="at" iso_3166_alpha_3="AUT">Österreich</land>
  

[himitsu]

Was die Umlaute betrifft, ist die Antwort "einfach".

Beim Auslesen werden diese nicht decodiert (warum auch immer), sondern einfach nur als ANSI ausgelesen.
Am Ende wird das Nichtdecodierte aber nach UTF-8 codiert, welches dann dein Ergebnis zur Folge hat.

[win568]

Hi

Danke für die schnelle Antwort. Was ich jedoch nicht verstehe ist, warum das nicht gemacht wird. Laut Doc wird bei LoadXML das Codierungsverfahren ausgelesen. Diese Methode rufe ich auf. Dann sollten ja die Werte richtig vorhanden sein. Oder muss man noch was aufrufen ??

[himitsu]

Eventuell mußt du es selber behandeln?
Also im selber im contentHandler das Processor-Tag ( <?xml ) aufspüren, den Encoding-Parameter auswerten und dann das Encoding manuell setzen. :gruebel:

[blackfin]

Wegen dem formatieren, vielleicht hilft dir das ja?:

Zitat:

...What you can do is run an XSLT transformation to create an indentend document,
then save that.
The XSLT stylesheet to do that is as easy as

<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>

</xsl:stylesheet>

Apply that with transformNodeToObject to transform the DOM document you
have to a new DOM document, then call the save method on the result.

Das heisst, du transformierst dein XMLDoc erstmal mit einem XSL stylesheet wie oben beschrieben und speicherst dann das.
Das sollte dann die Einrückungen haben.

[win568]

Hi

Nach langem Rumspielen habe ich nun die Lösung. Das Problem war das Laden des XML Dokumentes selbst. Ich habe es mit der TFileStream und TStringStream Klasse gemacht. Diese verwendet jedoch implizit kein WideString, wodurch die Umlaute nicht mehr korrekt an das XMLDOM übergeben wurden. Nach der Änderung:

Code:

    
    lFileStream := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyWrite);
    try
      if Assigned(FOnBeginParse) then begin
        FOnBeginParse(self);
      end;

      try
        FLastParseErrorPos := Point(0, 0);
        FLastParseErrorCode := 0;

        GetXMLDoc.PreserveWhiteSpace := True;
        Result := GetXMLDoc.Load(TStreamAdapter.Create(lFileStream, soReference) as IStream);
        if not Result then begin
          FLastParseErrorPos := Point(GetXMLDoc.parseError.linepos - 1, GetXMLDoc.parseError.line - 2);
          FLastParseErrorCode := GetXMLDoc.parseError.ErrorCode;
          lStr := Format('Parse Error: %s (Line: %d, Pos: %d)', [Trim(GetXMLDoc.parseError.Reason),
                                                                      GetXMLDoc.parseError.Line-1,
                                                                      GetXMLDoc.parseError.LinePos-1]);
          if Assigned(FOnParseError) then begin
            FOnParseError(self, lStr, GetXMLDoc.parseError.Line-1, GetXMLDoc.parseError.LinePos-1);
          end;
        end;
      finally
        if Assigned(FOnEndParse) then begin
          FOnEndParse(self);
        end;
      end;
    finally
      FreeAndNil(lFileStream);
    end;

wurden die Umlaute korrekt angezeigt und auch beim Speichern gabe es keine Probleme mehr. :D

Die Stylesheet Transformation werde ich heute ausprobieren. JEdoch vielen Dank für die Antworten.