Registry bei Windows 7 32bit mit Delphi 2009 auslesen

[Alex.P]

Hallo,

ich bin von Win XP auf Win 7 32bit umgezogen.
Unter XP konnte ich die vorhandenen COM Ports mit folgenden Code aus der Registry lesen:

Code:

reg := TRegistry.Create;

  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    reg.OpenKey('hardware\devicemap\serialcomm', False);

    reg.GetValueNames(TempResult);
    for i := 0 to TempResult.Count - 1 do
        Result.Add(reg.Readstring(TempResult.strings[i]));
    reg.CloseKey
  finally
    reg.Free;
    TempResult.Free;
  end;

Unter Windows 7 liefert die Funktion GetValueNames eine leere Liste zurück.
Der Pfad und der Inhalt des Registry Schlüssels ist zu XP gleich geblieben.

[Luckie]

Ins blaue geraten: Unter XP hast du als Administrator gearbeitet unter Windows 7 bist du das nicht mehr. TRegistry.Create(...) öffnet den Schlüssel aber lesend und schreibend. Das schlägt unter Windows 7 fehl, weil du im Hive HKLM keine Schreibrechte hast. Eine entsprechende Fehlerbehandlung hätte wahrscheinlich den Fehler "Zugriff verweigert" zurückgegeben. Was dir auch gleich den Hinweis gegeben hätte, warum es nicht funktioniert.

[Andreas L.]

Dem Konstrukor von TRegistry kann man den Parameter KEY_READ übergeben, damit das Objekt im Nur-Lesen-Modus erzeugt wird. Außerdem hat OpenKey einen Rückgabewert den man auswerten sollte.

[Luckie]

Delphi-Quellcode:

procedure foo;
var
  reg: TRegistry;
begin
  reg := TRegistry.Create;
  try
    reg.RootKey := HKEY_LOCAL_MACHINE;
    if reg.OpenKey('hardware\devicemap\serialcomm', False)then
    begin
      // ...;
      // ...;
      reg.CloseKey
    end
    else
      RaiseLastOSError;
  finally
    reg.Free;
  end;
end;

procedure TForm1.btn1Click(Sender: TObject);
begin
   try
     foo;
   except
     on e: Exception do
       ShowMessage(e.Message);
   end;
end;

[SirThornberry]

Wäre es hier nicht sicherer die dafür vorgesehene Api-funktion zu verwenden?

[Luckie]

Zitat:

Zitat von SirThornberry (Beitrag 1124523)

Wäre es hier nicht sicherer die dafür vorgesehene Api-funktion zu verwenden?

Wenn es die gibt sicher. Welche wäre denn das?

[DeddyH]

So geht es bei mir unter Vista 32 (kein Admin-Account):

Delphi-Quellcode:

procedure ListComPorts(ResultList: TStrings);
var
  reg: TRegistry;
  i: integer;
  TempResult: TStringlist;
begin
  TempResult := TStringlist.Create;
  try
    reg := TRegistry.Create(KEY_READ);
    try
      reg.RootKey := HKEY_LOCAL_MACHINE;
      if reg.OpenKey('hardware\devicemap\serialcomm', False) then
        begin
          reg.GetValueNames(TempResult);
          for i := 0 to TempResult.Count - 1 do
            ResultList.Add(reg.Readstring(TempResult.strings[i]));
          reg.CloseKey;
        end;
    finally
      reg.Free;
    end;
  finally
    TempResult.Free;
  end;
end;

[edit] BTW: Interessanter Artikel dazu: http://www.codeproject.com/KB/system...enum_fifo.aspx, aber ganz ohne die Registry kommt man wohl auch dort nicht aus, sofern meine bescheidenen C++-Kenntnisse ausreichen. [/edit]

[hathor]

Verständnisfrage:

Wozu reg.CloseKey; wenn reg.OpenKey nicht funktioniert ?

[DeddyH]

Wen meinst Du?

[hathor]

Alle...:-D

Wenn reg.CloseKey; nach einem missglückten reg.OpenKey aufgerufen wird - was passiert dann?
Nichts???

[DeddyH]

Ein Blick in die Hilfe bringt Erstaunliches zu Tage:

Zitat:

Ein Aufruf von CloseKey hat keinen Effekt, wenn aktuell kein Schlüssel geöffnet ist.

Abgesehen davon rufen Luckie und ich nur dann CloseKey auf, wenn OpenKey auch erfolgreich war ;)

[himitsu]

Wer will, kann auch noch TRegisty.OpenKeyReadOnly verwenden.

[Alex.P]

Hallo,

danke für die zahlreichen Antworten. Ich werde das gleich mal ausprobieren.
Version 1.0 ist leider schon rum ums Eck. Bin jetzt bei 5.0

[Alex.P]

Create mit KEY_READ ausführen, dann klapps auch wieder mit Windows 7

Code:

TRegistry.Create(KEY_READ);

[DeddyH]

Siehe #3 und #7.

[DP-Maintenance]

Dieses Thema wurde am "25. Sep 2011, 20:22 Uhr" von "MrSpock" aus dem Forum "Betriebssysteme" in das Forum "Win32/Win64 API (native code)" verschoben.