Windows message queue - Limit erreicht?

[moelski]

Moin !

Wir haben einen USB Logger den wir auslesen. Dieser Logger sendet nach einem Kommando einen Block an Daten (~40.000 Telegramme á 57 Byte).
Also komponente verwenden wir NrComm (HID) - aber das spielt hier eh keine wichtige Rolle.

Die Daten werdenfolgendermassen empfangen:

Delphi-Quellcode:

procedure TForm1.HidAfterReceive(Com: TObject; Buffer: Pointer;
  Received: Cardinal);
var ByteData : AnsiString;
    i        : integer;
    _msg     : PHIDFeedback;
begin
  Inc(HidCount);

  for i := 0 to Received - 1
    do ByteData := ByteData + PAnsiChar(Buffer)[i];

  New(_msg);
  _msg.Data     := ByteData;
  _msg.HidCount := HidCount;
  PostMessage(self.Handle, WM_MY_HID_DATA, 0, Integer(_msg));    // Daten übergeben
end;

Und so ausgewertet:

Delphi-Quellcode:

procedure TForm1.DecodeHID(var Msg: TMessage);
var _msg                    : PHIDFeedback;
begin
  _msg := nil;
  try
    _msg := PHIDFeedback(Msg.LParam);

    // hier passiert noch mehr ...

    memo1.Lines.Add('[' + IntToStr(_Msg.HidCount) + '] ' + string(_msg.Hex));
  finally
    Dispose(_msg);               // Pointer löschen
  end;
end;

Wir nutzen also Windows Messages um die Daten aus dem Empfangsthread in den Mainthread zur Auswertung zu bekommen.

Diese Technik hat bis dato immer super funktioniert. Aber nun ergeben sich mit einem neuen Logger Probleme.
Wenn die Zahl der Telegramme zu gross wird (so ab > 30.000) dann gehen teilweise Telegramme verloren.

Gibt es bei den windows Messages irgendwelche Grenzen die man nicht überschreiten darf? Hat die queue nur eine bestimmte maximale Länge?

[jfheins]

Ich zitiere mal aus dem MSDN:

Zitat:

There is a limit of 10,000 posted messages per message queue. This limit should be sufficiently large. If your application exceeds the limit, it should be redesigned to avoid consuming so many system resources. To adjust this limit, modify the following registry key.

HKEY_LOCAL_MACHINE
SOFTWARE
Microsoft
Windows NT
CurrentVersion
Windows
USERPostMessageLimit

The minimum acceptable value is 4000.

http://msdn.microsoft.com/en-us/libr...(v=vs.85).aspx

Frage erledigt?

[moelski]

Ja Frage erledigt ... :cry:

[himitsu]

Ein Blick in PostMessage sagt alles:

Zitat:

There is a limit of 10,000 posted messages per message queue. This limit should be sufficiently large. If your application exceeds the limit, it should be redesigned to avoid consuming so many system resources. To adjust this limit, modify the following registry key.

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Windows\USERPostMessageLimit

Aber eh ich an windowsglobalen Einstellungen rumspiele, würde ich eher das Programmkonzept überdenken.

[edit]
da hat wer schneller geantwortet, als meine Leitung senden wollte :cry:


[add]
zu der For-Schleife sag ich mal Aua :shock:

Delphi-Quellcode:

procedure TForm1.HidAfterReceive(Com: TObject; Buffer: Pointer;
  Received: Cardinal);
var ByteData : AnsiString;
    i        : integer;
    _msg     : PHIDFeedback;
begin
  Inc(HidCount);
  New(_msg);
  SetLength(_msg.Data, Received);
  MoveMemory(@msg.Data[0], Buffer, Received);
  _msg.HidCount := HidCount;
  PostMessage(self.Handle, WM_MY_HID_DATA, 0, Integer(_msg));
end;

PS: Wenn du/ihr noch etwas Zeit habt:
http://www.delphipraxis.net/156006-n...omponente.html

[moelski]

Moin !

Zitat:

zu der For-Schleife sag ich mal Aua

Is ja gut ...
Aber das ist im Moment das kleinste Problem.

Hast du nicht einen Tip wie ich die Daten vom Empfangsthread Resourcen schonender zum Mainthread bekomme ?

[Luckie]

Der Speicher von _msg wird nicht wieder freigegeben.

Delphi-Quellcode:

 New(_msg);
  _msg.Data := ByteData;
  _msg.HidCount := HidCount;
  PostMessage(self.Handle, WM_MY_HID_DATA, 0, Integer(_msg)); // Daten übergeben

[moelski]

Moin !

Zitat:

Der Speicher von _msg wird nicht wieder freigegeben.

Sollte doch in DecodeHID mittels Dispose(_msg) erfolgen ?

[Luckie]

Lokale Variablen verlieren ihre Gültigkeit beim Verlassen der Routine. _msg aus HidAfterReceive ist in Decode-Dingsbums unbekannt. Zu mal du in Decode-Dingsbums _msg auch deklariert hast. Das sind zwei unterschiedliche Variablen, auch wenn sie gleich heißen.

[himitsu]

Du könntest ja auf eine andere/größere Queue/Liste ausweichen?

Delphi-Quellcode:

uses SyncObjs, Generics.Collections;

var
  QueueCS: TCriticalSection;
  Queue: TQueue<THIDFeedback>;


var
  Temp: THIDFeedback;
begin
  // hid-thread
  SetLength(Temp.Data, Received);
  MoveMemory(@Temp.Data[0], Buffer, Received);
  Temp.HidCount := HidCount;
  QueueCS.Enter;
  try
    Queue.Enqueue(Temp);
  finally
    QueueCS.Leave;
  end;


  // mainthread
  QueueCS.Enter;
  try
    Found := Queue.Count > 0;
    if Found then Temp := Queue.Dequeue;
  finally
    QueueCS.Leave;
  end;
  if Found then
  begin
    // temp auswerten
  end;

Statt Record, CS und gen. Queue könnte man auch TThreadList mit Objekten nutzen.

[Basilikum]

Zitat:

Zitat von Luckie (Beitrag 1067198)

Lokale Variablen verlieren ihre Gültigkeit beim Verlassen der Routine. _msg aus HidAfterReceive ist in Decode-Dingsbums unbekannt. Zu mal du in Decode-Dingsbums _msg auch deklariert hast. Das sind zwei unterschiedliche Variablen, auch wenn sie gleich heißen.

Oberflächlich betrachtet ist diese Aussage natürlich korrekt - aber wenn man es genauer anschauen würde, würde man erkennen, dass zwischen den beiden Funktionen die erwähnte Windows-Message-Queue steckt, welche den Pointer auf den vermeindlich nicht freigegebenen Speicher an die Funktion überliefert, welche den Speicher dann korrekt freigibt - das Speicher-Handling ist korrekt...