Dynamisch erzeugte Komponente soll sich selbst löschen...

[arc]

Ich habe leider noch ein kleines Problem, ich erzeuge mir ein dynamisch Panel und darin einen Button.
Das Panel stellt ein "Fenster" dar und soll durch den Button "geschlossen" werden.

Dazu habe ich in den onClick EventHandler entsprechend den Code geschrieben der beide Komponenten Free'd. Nach vielen Versuchen in denen es nicht funktioniert hat, ist mir nun wahrscheinlich der Grund eingefallen. Eine Komponente kann sich nicht selbst durch eine eigene Methode löschen, richtig?

Nun bräuchte ich einen geschickten Weg, wie ich eine Komponente die ich erzeugt habe durch sich selbst löschen kann. Eine Idee kam mir, daß ich eine Art globalen Timer und eine Queue anlege. In dieser wird dann einfach der Befehl zum Löschen der entsprechenden Komponenten abgelegt und der Timer im onClick Ereignis aktiviert. Dieser wartet seine Zeit, löscht die Komponente und deaktiviert sich wieder.

Aber das ist irgendwie nicht schön und über 3 Ecken, bevor ich das implementiere wollte ich mich nach weiteren Vorschlägen umhören...

So sieht das ganze übrigens aus:

Anhang 32631

Durch das x wird eine "Zeile" komplett gelöscht.

Danke schonmal!

[edit=Matze]Bild angehängt. MfG Matze[/edit]

[himitsu]

Wie hast du denn das Panel und die enthaltenen Komponenten erstellt?

Wenn du bei den untergeordneten Komponenten das Panel als Owner (der Parameter im Create) angibst, dann gibt das Panel bei seiner Freigabe auch die untergeordneten Komponente frei.

Owner = ist für die Freigabe zuständig
Parent = ist für die Anzeige zuständig.

Also wenn der Owner richtig gesetzt ist, dann reicht es, wenn du das Panel freigibst.

PS: Wenn das jetzt schon der Fall ist und du z.B. versuchst den (nicht mehr vorhandenen Button) nach dem Panel zu löschen, dann ist der da ja schon lange weg und es knallt natürlich.

[stahli]

Wie sieht denn Dein Code aus und was passiert?
Button.Owner.Free sollte (mit den aktuellen Komponenten) eigentlich funktionieren.

Wir hatten das Thema kürzlich hier.

[Peter1999]

Ja, du hast Recht, eine Komponente kann sich nicht selbst löschen.
Einen Timer zu missbrauchen, halte ich aber für ziemlichen Pfusch ;) .
Eine ebenfalls unschöne aber bessere Lösung sieht folgendes vor:
Jedes Panel bekommt eine ID, z.B in dessen Tag.
Beim Klick auf den Button (auf dem Panel) bekommt ein beliebiges anderes Control (z.B. deine Combobox, nicht auf dem Panel!) den Focus zugewiesen und übernimmt in seinem Tag den Tag des Panels.
In der Methode OnGetFocus des anderen Controls löschst du dann (wenn eigener Tag > 0) das Panel und alles was dazu gehört und setzt den Tag wieder auf -1 .
Somit wird das Panel nicht von sich selbst freigegeben und es läuft nirgends ein unnützer Timer.

Achtung, falls du wirklich noch mit D7 arbeitest, da hat scheinbar der Speichermanager ein Problem.
Jedenfalls habe ich FastMM mit einbinden müssen. Ab D2006 ist das ja standard.

Beispiel findest du im Anhang.

Viele Grüße,
Peter

[Bummi]

Das Problem eine Komponente im OnClick zu vernichten habe ich auch lange über eine Liste und Timer gelöst, da es zwar manchmal funktioniert, aber üblicherweise zu Zugriffsverletzungen führt da das Verlassen der Prozedur OnClick nach dem Vernichten nicht mehr definiert ist.
Ich habe inzwischen eine zuverlässige Methode gefunden die in Deinem Beispiel wie folgt aussähe:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

const
  KillMessage = WM_USER + 200;

type
  TPanel=Class(ExtCtrls.TPanel)
    procedure Kill(var Msg: TMessage); message KillMessage;
  End;

  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
 PostMessage(TButton(sender).Parent.Handle,KillMessage,0,0) ;
end;

{ TPanel }
procedure TPanel.Kill(var Msg: TMessage);
begin
  Free;
end;
end.

[arc]

Vielen Dank für die Hinweise, ich werde gleich schauen was funktioniert und gebe anschließend Rückmeldung.

FastMM nutze ich seit gestern, da ich zuerst einen Fehler in Richtung Pointer im Verdacht hatte (daher auch mein Thread mit FreeAndNil). Ich habe auch gleich zwei Fälle entdeckt, wo ein inherited im Destructor gefehlt hat und Speicher nicht freigegeben wurde. Ein sehr mächtiges und nützliches Tool. :thumb:

[arc]

Ich habe mich letztendlich für die Timerversion entschieden, die ja nichts anderes ist als die Sache mit den Messages, nur auf vertrautem Terrain.
Letztenendes sieht es so aus:

Delphi-Quellcode:

type TModifyModule = class(TSplitModule)
                       DeleteTimer:TTimer;

                       constructor Create; override;
                       procedure eventHandlerParameterFormControlsDelete(Sender:TObject); virtual;
                       procedure eventHandlerParameterFormControlsDeleteWrapper(Sender:TObject); virtual; 
                       destructor Destroy; override;
                     end;

constructor TModifyModule.Create;
begin
  inherited Create;
  DeleteTimer:=TTimer.Create(nil);
  DeleteTimer.Enabled:=false;
  DeleteTimer.Interval:=10;
end;

procedure TModifyModule.eventHandlerParameterFormControlsDelete(Sender:TObject);
begin
  // code zum Löschen
  DeleteTimer.Enabled:=false;
end;

procedure TModifyModule.eventHandlerParameterFormControlsDeleteWrapper(Sender:TObject);
begin
  DeleteTimer.OnTimer:=eventHandlerParameterFormControlsDelete;
  DeleteTimer.Enabled:=true;
end;

destructor TModifyModule.Destroy;
begin
  FreeAndNil(DeleteTimer);
  inherited Destroy;
end;

Funktioniert bisher wunderbar...

[Bummi]

Zitat:

Ich habe mich letztendlich für die Timerversion entschieden, die ja nichts anderes ist als die Sache mit den Messages, nur auf vertrautem Terrain.

Ich sehe zwar die Verwandschaft nicht und finde die Messagemethode deutlich überlegen, aber wie gesagt, ich habe es früher ebenfalls umgesetzt wie Du jetzt.

MfG
Bummi

[arc]

Ich meine die Verwandschaft folgendermaßen, es geht am Ende ja lediglich darum, die Methode indirekt aufzurufen. Bei der Message lege ich eine Message in die Queue, die dann entsprechend abgearbeitet wird bzw die Methode aufruft. Beim Timer ist der Timer die Queue und ruft anschließend die Methode auf.

[shmia]

Ich habe zu selbstzerstörerischen Controls vor langer Zeit etwas in der Code-Library geschrieben. klick

Im Gegensatz zur Lösung von Bummi schicke ich die Message an das Formular und nicht an das Control das Sterben soll.
Ich finde das besser, weil so das Control "von Aussen" gemeuchelt wird und man ausserdem den Trick mit

Delphi-Quellcode:

TPanel=Class(ExtCtrls.TPanel)

nicht braucht.

Aus heutiger Sicht würde ich nur noch das Killen etwas vereinfachen:

Delphi-Quellcode:

// Hilfsprocedure für einfacheres Morden von Controls
procedure TForm1.KillObjectByMessage(c:TObject);
begin
  PostMessage(Self.Handle, WM_KILL_CONTROL, 0, Integer(c));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  // Sender.Free; // würde meistens eine Exception auslösen
  KillObjectByMessage(Sender);
end;