Wlan Informationen erhalten

[schlagzu]

Hallo,

ich versuche seit mehreren Tagen einfach ein Paar Informationen zum Thema Wlan auszulesen.
Was ich bräuchte wäre (in absteigender Wichtigkeit):

-Signalstärke (wenn möglich in %, falls nicht nötig in dBm)
-SSID
-Verschlüsselung (Ja/Nein und welche)
-Name der Wlankarte
-Übertagungsrate (in Mbs oder a,b,g,n)

Was ich schon probiert habe:
-Wlan-Api (Wlan-Manager) aus dem Forum hier.(Probleme mit Unicode)
-WMI (MSNdis_80211_ReceivedSignalStrength) aber bei mir kommt immer 2972

Also gibt es noch eine andere / leichtere Möglichkeit an die Informationen zu kommen.
Für die Sidebar-Gadgets gibt es eine so tolle Sammlung an Systeminformationen (Bsp Wlan: http://msdn.microsoft.com/en-us/library/windows/desktop/ff486271%28v=VS.85%29.aspx)

Ich hoffe ihr könnt mir helfen.

MfG schlagzu

[p80286]

wenn Du im wlanmanager Char durch Ansichar ersetzt, sollte es eigentlich funktionieren.
(Und wenn Du uns sagst mit welcher Delphi-Version Du arbeitest, ists für uns auch ein wenig einfacher)

Gruß
K-H

[schlagzu]

schlagzu
Online

Registriert seit: 11. Okt 2010
36 Beiträge

>>>>>>Delphi XE Starter<<<<<<

[schlagzu]

Problem beim WLAN-Manager, er zeigt mir 2mal das gleiche Netzwerk mit unterschiedlichen Signalstärken an.
Und ich glaub, wenn ich das richtig verstanden habe, dann greift der nur auf lokal gespeicherte Profile zurück oder?

MfG schlagzu

[Bummi]

unter diesem Link gibt es was:

http://stackoverflow.com/questions/1...ith-delphi-how

mal kurz für Unicode verbogen, läuft es bei mir so:

Delphi-Quellcode:

program WLAN;


{$APPTYPE CONSOLE}

uses
  Windows,
  SysUtils,
  nduWlanAPI ,
  nduWlanTypes ;

function DOT11_AUTH_ALGORITHM_To_String( Dummy :Tndu_DOT11_AUTH_ALGORITHM):ANSIString;
begin
    Result:='';
    case Dummy of
        DOT11_AUTH_ALGO_80211_OPEN          : Result:= '80211_OPEN';
        DOT11_AUTH_ALGO_80211_SHARED_KEY    : Result:= '80211_SHARED_KEY';
        DOT11_AUTH_ALGO_WPA                 : Result:= 'WPA';
        DOT11_AUTH_ALGO_WPA_PSK             : Result:= 'WPA_PSK';
        DOT11_AUTH_ALGO_WPA_NONE            : Result:= 'WPA_NONE';
        DOT11_AUTH_ALGO_RSNA                : Result:= 'RSNA';
        DOT11_AUTH_ALGO_RSNA_PSK            : Result:= 'RSNA_PSK';
        DOT11_AUTH_ALGO_IHV_START           : Result:= 'IHV_START';
        DOT11_AUTH_ALGO_IHV_END             : Result:= 'IHV_END';
    end;
End;

function DOT11_CIPHER_ALGORITHM_To_String( Dummy :Tndu_DOT11_CIPHER_ALGORITHM):AnsiString;
Begin
    Result:='';
    case Dummy of
    DOT11_CIPHER_ALGO_NONE      : Result:= 'NONE';
    DOT11_CIPHER_ALGO_WEP40     : Result:= 'WEP40';
    DOT11_CIPHER_ALGO_TKIP      : Result:= 'TKIP';
    DOT11_CIPHER_ALGO_CCMP      : Result:= 'CCMP';
    DOT11_CIPHER_ALGO_WEP104    : Result:= 'WEP104';
    DOT11_CIPHER_ALGO_WPA_USE_GROUP : Result:= 'WPA_USE_GROUP OR RSN_USE_GROUP';
    //DOT11_CIPHER_ALGO_RSN_USE_GROUP : Result:= 'RSN_USE_GROUP';
    DOT11_CIPHER_ALGO_WEP           : Result:= 'WEP';
    DOT11_CIPHER_ALGO_IHV_START     : Result:= 'IHV_START';
    DOT11_CIPHER_ALGO_IHV_END       : Result:= 'IHV_END';
    end;
End;

procedure Scan();
const
WLAN_AVAILABLE_NETWORK_INCLUDE_ALL_ADHOC_PROFILES =$00000001;
var
  hClient              : THandle;
  dwVersion            : DWORD;
  ResultInt            : DWORD;
  pInterface           : Pndu_WLAN_INTERFACE_INFO_LIST;
  i                    : Integer;
  j                    : Integer;
  pAvailableNetworkList: Pndu_WLAN_AVAILABLE_NETWORK_LIST;
  pInterfaceGuid       : PGUID;
  SDummy               : Ansistring;
begin
  ResultInt:=WlanOpenHandle(1, nil, @dwVersion, @hClient);
  if  ResultInt<> ERROR_SUCCESS then
  begin
     WriteLn('Error Open CLient'+IntToStr(ResultInt));
     Exit;
  end;

  ResultInt:=WlanEnumInterfaces(hClient, nil, @pInterface);
  if  ResultInt<> ERROR_SUCCESS then
  begin
     WriteLn('Error Enum Interfaces '+IntToStr(ResultInt));
     exit;
  end;

  for i := 0 to pInterface^.dwNumberOfItems - 1 do
  begin
   Writeln('Interface       ' + pInterface^.InterfaceInfo[i].strInterfaceDescription);
   WriteLn('GUID            ' + GUIDToString(pInterface^.InterfaceInfo[i].InterfaceGuid));
   Writeln('');
   pInterfaceGuid:= @pInterface^.InterfaceInfo[pInterface^.dwIndex].InterfaceGuid;

      ResultInt:=WlanGetAvailableNetworkList(hClient,pInterfaceGuid,WLAN_AVAILABLE_NETWORK_INCLUDE_ALL_ADHOC_PROFILES,nil,pAvailableNetworkList);
      if  ResultInt<> ERROR_SUCCESS then
      begin
         WriteLn('Error WlanGetAvailableNetworkList '+IntToStr(ResultInt));
         Exit;
      end;

        for j := 0 to pAvailableNetworkList^.dwNumberOfItems - 1 do
        Begin
           WriteLn(Format('Profile         %s',[WideCharToString(pAvailableNetworkList^.Network[j].strProfileName)]));
           SDummy:=PAnsiChar(@pAvailableNetworkList^.Network[j].dot11Ssid.ucSSID);
           WriteLn(Format('NetworkName     %s',[SDummy]));
           WriteLn(Format('Signal Quality  %d ',[pAvailableNetworkList^.Network[j].wlanSignalQuality])+'%');
           //SDummy := GetEnumName(TypeInfo(Tndu_DOT11_AUTH_ALGORITHM),integer(pAvailableNetworkList^.Network[j].dot11DefaultAuthAlgorithm)) ;
           SDummy:=DOT11_AUTH_ALGORITHM_To_String(pAvailableNetworkList^.Network[j].dot11DefaultAuthAlgorithm);
           WriteLn(Format('Auth Algorithm  %s ',[SDummy]));
           SDummy:=DOT11_CIPHER_ALGORITHM_To_String(pAvailableNetworkList^.Network[j].dot11DefaultCipherAlgorithm);
           WriteLn(Format('Auth Algorithm  %s ',[SDummy]));
           Writeln('');
        End;
  end;

  WlanCloseHandle(hClient, nil);

end;
begin
  try
    Scan();
    Readln;
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

[schlagzu]

Danke, das hat mir schon weiter geholfen.
Er zeigt zwei Netzwerke an, was mich verwirrt. das eine als Profil das andere nicht (Unbenannt2.png). Daraufhin habe ich das Profil umbenannt, um zu sehen was er macht (Unbenannt.png). Resultat bei beiden zeigt er manchmal gleiche Werte manchmal ungleiche Werte (egal ob online oder offline). Welcher ist das Profil (lokal gespeichert) und was ist die tatsächliche Verbindung.

Noch eine Frage: Ich habe den Typ Tndu_WLAN_AVAILABLE_NETWORK und die Funktion WlanGetAvailableNetworkList gefunden, wie verwende ich die? Wie kriege ich das hin das er mir die Netzwerke auflistet, und sind damit überhaupt die gemeint, die er findet, nicht die er als Profil gespeichert hat?

MfG schlagzu

[schlagzu]

Noch was: Kennt sich einer mit Visual Basic .NET aus, und könnte mir helfen http://sourceforge.net/projects/wlaninfoproject/ auseinander zu basteln?

MfG schlagzu