WS_Child vom Desktop in der Taskleiste verbergen

[erich.wanker]

Hallo Leute,

ich hab eine kleines Programm, dass immer im Hintergrund liegt (also auf dem Desktop - genau das Gegenteil von StayOnTop..)

Sobald ich das Programm starte - sehe ich zwei (?) identische Programmeinträge in der Taskbar!
Nun versuche ich schon die ganze Zeit, die Einträge der Taskbar zu verbergen - ohne Erfolg :-(

Es sollte kein einziger Eintrag in der Taskbar angezeigt werden - hat jemand eine Idee ?

Vielen Dank
Erich

Codebeispiel:

Delphi-Quellcode:

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, LMDControl, LMDBaseControl, LMDBaseGraphicControl,
  LMDGraphicControl, LMDFill, LMDCustomControl, LMDCustomPanel,
  LMDCustomBevelPanel, LMDSimplePanel, StdCtrls, LMDCustomParentPanel,
  LMDCustomPanelFill, LMDPanelFill, LMDStarter,
  LMDCustomComponent, LMDSysInfo, Buttons, LMDWndProcComponent,
  Menus, ExtCtrls, StrUtils,JclSysInfo  ;

type
  TMainForm = class(TForm)
    LMDSysInfo1: TLMDSysInfo;
    LMDStarter1: TLMDStarter;
    LMDSimplePanel1: TLMDSimplePanel;
    LMDPanelFill1: TLMDPanelFill;
    infolabel: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure FormShow(Sender: TObject);

  private
     //nix
  public
     //nix
  protected
     procedure CreateParams(var Params: TCreateParams); override;
  end;

var
  MainForm: TMainForm;

implementation



{$R *.dfm}

procedure hide_app();      // Hier gehe ich alle Handles durch und suche mein Fenster
var
  Handle,WindowStyle: HWND;
begin
  Handle:=GetWindow(GetDesktopWindow(),GW_CHILD);
  while (Handle<>0) do
  begin
      if GetWindowCaption(Handle) = 'Interactive Desktop' then
      begin
        showmessage('Handle gefunden:"'+GetWindowCaption(Handle)+'"  Nr.:'+inttostr(Handle));
        WindowStyle := GetWindowLong(handle, GWL_STYLE);
        WindowStyle := WindowStyle-WS_ICONIC;
        SetWindowLong(handle, GWL_STYLE, WindowStyle) ;
        SetWindowLong(Handle, WS_ICONIC, WindowStyle);
        break;
      end;
  Handle:=GetWindow(Handle,GW_HWNDNEXT);
  end;
end;




procedure TMainForm.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);         //Hier setze ich das Parent und "keine fesnterrahmen"
  Params.WndParent := GetDesktopWindow;
  Params.Style := WS_CHILD;
end;


procedure TMainForm.FormCreate(Sender: TObject);
begin

MainForm.Top    :=screen.WorkAreaTop;
MainForm.Left   :=screen.WorkAreaLeft;                   // Größe des Hauptbildschirms
MainForm.Width  :=screen.WorkAreaWidth;
MainForm.Height :=screen.WorkAreaHeight;

infolabel.Caption:='Sie sind als '+LMDSysinfo1.currentuser+' am Computer '+LMDSysinfo1.computername+' angemeldet';

end;

procedure TMainForm.FormResize(Sender: TObject);
begin
application.ProcessMessages;
LMDPanelFill1.Repaint;
LMDPanelFill1.Refresh;
end;

procedure TMainForm.FormShow(Sender: TObject);
begin
hide_app;
end;

end.

[DeddyH]

Kannst Du mir hide_app() einmal erklären? Ich verstehe den Code nicht, ehrlich gesagt. Suchst Du das Handle von TMainForm? Und wie Du den Fensterstil änderst, sieht auch etwas kreativ aus :gruebel:

[edit] Du willst ein Fenster ohne Rahmen und ohne Taskbar-Eintrag, stimmt das soweit? Wie ist es denn so?

Delphi-Quellcode:

procedure TFormMain.CreateParams(var Params: TCreateParams);
begin
  inherited;
//  Params.WndParent := GetDesktopWindow;
//  Params.Style := Params.Style or WS_CHILD;
  Params.ExStyle := Params.ExStyle or WS_EX_TOOLWINDOW;
end;

procedure TFormMain.FormShow(Sender: TObject);
begin
  ShowWindow(Application.Handle, SW_HIDE);
end;

BorderStyle habe ich im OI auf bsNone gesetzt. [/edit]

[erich.wanker]

Hi DaddyH,

meine kreativen ;-) zeilen sollten mein Programm dem "Desktop" unterordnen und den Taskbar-Eintrag verbergen...

@Du willst ein Fenster ohne Rahmen und ohne Taskbar-Eintrag, stimmt das soweit? Wie ist es denn so?
Ja .. soll ein pseudo-"interaktiver Desktop" werden - die Desktop Icons werden dadurch auch "überlagert", was in meinem Fall sogar ein Vorteil ist ..

Meine "hide-app" Erklärung: (hoffentlich verständlich..) :stupid:

• Ich such ein Handle nach dem anderen
• Wenn das Handle mein Fenster ist - lade ich den Fensterstil via SetWindowLong in WindowStyle
• Dann streiche ich aus dem WindowStyle den Flag "WS_Iconic"
• Dann speichere ich den Fensterstil wieder zurück in mein Fenster
• (Mit "ShowWindow(Handle,SW_HIDE)" hab ich leider auch keinen Erfolg!

Die Probleme habe ich nur, wenn ich mein Fenster dem Desktop zuordne.. :pale:
..aber grad das ist ja das gewünschte ...:cry:

Delphi-Quellcode:

procedure hide_app(); 
var
  Handle,WindowStyle: HWND;
begin
  Handle:=GetWindow(GetDesktopWindow(),GW_CHILD);   // Alle Handle durchgehen
  while (Handle<>0) do                              //Handle gefunden
  begin
      if GetWindowCaption(Handle) = 'Interactive Desktop' then   // Ist der Handle mein fenster?
      begin
        showmessage('Handle gefunden:"'+GetWindowCaption(Handle)+'" Nr.:'+inttostr(Handle));   // Testausgabe Fenstername und ID
        WindowStyle := GetWindowLong(handle, GWL_STYLE);       // meinen Fensterstil auslesen mit GetWindowLong
        WindowStyle := WindowStyle-WS_ICONIC;                  // Dem Fensterstil das WS_ICONIC entfernen
        SetWindowLong(handle, GWL_STYLE, WindowStyle) ;        // und nun alles
        SetWindowLong(Handle, WS_ICONIC, WindowStyle);         // wieder setzen
        break;
      end;
  Handle:=GetWindow(Handle,GW_HWNDNEXT);
  end;
end;

[DeddyH]

Aber wenn Du aus der Prozedur eine Methode des Fensters machst, dann hast Du das Handle doch und musst es nicht mehr suchen. Oder wenn Dir das nicht behagt, übergib es doch als Parameter beim Aufruf. Hast Du übrigens den Code aus meinem Edit oben mal versucht?

[edit] Übrigens, das war wohl so gemeint:

Delphi-Quellcode:

WindowStyle := WindowStyle and not WS_ICONIC; // niemals (!!) subtrahieren
SetWindowLong(handle, GWL_STYLE, WindowStyle) ; 
//SetWindowLong(Handle, WS_ICONIC, WindowStyle); <-- hä?

[/edit]

[erich.wanker]

Super... vielen Dank!

1. SetWindowLong ... WS_ICONIC ist natürlich ein Mist von mir :oops:
2. Durch dein ExStyle greift jetzt SW_HIDE

hab jetzt folgendes (funktioniert auf WinXP bis SBS2011)

Delphi-Quellcode:

procedure TMainForm.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  Params.WndParent := GetDesktopWindow;
  Params.Style := WS_CHILD;
  Params.ExStyle := Params.ExStyle or WS_EX_TOOLWINDOW;
end;

und

Delphi-Quellcode:

procedure TMainForm.FormShow(Sender: TObject);
begin
ShowWindow(Application.Handle, SW_HIDE);
end;

Das LMDPanelFill1 hat ein Bildchen und das ganze funktioniert einwandfrei (siehe Bildanhang)

Vielen Dank

Erich