Delphi-PRAXiS
Seite 1 von 3  1 23      

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   GUI-Design mit VCL / FireMonkey / Common Controls (https://www.delphipraxis.net/18-gui-design-mit-vcl-firemonkey-common-controls/)
-   -   Delphi ComboBox Einträge editieren (https://www.delphipraxis.net/152872-combobox-eintraege-editieren.html)

Chemiker 10. Jul 2010 11:36

ComboBox Einträge editieren
 
Hallo,

ich arbeite zurzeit mit einer ComboBox in der Einträge vorhanden sind und weitere im Programm hinzugefügt werden sollen, desweiteren sollen Einträge auch wieder gelöscht werden. Dafür wird das Event KeyDown benutzt.

Ein wenig Quelltext:

Delphi-Quellcode:
procedure TfrmMainDB_Eigenschaften.cBoxServernameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
var i: integer;
begin
  if Key = VK_RETURN then
  begin
    if cBoxServername.ItemIndex= -1  then    // Kein Eintrag vorhanden
                                              // ohne Prüfung eintragen
    begin
      cBoxServername.Items.Add(cBoxServername.Text);
    end else
    begin
      for I := 0 to cBoxServername.Items.Count - 1 do
      begin
        // Doppelte und leere Einträge verhindern
        if not (cBoxServername.Items[i] =
          cBoxServername.Text) and not (Trim(cBoxServername.Text)= '') then
        begin
          if cBoxServername.Items.IndexOf(cBoxServername.Text) < 0 then
          begin
            cBoxServername.Items.Add(cBoxServername.Text);
          end;
        end;
      end;
    end;
    Key:= 0;
  end;
  if Key = VK_DELETE then
  begin
    for I := 0 to cBoxServername.Items.Count - 1 do
    begin
      if cBoxServername.Items[i] = cBoxServername.Text then
      begin
        cBoxServername.DeleteSelected; // Angezeiter Eintrage löschen
        cBoxServername.ItemIndex := 0; // Auf den ersten Eintrag einstellen
                                       // soweit vorhanden.
        key:= 0;
        break;
      end;
    end;
  end;
  if Key = VK_BACK then
  begin

    key:= 0;
  end;
end;
Bevor ich jetzt weiter mache ist meine Frage, gibt’s dafür eigentlich eine fertige Lösung die ich noch nicht gefunden habe, oder muss man es eben alles von Hand machen?

Bis bald Chemiker

DeddyH 10. Jul 2010 11:56

AW: ComboBox Einträge editieren
 
Sollte nicht in beiden Fällen eine Prüfung mit IndexOf ausreichen? Irgendwie sieht mir das so zu kompliziert aus.

[edit] Ich dachte mir das in etwa so:
Delphi-Quellcode:
procedure TForm1.cBoxServernameKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var idx: integer;
begin
  idx := cBoxServername.Items.IndexOf(cBoxServername.Text);
  case Key of
    VK_RETURN: begin
                 Key := 0;
                 if idx = -1 then
                   cBoxServername.Items.Add(cBoxServername.Text);
               end;
    VK_DELETE: begin
                 if idx > -1 then
                   begin
                     cBoxServername.Items.Delete(idx);
                     if cBoxServername.Items.Count > 0 then
                       cBoxServername.ItemIndex := 0;
                   end;
                 Key := 0;
               end;
  end;
end;
[/edit]
[edit2] Den Signalton bekommst Du übrigens im OnKeyDown nicht weg, das musst Du schon im OnKeyPress machen. [/edit2]

Chemiker 11. Jul 2010 14:09

AW: ComboBox Einträge editieren
 
Hallo DaddyH,

hatte den Quellcode erst grade gesehen. Hatte heute Morgen das Event nach Deiner Empfehlung von gestern noch mal Überarbeitet. Abweichend zu Deiner Lösung werden keine Leerzeichen in die String-Liste übernommen und man kann auch den letzten Eintrag löschen. Habe zusätzlich AutoComplete auf FLASE gesetzt, damit können die vorhanden Einträge besser bearbeitet werden.

Delphi-Quellcode:
procedure TfrmMainDB_Eigenschaften.cBoxServernameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  if Key = VK_RETURN then
  begin
    // Leer Zeichen nicht in die Liste übernehmen.
    if ((cBoxServername.Items.IndexOf(cBoxServername.Text) = -1) and
      (not (Trim(cBoxServername.Text) = ''))) then
    begin
      cBoxServername.Items.Add(cBoxServername.Text);
    end;
  end;
  if Key = VK_DELETE then
  begin
    if cBoxServername.Items.IndexOf(cBoxServername.Text) > -1 then
    begin
      cBoxServername.Items.Delete(cBoxServername.Items.IndexOf(cBoxServername.Text));
      if cBoxServername.Items.Count > -1 then
      begin
        cBoxServername.ItemIndex := 0; // Auf den ersten Eintrag einstellen
                                       // soweit vorhanden.
      end;
    end;
  end;
  Key:= 0;
end;
Vielen Dank für Deine Hilfe.

Bis bald Chemiker

DeddyH 11. Jul 2010 16:58

AW: ComboBox Einträge editieren
 
Den letzten Eintrag kannst Du bei mir auch löschen, nur kannst Du den ItemIndex nicht setzen, wenn gar keine Items vorhanden sind ;)

xZise 11. Jul 2010 17:33

AW: ComboBox Einträge editieren
 
Ich würde auch nicht öfters IndexOf() aufrufen ;) Ich meine O(2n) liegt zwar auch in O(n), aber es halbiert i.A. die Laufzeit ;)

MfG
Fabian

Chemiker 11. Jul 2010 23:05

AW: ComboBox Einträge editieren
 
Hallo,

Zitat:

Zitat von DeddyH
Den letzten Eintrag kannst Du bei mir auch löschen, nur kannst Du den ItemIndex nicht setzen, wenn gar keine Items vorhanden sind

Es gelingt mir nicht den Eintrag zu löschen.

[Edit]
Delphi-Quellcode:
if cBoxServername.Items.Count > 0 then
es müssen min. 2 Einträge vorhanden sein, damit die Bedingung zutrifft.
[/Edit]


Zitat:

Zitat von xZise
Ich würde auch nicht öfters IndexOf() aufrufen Ich meine O(2n) liegt zwar auch in O(n), aber es halbiert i.A. die Laufzeit

Ich glaube nicht das die Ausführungszeit bei einer manuellen Eingabe so relevant ist, zu dem wird wenn nicht Enter oder Entfernen gedrückt wird Zeit eingespart weil IndexOf erst gar nicht aufgerufen wird.

Bis bald Chemiker

DeddyH 12. Jul 2010 09:47

AW: ComboBox Einträge editieren
 
Zitat:

Zitat von Chemiker (Beitrag 1034877)
[Edit]
Delphi-Quellcode:
if cBoxServername.Items.Count > 0 then
es müssen min. 2 Einträge vorhanden sein, damit die Bedingung zutrifft.
[/Edit

Das wäre mir aber neu. Count gibt die Anzahl der Elemente zurück, d.h. ein Count > 0 heißt mindestens ein Element vorhanden.

[edit] OK, hier noch einmal eine überarbeitete Version:
Delphi-Quellcode:
procedure TForm1.cBoxServernameKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var idx: integer;
begin
  //Index einmalig ermitteln
  idx := cBoxServername.Items.IndexOf(cBoxServername.Text);
  //case statt if -> IMHO übersichtlicher und schneller
  case Key of
    VK_RETURN: begin
                 //wenn Text nicht vorhanden und
                 //nicht nur aus Leer- bzw. Steuerzeichen bestehend -> eintragen
                 if (idx = -1) and (trim(cBoxServername.Text) <> '') then
                   cBoxServername.Items.Add(cBoxServername.Text);
               end;
    VK_DELETE: begin
                 //wenn Eintrag gefunden
                 if idx > -1 then
                   begin
                     //Eintrag löschen
                     cBoxServername.Items.Delete(idx);
                     //Erst einmal den alten Text löschen
                     cBoxServername.Text := '';
                     //-> wird ggf. durch geänderten Index neu gesetzt
                     if cBoxServername.Items.Count > 0 then
                       cBoxServername.ItemIndex := 0;
                     //notwendig, da Anzeige sonst nicht aktualisiert wird
                     Key := 0;
                   end;
               end;
  end;
end;

procedure TForm1.cBoxServernameKeyPress(Sender: TObject; var Key: Char);
begin
  //"Bimmeln" unterbinden
  if Key = sLineBreak[1] then
    Key := #0;
end;
[/edit]

Chemiker 12. Jul 2010 18:41

AW: ComboBox Einträge editieren
 
Hallo DeddyH,

Zitat:

Zitat von DeddyH
Das wäre mir aber neu. Count gibt die Anzahl der Elemente zurück, d.h. ein Count > 0 heißt mindestens ein Element vorhanden.

Nochmal zur Klärung:

Count = 0 erster Eintrag
Count = 1 zweiter Eintrag

Wenn Count > 0 // sollte Count mindestens 1 sein um die Bedienung zu erfüllen, oder?

Bis bald Chemiker

jfheins 12. Jul 2010 19:27

AW: ComboBox Einträge editieren
 
Zitat:

Zitat von Chemiker (Beitrag 1034987)
Hallo DeddyH,

Zitat:

Zitat von DeddyH
Das wäre mir aber neu. Count gibt die Anzahl der Elemente zurück, d.h. ein Count > 0 heißt mindestens ein Element vorhanden.

Nochmal zur Klärung:

Count = 0 erster Eintrag
Count = 1 zweiter Eintrag

Wenn Count > 0 // sollte Count mindestens 1 sein um die Bedienung zu erfüllen, oder?

Bis bald Chemiker

Denke nochmal über den Unterschied zwischen Count und Index nach. Count ist die Anzahl der Elemente. Wenn es ein Element gibt, hat das meistens den Index 0.

fatalerror 12. Jul 2010 19:38

AW: ComboBox Einträge editieren
 
Zitat:

Zitat von Chemiker (Beitrag 1034987)
Hallo DeddyH,

Zitat:

Zitat von DeddyH
Das wäre mir aber neu. Count gibt die Anzahl der Elemente zurück, d.h. ein Count > 0 heißt mindestens ein Element vorhanden.

Nochmal zur Klärung:

Count = 0 erster Eintrag
Count = 1 zweiter Eintrag

Wenn Count > 0 // sollte Count mindestens 1 sein um die Bedienung zu erfüllen, oder?

Bis bald Chemiker

Ich hoffe du verstehst selbst, dass deine Aussage nicht korrekt sein kann. Count heisst "zähle" Wenn es keinen Eintrag in der Liste hat, dann ergibt count auch 0.

Zum besseren Verständnis:

Delphi-Quellcode:

//Kein Eintrag in der Liste
combobox1.Items.Clear;
showmessage(inttostr(combobox1.Items.Count));


//4 Einträge zur Liste hinzufügen
for i:= 0 to 3 do
  combobox1.items.add('test-'+inttostr(i));

showmessage(inttostr(combobox1.Items.Count));


Alle Zeitangaben in WEZ +1. Es ist jetzt 00:59 Uhr.
Seite 1 von 3  1 23      

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz