Schachfeld mit 2 Figuren (Läufer, Turm)

[Roflto]

So, ich muss/soll ein Schachfeld programnmieren, auf dem 2 Figuren (Turm & Läufer) beliebig stehen. Per Tastendruck wird das Spielfeld mit 2 Figuren erzeugt. Sie sollen Kreise in 2 verschiedenen Farben sein. Per Mausklick soll man sie auswählen können und dann auf ein andres Feld klicken und das Programm erkennt, ob der Zug gültig für diese Figur ist (dann dorthin verschieben), wenn nicht showmessage ('Flascher Zug')

Bin nicht weit gekommen, hänge gerade...

Delphi-Quellcode:

var xx, yy, dx, dy : integer;
var farbe: array [1..8,1..8] of TColor;

var
  Form1: TForm1;

implementation


{$R *.dfm}

procedure TForm1.FormKeyPress(Sender: TObject; var Key: Char);
var i,j, x1, y1, x2, y2, x3, x4, y3, y4, n :integer;
begin
xx:=10;
yy:=10;
dx:=(Form1.ClientHeight-20) div 8;     //Breite der Kästchen
dy:=dx;                                //Höhe der Kästchen
canvas.Pen.color := clblack;
  for i:=0 to 8 do begin               //Schachfeld 8x8 zeichnen
    canvas.MoveTo(xx+(dx*i),yy);
    canvas.lineto(xx+(dx*i),(dy*8)+10);
    canvas.MoveTo(xx,yy+(dy*i));
    canvas.lineto((dx*8)+10,yy+(dy*i));
  end;

x1 := random(8); y1 := random(8);
x2 := x1+1; y2 := y1+1;
x3 := random(8); y3 := random(8);
x4 := x3+1; y4 := y3+1;
farbe[x1,y1]:=clblue;
farbe[x3,y3]:=clred;
   for i:= 0 to 8 do begin
    for j:= 0 to 8 do begin
      if farbe[i,j] <> clblack then begin
        canvas.brush.color:=farbe[x1,y1];
        canvas.Ellipse(xx+(dx*x1),yy+(dy*y1),xx+(dx*x2),yy+(dy*y2));
        canvas.brush.color:=farbe[x3,y3];
        canvas.Ellipse(xx+(dx*x3),yy+(dy*y3),xx+(dx*x4),yy+(dy*y4));
      end;
     end;
    end;
end;

procedure TForm1.FormResize(Sender: TObject);
begin
Form1.Refresh;           //Bild löschen wenn Größenänderung
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
Showmessage('Bitte eine beliebige Taste zum Starten drücken!');
end;


end.

[jfheins]

Hallo,
der Code ist ja ganz nett - er zeichnet das Feld. Hast du dir auch schon zu dem eigentlichen Problem Gedanken gemacht? Wie würdest du sowas sonst lösen?

Zu dem Code: Man könnte das noch etwas auftrennen, und zwar sollte die Platzierung da raus. Dann hast du eine Repaint-Methode und brauchst nur noch das array ändern und die Methode aufrufen ;)

[Roflto]

wie meinste mit platzierung da raus bzw wie würde dass dann aussehen?

zum Problem: ich müsste mit Hilfe eines Array (denke ich) die Punkte/Felder speichern, in denen eine Figur ist und welche Figur das ist (bzw welche Farbe sie hat) und dann eine abfrage reinbringen die beim klick auf diese figur und dann auf ein andres Feld nachprüft ob dieser Zug erlaubt ist...
ich weiß aber ehrlich gesagt nicht wie ich das realisieren soll...das is leider mein prob

[jfheins]

Mit dem Trennen meine ich sowas:

Delphi-Quellcode:

TFigur = enum (fgLaeufer, fgTurm, fgNone); // keine Syntaxgarantie

var
  Form1: TForm1;
  Spielfeld: array [0..7, 0..7] of TFigur;

implementation


{$R *.dfm}


procedure TForm1.RepaintBoard()
const
  topmargin = 20;
  leftmargin = 30;
var
  width, height, i, j: Integer;
begin
  fieldwidth := (ClientWidth - 2 * leftmargin) div 8;
  fieldheight := (ClientHeight - 2 * topmargin) div 8;

  for i := 0 to 7 do
    for j := 0 to 7 do
    begin
      if (i+j) mod 2 = 0 then
        Canvas.brush.Color := clWhite;
      else
        Canvas.brush.Color := clBlack;
      Canvas.rectangle(leftmargin+i*fieldwidth, topmargin+j*fieldheight, fieldwidth, fieldheight);

// wenn du das schon kennst, kannst du folgendes durch ein case ersetzen
      if Spielfeld[i,j] = fgLaeufer then
        // Läufer malen
      else if Spielfeld[i,j] = fgTurm then
        // Turm malen
    end;
end;

procedure TForm1.FormKeyPress(Sender: TObject; var Key: Char);

begin

// Sollte ins OnCreate, und randomize nicht vergessen !!
// Spielfeld mit fgNone initialisieren!
Spielfeld[random(8),random(8)]:=fgNone;
Spielfeld[random(8),random(8)]:=fgNone;
 
end;

procedure TForm1.FormResize(Sender: TObject);
begin
// Nonsense
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
Showmessage('Bitte eine beliebige Taste zum Starten drücken!');
end;

// Noch ein OnFormPaint Ereignis, und darin dann RepaintBoard() aufrufen


end.

So ungefähr. Dass das nicht auf Anhieb compiliert ist mir klar.

[Roflto]

ok ich probiers mal aus, danke vielmals, case hatte ich noch nicht =) und das mit dem
"Noch ein OnFormPaint Ereignis, und darin dann RepaintBoard() aufrufen" hatte ich auch noch nicht

und
TFigur = enum (fgLaeufer, fgTurm, fgNone); // keine Syntaxgarantie
geht nicht und ich hab keine AHnung wie ich das andersch schreiben soll damits compilierbar iwird...der verlangt immer nach einem = anstatt den , die da stehen
und er erkennt den identifier enum nicht

[Bummi]

Delphi-Quellcode:

unit Unit5;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TFeldInfo=record
    Farbe:TColor;
    Figur:Integer;
  end;

  TFeldArray=Array[0..7,0..7] of TFeldInfo;
  TForm5 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    FFeldArray:TFeldArray;
    FLaufer:Tpoint;
    FTurm:Tpoint;
    FSelectedFigure:Integer;
    procedure MoveFromTo(vx, vy, tx, ty:Integer);
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;


const
 C_FeldGroesse=50;
 C_Laufer=1;
 C_Turm=2;
var
  Form5: TForm5;

implementation

{$R *.dfm}

procedure TForm5.FormCreate(Sender: TObject);
var
  x,y:Integer;
begin
  ClientWidth := 8 * C_FeldGroesse ;
  Clientheight := 8 * C_FeldGroesse;
  For y := 0 to 7 do
    for x  := 0 to 7 do
      if (((y and 1)= 1 ) and ((X AND 1)=0)) or (((y and 1)= 0 ) and ((X AND 1)=1)) then FFeldArray[x,y].Farbe := clBlack else FFeldArray[x,y].Farbe := clWhite;

  FLaufer.x := Random(7);
  FLaufer.y := Random(7);
  FFeldArray[FLaufer.x,FLaufer.y].Figur := C_Laufer;
  FTurm.x := Random(7);
  FTurm.y := Random(7);
  while (FTurm.x = Flaufer.x) and (FTurm.y = Flaufer.y)  do
    begin
     FTurm.x := Random(7);
     FTurm.y := Random(7);
    end;
  FFeldArray[FTurm.x,FTurm.y].Figur := C_Turm;



end;

procedure TForm5.MoveFromTo(vx,vy,tx,ty:Integer);
begin
   if FFeldArray[vx,vy].Figur = C_Laufer then
    begin
    Flaufer.X := tx;
    Flaufer.Y := ty;
    end
   else if FFeldArray[vx,vy].Figur = C_Turm then
    begin
    FTurm.X := tx;
    FTurm.Y := ty;
    end;
  FFeldArray[tx,ty].Figur  := FFeldArray[vx,vy].Figur;
  FFeldArray[vx,vy].Figur := 0;
  Invalidate;
end;

procedure TForm5.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  NowSelectedFigure:Integer;
  cx,cy:Integer;
begin
    cx :=  x DIV C_FeldGroesse;
    cy := y DIV C_FeldGroesse;
    NowSelectedFigure := FFeldArray[cx,cy].Figur;
    if NowSelectedFigure <> 0 then  FSelectedFigure :=  NowSelectedFigure
    else
      begin
         if FSelectedFigure=C_Turm then
            begin
            if (cx= FTurm.X) or (cy= FTurm.y) then MoveFromTo(FTurm.X,FTurm.y,cx,cy);
            end
         else if FSelectedFigure=C_Laufer then
            if ABS(cx - Flaufer.X) =  ABS(cy - Flaufer.y) then MoveFromTo(Flaufer.X,Flaufer.y,cx,cy);
      end;

end;

procedure TForm5.FormPaint(Sender: TObject);
var
  x,y:Integer;
  R:TRect;
begin
  For y := 0 to 7 do
    for x  := 0 to 7 do
      begin
      r.Left := x * C_FeldGroesse;
      r.Top  := y * C_FeldGroesse;
      r.Right := x * C_FeldGroesse + C_FeldGroesse;
      r.Bottom  := y * C_FeldGroesse + C_FeldGroesse;
      canvas.Brush.Color := FFeldArray[x,y].Farbe ;
      Canvas.FillRect (R);
      if FFeldArray[x,y].Figur=C_turm then
        begin
          Canvas.Brush.Color := clBlue;
          Canvas.Ellipse(r.Left,r.Top,r.Right,r.Bottom);
        end;

      if FFeldArray[x,y].Figur=C_laufer then
        begin
          Canvas.Brush.Color := clred;
          Canvas.Ellipse(r.Left,r.Top,r.Right,r.Bottom);
        end;

      end;

end;

end.

[jfheins]

Nur mal so gefragt: Ist das ne Schulaufgabe?

[Sir Rufo]

Zitat:

Zitat von jfheins (Beitrag 1032385)

Nur mal so gefragt: Ist das ne Schulaufgabe?

Mal überlegen:

"Ich muss/soll ein Schachfeld ..."
"... case hatte ich noch nicht ..."

Nö, bestimmt nicht :mrgreen:

[Roflto]

ja ist es

[Roflto]

Zitat:

Zitat von Bummi (Beitrag 1032383)

Delphi-Quellcode:

unit Unit5;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TFeldInfo=record
    Farbe:TColor;
    Figur:Integer;
  end;
...

wenn ich da bei mir in mein delphi reinhau, dann passiert bei mir wieder auf mausklick noch auf sonst was, irgend eine reaktion...

[Sir Rufo]

Das muss doch wohl nicht sein, den ganzen Code zu zitieren.
Vor allem nur um zu sagen "Tut nicht!"

[Roflto]

hab es schon geändert

[tkone]

also wenn es eine schulaufgabe ist, dann habt ih sicher schon alle wichtigen dinge im unterricht durchgenommen, die zur erfüllung der aufgabe nötig sind.
erzähl mal ein bisschen, was ihr bereits dran hattet. mit tipps auf dem "richtigen" niveau hilft dir dann jeder weiter.
bloß fertige hausaufgaben bekommst du wahrscheinlich nicht, da es dir sowieso nicht weiter hilft. ;)

[Roflto]

wir hatten arrays, 1 und 2-dimensional, procedures, oncreate, onmousedown,onrepaint und sowas ca.

[Aurelius]

Hm, wenn ihr noch nicht so viel gehabt habt würde ich so an die Sache gehen:

1. Schachfeld aus Paintboxen o.ä. bilden. Das hat den Vorteil dass du relativ leicht auf die Klickereignisse reagieren kannst und auch direkt weißt auf welches Feld wirklich geklickt wurde
2. für die interne Betrachtung ein zweidimensionales Array benutzen, wobei man z.B. als Werte bspw. 0=nicht besetzt, 1=Läufer, 2=Turm nutzen könnte
3. bei jedem Klick auf die Controls jeweils die Positionen abfragen
4. Klick: Ist eine Figur auf dem Feld? Wenn ja Flag setzen, ansonsten nichts machen
5. Klick: Ist Flag für Figur gesetzt? Wenn ja prüfen ob der "Laufweg" korrekt ist, entsprechend bewegen oder Meldung ausgeben

Ich hoffe es ist einigermaßen verständlich :)

[Roflto]

...

[Roflto]

kann mir einer bitte:

Delphi-Quellcode:

if (((y and 1)=1) and ((x and 1)=0)) or (((y and 1)= 0 ) and ((x and 1)=1)) then...

erklären aus dem von Bummi
bzw. mal in Worten schreiben was die einzelnen Sachen bedeuten
was die gesamte zeile bedeutet weiß ich auch

[jfheins]

Das sorgt halt für das typische Schachbrettmuster ;)
Benutzt aber bitweise Operatoren.
Du kannst auch

Delphi-Quellcode:

if (i+j) mod 2 = 0 then

nehmen, das ist vielleicht leichter zu verstehen ;)

[Bummi]

(((y and 1)=1) and ((x and 1)=0))
= Bin ich in einer ungeraden Zeile und Gleichzeitig in einer geraden Spalte?
oder
(((y and 1)= 0 ) and ((x and 1)=1))
= Bin ich in einer geraden Zeile und Gleichzeitig in einer ungeraden Spalte?

and vergleicht hier binär
0 and 1 = 0
1 and 1 = 1
2 and 1 = 0
3 and 1 = 1
....

alle 8 bit zweier werte UND verknüpfen

0 = 00000000
1 = 00000001
2 = 00000010
3 = 00000011

1 and 3:

00000001
00000011
=
00000001


oder

7 und 5

00000111
00000101
=
00000101

Kommst Du damit klar?

[Roflto]

Zitat:

Zitat von jfheins (Beitrag 1032712)

Das sorgt halt für das typische Schachbrettmuster ;)
Benutzt aber bitweise Operatoren.
Du kannst auch

Delphi-Quellcode:

if (i+j) mod 2 = 0 then

nehmen, das ist vielleicht leichter zu verstehen ;)

ok dann hab ichs verstanden ;) geht auch wunderbar, nja war klar, dass ich auf sowas triviales ned komm^^

[Roflto]

jetzt ist hier eindeutig -closed-
hab alles,
hab alles verstanden^^