Komponenten Programmierung: PropertyEditor

[Sybok Factor]

Hallo allerseits,
kennt Jemand von Euch ein gutes Tutorial zur Komponentenprogrammierung? Ich versuche gerade das zu verstehen, aber ich scheitere immer wieder an Kleinigkeiten.
Ein Beispiel: Eine datengebundene Komponente hat ja das Property DataField. Im z.B. DBEdit klappt dann eine Liste auf, in der die Datenbankfelder aufgelistet werden.

Umsetzung in DBCtrls:

Delphi-Quellcode:

function GetDataField: Widestring;
begin
  Result := FDataLink.Field;
end;

Die Set-Methode greift ebenfalls aus FDatalink zu. Property ist Widestring.
In DBReg ist ein TDataFieldProperty deklariert, das die Valuelist zur Verfügung stellt.

In meiner Komponente habe ich also ein property DataField angelegt, Methoden wie im DBEdit. FDataLink wird auch erzeugt, und bekommt DataSource zugewiesen. Nur kommt leider keine Liste.

Gibt es also ein gutes Tutorial, das mir erklärt, wie ich es richtig mache? Oder gibt es eine Einschränkung das Professional User von der Komponentenprogrammierung ausschließt?
Die obige Frage ist mehr als ein Beispiel meines Problems zu sehen.
Ich arbeite mit Delphi Prof. 2010.

Viele Grüße
Sybok Factor

[himitsu]

Dieses Property ist ja nur zum Setzen eines neuen Wertes, bzw. zum auslesen des alten Wertes.

Das Property alleine weiß natürlich nicht, was man da sonst noch eintragen kann,
also weiß es der Standard-PropertyEditor für WideStrings das natürlich auch nicht. :zwinker:

Du muß da also schon einen eigenen PropertyEditor erstellen und mit diesem Property (z.B. via PropertyName und Klassenname) verknüpfen, in welchem zu dann die Liste erstellst.


Ich glaub hier drin http://wiki.delphigl.com/index.php/T...tenentwicklung steht irgendwo etwas dazu.
Hatte es Letzens für Integer-Property verwendet, allerdings mit einem Editfenster (wie bei TStrings), anstatt dem Dropdown, da es zuviele Werte waren.

[Sybok Factor]

Danke schon mal für die Antwort, himitsu.

Die obige Fragestellung ist mehr als Beispiel zu sehen... Zu dem PropertyEditor.

Ich gehe hin und lege mir in meiner Komponente an:

Delphi-Quellcode:

TMyEditor = class (TPropertyEditor)
end.

Jetzt ist TPropertyEditor nicht bekannt, flugs die Hilfe geöffnet: Aha, kommt aus DesignEditors. In uses Klausel aufgenommen. Kompilieren, ups, in der ToolsAPI wird TDockableForm als undeklarierter Bezeichner ausgeworfen. Nach ein bißchen Suchen stellt sich heraus: TDockableForm soll in der Unit ToolsAPI deklariert sein. Usw. usw.

Was hast Du denn veranstaltet, damit Du Dein Property anders bearbeiten konntest? (Ich kann mir das Beispielprojekt z.z. nicht ansehen, vielleicht würde es ja daraus klarer).
Setzt Du auch Professional ein oder höher? (Ich habe langsam das Gefühl, dass unter Prof. Teile zur Komponenten Bearbeitung fehlen, deshalb frage ich).

[himitsu]

Bei mir sieht es aktuell so aus. (ganz billig, aber es läuft :stupid:)

Delphi-Quellcode:

uses DesignIntf, DesignEditors;

type
  TText0 = type Integer;
  TText0Property = class(TPropertyEditor)
  public
    function  GetAttributes: TPropertyAttributes;      override;
    procedure Initialize;                              override;
    procedure Edit;                                    override;
    function  GetValue:             string;            override;
    procedure SetValue(const Value: string); overload; override;
  end;

procedure register;
begin
  RegisterPropertyEditor(TypeInfo(TText0), nil, '', TText0Property);

  // RegisterPropertyEditor(TypeInfo(WideString), TDeineKlasseWoDasPropertyDrinIst, 'DataField', TDataFieldProperty);
end;

procedure TText0Property.Edit;
var
  F: TForm;
  G: TDBGrid;
begin
  F := TForm.Create(nil);
  try
    G := TDBGrid.Create(F);
    G.Align := alClient;
    G.Parent := F;
    G.DataSource := TDataSource.Create(F);
    G.DataSource.DataSet := DM1.MemTextX;
    DM1.MemTextX.Active := True;
    DM1.MemTextX.Locate('t_nr', GetOrdValue, []);
    F.Position := poScreenCenter;
    F.Height := Screen.Height - 100;
    F.Width := 500;
    F.ShowModal;
    SetOrdValue(DM1.MemTextXt_nr.AsInteger);
  finally
    F.Free;
  end;
end;

function TText0Property.GetAttributes: TPropertyAttributes;
begin
  Result := [paDialog];
end;

function TText0Property.GetValue: string;
begin
  if GetOrdValue <> 0 then
    Result := IntToStr(GetOrdValue) + ': ' + makeText(GetOrdValue)
  else
    Result := IntToStr(GetOrdValue);
end;

procedure TText0Property.Initialize;
begin
  inherited;
end;

procedure TText0Property.SetValue(const Value: string);
begin
  SetOrdValue(StrToInt(Trim(Copy(Value, 1, Pos(':', Value + ':') - 1))));
end;

Und dazu noch das Package "DesignIde" in das eigene Package aufnehmen, bei "Erfordert".



GetValue und SetValue brauchte ich, da ich was anderes "Anzeige", als Wertmäßig in dem Property drinsteht.
In Initialize würdest du, wenn ich das richtig im Kopf hab, dann irgendwie die Liste für deine DropDownBox erstellen/befüllen.
Bei paDialog dann ntürlich was anderes, für das DropDown.
Und Edit ist bei mit der Button im Property-Edit, da im OI. (so wie bei Lines in TMemo)

[Sybok Factor]

Hallo himitsu,
es hat ein bißchen gedauert, bis ich testen konnte und vor allen Dingen, bis ich das gewünschte Ergebnis bekam. Deine Antwort hat mir auf dem Weg dorthin sehr geholfen, danke.