[D2010] Dateien in Zwischenablage kopieren (PDF)

[H3llsing]

Hallo DPler,

entschuldigt bitte wenn ich ein weiteres Thema zu den vielen anderen Clipboard-Themen erstelle, aber die anderen führen leider nicht zur Lösung.
Nun zu meinem Problem:
Ich möchte gerne Dateien in die Zwischenablage kopieren und woanders einfügen. Beim kopieren geht etwas schief :(

dazu verwende ich diesen Code:

Delphi-Quellcode:

//################################################
//   CopyFilesToClipboard
//################################################
procedure TfrmAnfrage.CopyFilesToClipboard(FileList: string);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end

ich habe

Delphi-Quellcode:

(PChar(DropFiles)

durch

Delphi-Quellcode:

(PAnsiChar(DropFiles)

bereits ersetzt da es sonst zu einem Fehler beim kopieren führt.

dann habe ich das Tool Clipboard-Explorer besorgt
und folgende abweichung beim kopieren im Explorer und beim kopieren per Programm festgestellt:

Explorer: HDROP: C:\Users\XXX\Documents\RAD Studio\Projekte\Hexacom\SalesBoard\bin\Anhang\10_P romotion2010_Q3.pdf
Programm: HDROP: C:\Users\XXX\Documents\RAD Studio\Projekte\He????.?.lesBoard\bin\Anhang\10_Pr omotion2010_Q3.pdf

desweiteren wird per programm nur der HDROP erstellt.
Beim Explorer kopieren der PDF: an die 11 Formate (DataObject,ShellIDListArray,dataobjectAtrribute.. .usw)

Ich wäre euch für jeden Tipp sehr Dankbar!

MFG
H3llsing

[H3llsing]

hat niemand ne idee woran es liegen könnte ?

[MarcoWarm]

Was genau ist

Delphi-Quellcode:

PDropFiles

?
Soll heißen ... auf welchen Typ ist das ein Pointer?

[H3llsing]

Da ich noch Delphi-Anfänger bin kann ich dir die frage nicht genau beantworten.

MSDN DROPFILES Structure ist zu entnehmen dass es ein Pointer aufs CF_HDROP Clipboard format ist. Dem die Daten in einer Liste von Filenamen vorliegt, die mit doppeltem #0 schließt.

;) ich hoffe ich lieg damit einiger maßen richtig :)

Die Funktion ist übrigens von den Schweizern Hier zu finden

[DeddyH]

Ich vermute ein Unicode-Problem. Wie sieht es so aus?

Delphi-Quellcode:

procedure TfrmAnfrage.CopyFilesToClipboard(FileList: AnsiString);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PAnsiChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end

[H3llsing]

wunderbar =D
DeddyH du bist mein Held :)

Bin nicht draufgekommen es bei dem Funktionsparameter selbst umzustellen.

außerdem musste noch folgende Zeile geändert werden

Delphi-Quellcode:

hGlobal := GlobalAlloc(GMEM_MOVEABLE+GMEM_DDESHARE,

in

Delphi-Quellcode:

hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT,

GesamtCode:

Delphi-Quellcode:

//################################################
//   CopyFilesToClipboard
//################################################
procedure TfrmAnfrage.CopyFilesToClipboard(FileList: Ansistring);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList) + 2;
  FileList := FileList + #0#0;
  hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT,
    SizeOf(TDropFiles) + iLen);
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  begin
    DropFiles := GlobalLock(hGlobal);
    DropFiles^.pFiles := SizeOf(TDropFiles);
    Move(FileList[1], (PAnsiChar(DropFiles) + SizeOf(TDropFiles))^, iLen);

    GlobalUnlock(hGlobal);
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  end;
end;

Vielen Dank an euch beide =)

[MarcoWarm]

*räusper*

Ein Unicode-Problem sollte man nicht damit lösen es zu ignorieren. Falls mal Unicodezeichen im Pfad vorkommen 'المسار_الأكاديمي.png' ... (oops hoffentlich hat google das richtig übersetzt) hilft dir diese routine nicht weiter. Also besser so:

Delphi-Quellcode:

procedure CopyFilesToClipboard(FileList: string);
var
  DropFiles: PDropFiles;
  hGlobal: THandle;
  iLen: Integer;
begin
  iLen := Length(FileList);
  hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT, SizeOf(TDropFiles) + ((iLen + 2) * SizeOf(Char)));
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.');
  try
    DropFiles := GlobalLock(hGlobal);
    if (DropFiles = nil) then raise Exception.Create('Could not access allocated memory.');
    try
      DropFiles^.pFiles := SizeOf(TDropFiles);
      DropFiles^.fWide := (SizeOf(Char) = SizeOf(WideChar));

      if FileList <> '' then
        Move(FileList[1], (PByte(DropFiles) + SizeOf(TDropFiles))^, iLen * SizeOf(Char));
    finally
      GlobalUnlock(hGlobal);
    end;
    Clipboard.SetAsHandle(CF_HDROP, hGlobal);
  except
    GlobalFree(hGlobal);
  end;
end;

Dann geht auch sowas:

Delphi-Quellcode:

procedure TForm2.Button1Click(Sender: TObject);
begin
  CopyFilesToClipboard('C:\Temp\المسار_الأكاديمي.png');
end;

viel Spaß

Marco

[himitsu]

Zitat:

Zitat von DeddyH (Beitrag 1038926)

Ich vermute ein Unicode-Problem.

Nee, hier würde mal das Unicodeproblem auftreten, wenn man den Code genauso in einem älteren Delphi ausführt.

Diese Strucktur muß als Unicode vorliegen. :stupid:

[MarcoWarm]

Zitat:

Zitat von himitsu (Beitrag 1038950)

Diese Strucktur muß als Unicode vorliegen. :stupid:

Die Struktur selbst ist in jeder Version gleich, da sie selbst keine Stringdaten enthält. Da gibt es keine Unicodeversion. Daher auch das boolsche Wide-Flag

[DeddyH]

Eine Frage noch: müsste das letzte except nicht eigentlich ein finally sein?

[MarcoWarm]

Zitat:

Zitat von DeddyH (Beitrag 1038955)

Eine Frage noch: müsste das letzte except nicht eigentlich ein finally sein?

Wir müssen die globale Resource nur im Fehlerfall freigeben. Ansonsten kümmert sich's Clipboard drum.

[DeddyH]

Ah, wieder was gelernt, thx.

[H3llsing]

nochmal vielen Dank @MarkoWarm =)

[GoTo0815]

Guten Tag,

ggf. habe ich ein riesiges Brett vor dem Kopf, aber ich versuche Dateien, deren Dateipfad und Dateinamen ich in einer StringListe gespeichert habe mittels CopyFilesToClipboard in die Zwischenablage kopieren, damit ich diese per Strg+V in beispielsweise Outlook einfügen kann.

Delphi-Quellcode:

procedure TForm1.BitBtn5Click(Sender: TObject);
var
  aList : TStringList;
  s, aListString : String;
begin
  try 
    aList := TStringList.Create;
    aList.Clear;

    // hier wird die Liste mit den Dateinamen erstellt, ich habe die Dateinamen und Pfade auch aus der 
    // Liste mal wieder ausgeben lassen, die sind in Ordnung, wobei die teilweise Leerzeichen enthalten.
    // Habe aber auch schon versucht die einzelnen Dateinamen inkl. Pfad in Anführungszeichen zu betten.
    // Alles irgendwie ohne Erfolg.
    // Muss eigentlich bei dem letzten Dateinamen dann das #0 weggelassen werden, da ja in der 
    // CopyFilesToClipboard dann #0#0 ergänzt wird?

    aListString := '';
    for i := 0 to aList.Count -1 do
    begin
      s:= aList[i];
      aListString:= aListString + s + #0;
    end;
    CopyFilesToClipboard(aListString);

  finally
    FreeAndNil(aList);
  end;
end;

[GoTo0815]

... kaum habe ich mir und Euch diese Frage gestellt:

Muss eigentlich bei dem letzten Dateinamen dann das #0 weggelassen werden, da ja in der CopyFilesToClipboard dann #0#0 ergänzt wird?

Jetzt habe ich das mal geändert und nun funktioniert es natürlich :-)

Delphi-Quellcode:

//...

    for i := 0 to aList.Count -1 do
    begin
      s:= aList[i];
      if i < aList.Count -1 then aListString:= aListString + s + #0
      else aListString:= aListString + s;
    end;

//...

[mkinzler]

Delphi-Quellcode:

  aList.Delimiter := #0;
  aListString:= aList.DelimitedText;

[GoTo0815]

Delphi-Quellcode:

  aList.Delimiter := #0;
  aListString:= aList.DelimitedText;

... das hatte ich zwischendurch auch einmal so versucht und leider funktionierte das nicht.
Ich bekomme dann beim Einfügen eine Fehlermeldung, dass ein Dateiname/Dateipfad nicht stimmt.

Sehr merkwürdig! :pale:

[himitsu]

#0 = Ende es TStringList Textes?

Ich könnte fast wetten, daß bei Delemiter=#0 alle String gequotet werden,
aber du hast dir natürlich im Debugger angesehn, was als aListString raus kommt, bzw. was an CopyFilesToClipboard übergeben wird. :stupid:

[GoTo0815]

... ja Du hast recht! Im Debugger habe ich nicht geschaut.
Ich hatte mir versucht den String anderweitig anzuschauen (in einem Memo ausgegeben), was durch das #0 natürlich nicht wirklich schlau ist.

Doppelte Anführungszeichen werden scheinbar hinzugefügt bei Strings mit Leerzeichen:

Delphi-Quellcode:

aList.Delimiter:=#0;
aListString := aList.DelimitedText;

Ergebnis: 'C:\Folder\Dateiname1.pdf'#0'C:\Folder\Dateiname2. pdf'#0'"C:\Folder\Datei name3.pdf"'


und bei folgendem Code nicht:

Delphi-Quellcode:

for i := 0 to aList.Count -1 do
begin
  s:= aList[i];
  if i < aList.Count -1 then aListString:= aListString + s + #0
  else aListString:= aListString + s;
end;

'C:\Folder\Dateiname1.pdf'#0'C:\Folder\Dateiname2. pdf'#0'C:\Folder\Datei name3.pdf'

[himitsu]

Delphi-Quellcode:

if i < aList.Count -1 then

kann bestimmt weg.

Diese Listen sind ja so definiert
#0 = nächster Listeneintrag
#0#0 = Ende der Liste (wobei #0#0 eigentlich für einen Leerstring steht)

Und da das Ende als #0#0 deklariert it, wird alles danach ignoriert. Es ist also egal, ob am Ende #0#0 oder #0#0#0 steht.

[GoTo0815]

... so hatte ich das auch gedacht. Während ich dann gestern 16:47 den ersten Post hier schrieb, hatte ich das auch noch nicht in meinem Code. Stellte mir selbst und der Community hier dann aber die Frage:

Delphi-Quellcode:

// Muss eigentlich bei dem letzten Dateinamen dann das #0 weggelassen werden, da ja in der
// CopyFilesToClipboard dann #0#0 ergänzt wird?

Daraufhin habe ich das "if i < aList.Count -1 then" erst eingefügt und seither läuft es.

Ggf. wird bei einem #0#0#0 ein leerer Listeneintrag interpretiert #0{leerer Eintrag}#0#0 und das führt zu einem Fehler beim Einfügen denn eine Datei mit dem Pfad und namen = {leerer Eintrag} kann es ja nicht geben.

Wie auch immer, jetzt läuft es einwandfrei.

Mir hätte das mit dem DelimitedText auch besser gefallen.

[himitsu]

Ich weiß jetzt nicht, ob StringReplace/ReplaceStr mit einem #0 als Ersatzstring klar kommt (vermutlich ja).

Delphi-Quellcode:

aListString := ReplaceStr(aList.Text, sLineBreak, #0);

// oder
aList.LineBreak := #1;
aListString := ReplaceStr(aList.Text, #1, #0);