Aus einem String eine Klasse erzeugen

[moelski]

Moin !

Ich teste gerade wieder ein bisschen mit RTTI und bin gerade zu der Frage gekommen ob man aus einem String eine Klasse erstellen kann.

Bsp:

Delphi-Quellcode:

type
  TUserTest = class(TUser)
  private
    Test : Boolean;
  public

  end;

Das sei mal unsere Klasse.

Delphi-Quellcode:

var user : TUser
begin 
  user := ??? 'TUserTest' ???.Create

Geht das schon mit reinen Delphi Bordmitteln oder geht das nur mit RTTI?
Hat da ggf. jemand ein Beispiel zu?

[Bummi]

http://delphi.about.com/library/weekly/aa080905a.htm

[moelski]

Moin !

Das habe ich auch gefunden. Dort muss man aber die Klassen extra mittels RegisterClass(Txxxxx) registrieren.

Geht das ggf. auch ohne?

Man kann sich mit den RTTI Möglichkeiten von D2010 die Klassen auflisten lassen:

Delphi-Quellcode:

var
  aClass  : TClass;
  context : TRttiContext;
  types   : TArray<TRttiType>;
  aType   : TRttiType;
begin
  context := TRttiContext.Create;
  types := context.GetTypes;
  for aType in types do begin
    if aType.TypeKind = tkClass then begin
      aClass := aType.AsInstance.MetaclassType;
      Memo.Lines.Add(aClass.ClassName);
    end;
  end;

Evtl. kann man dann damit auch direkt eine Klasseninstanz erzeugen ?

[himitsu]

Du müßtest erstmal schauen ob/wie man mit der neuen RTTI "alle" Klassen auflistet, bzw. dort nach der Gewünschten sucht.

Wenn du dann Etwas ala TClass rausbekommst, dann könntest du darüber .Create aufrufen.



Problem: Damit das richtige .Create aufgerufen wird, muß dieses als virtual deklariert sein, welches bei TObject (TClass = class of TObject) nicht der Fall ist.

Delphi-Quellcode:

var C: TClass;
X := C.Create;

Hier würde immer nur TObject.Create aufgerufen, egal ob zur (in C gespeicherten) Klasse ein anderes .Create deklariert wurde.

Bei TComponent wäre dieses der Fall und wenn man seinen TComponent-Nachfolger registriert hat, dann geht es auch ohne RTTI (die VCL nutzt dieses ja ausgiebig, um die DFMs zu laden)

OK, man könnte nun schauen, ob die RTTI hier auch noch eine Adresse für das richtige .Create liefert und Dieses direkt aufrufen.

[moelski]

Moin !

Also ich habe es jetzt mal so probiert und das funktioniert ...

StrClass : TObject;

Delphi-Quellcode:

var
  aClass  : TClass;
  context : TRttiContext;
  types   : TArray<TRttiType>;
  aType   : TRttiType;
begin
  context := TRttiContext.Create;
  types := context.GetTypes;
  for aType in types do begin
    if aType.TypeKind = tkClass then begin
      aClass := aType.AsInstance.MetaclassType;
      if aClass.ClassName = 'TUserTest' then begin
        StrClass := aClass.NewInstance;
        TUserTest(StrClass).User := 'Test'; // Testzuweisung
      end;
    end;
  end;

Das geht durch alle Klassen und wenn 'TUserTest' vorhanden ist, dann habe ich danach in StrClass eine Instanz.

Sollte es so einfach gehen? :gruebel:

[Bummi]

sieht so aus ...das funktioniert ebenfalls

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
var
  aClass : TClass;
  context : TRttiContext;
  types : TArray<TRttiType>;
  aType : TRttiType;
  StrClass:TForm;
begin
  context := TRttiContext.Create;
  types := context.GetTypes;
  for aType in types do begin
    if aType.TypeKind = tkClass then begin
      aClass := aType.AsInstance.MetaclassType;
      if aClass.ClassName = 'TForm2' then begin
        StrClass :=  TFormClass(aClass).Create(self);
        Tform(StrClass).Show;
      end;
    end;
  end;
end;

[moelski]

Moin !

aber himitsu hat Recht mit dem Create.

Meine urKlasse hat einen eigenen konstruktor:

Delphi-Quellcode:

constructor Create(name : string);

Der wird nicht genutzt bei NewInstance.

[moelski]

Hiermit würde es ja gehen:

Delphi-Quellcode:

 aType.GetMethod('Create').Invoke(aClass, ['']).AsObject as TUserTest

Aber da muss ich ja die Klasse dennoch als Cast mit angeben. :?

[Bummi]

vielleicht gibt es doch Fälle bei denen man es einsetzen möchte.

Für Controls funktioniert es wie gewünscht, für eigene Klassen könnte man gegf. Statt TClass syn. TObject beiliegnde TBaseObject verwenden.

nur als Vorschlag.. btw. wenn die Klassen im Code nur deklariert sind und nirgends verwendet werden, läuft das ganze nicht da der Linker den Code wegoptimiert.

Delphi-Quellcode:

unit EXCreateByClassName;
// 20101125 Thomas Wassermann
interface
uses RTTI,TypInfo,Controls,Classes;


type
  TBaseObject=Class
     Constructor Create(a:TValue);virtual;
  End;
TBaseObjectClass= Class of TBaseObject;

Function CreateClassByClassName(const s:String;a:Tvalue):TObject;
Function CreateControlClassByClassName(const s:String;Owner:TComponent):TControl;
implementation

Function CreateClassByClassName(const s:String;a:Tvalue):TObject;
var
  aClass : TClass;
  context : TRttiContext;
  types : TArray<TRttiType>;
  aType : TRttiType;
begin
  Result := nil;
  context := TRttiContext.Create;
  types := context.GetTypes;
  for aType in types do
  begin
    if aType.TypeKind = tkClass then
    begin
      aClass := aType.AsInstance.MetaclassType;
      if aClass.ClassName = s then
        begin
        Result :=  TBaseObjectClass(aClass).Create(a);
        end;
    end;
  end;
end;

Function CreateControlClassByClassName(const s:String;Owner:TComponent):TControl;
var
  aClass : TClass;
  context : TRttiContext;
  types : TArray<TRttiType>;
  aType : TRttiType;
  StrClass:TControl;
begin
  Result := nil;
  context := TRttiContext.Create;
  types := context.GetTypes;
  for aType in types do begin
    if aType.TypeKind = tkClass then begin
      aClass := aType.AsInstance.MetaclassType;
      if aClass.ClassName = s then begin
        Result :=  TControlClass(aClass).Create(Owner);
      end;
    end;
  end;
end;


{ TBaseObject }

constructor TBaseObject.Create(a: TValue);
begin
  inherited Create;
end;

end.

[himitsu]

Zitat:

Zitat von moelski (Beitrag 1063944)

Der wird nicht genutzt bei NewInstance.

Bei NewInstanze wird überhaupt kein Constructor aufgerufen.


PS: NewInstanze ruft man überhaupt nicht auf, wenn man eine Klasse instantiieren will.
NewInstanze reserviert nur den Speicher für die Klasse selber und richtet den eigenen Klassentypen ein und läd die Interface- und VirtualMethodes-Tabelle.

Aber wenn in irgendwelchen Kontruktoren z.B. wichtige Dinge initialisiert werden (z.B. Unterobjekte erstellen und andere Dinge laden), dann fehlt dieses natürlich.
(das wäre wie, wenn man statt Free/Destroy einfach nur FreeInstanze oder FreeMem aufruft)