Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Object-Pascal / Delphi-Language (https://www.delphipraxis.net/32-object-pascal-delphi-language/)
-   -   D2007 Vererbung Constructor (https://www.delphipraxis.net/169540-d2007-vererbung-constructor.html)

hanspeter 27. Jul 2012 14:10

Delphi-Version: 5

D2007 Vererbung Constructor
 
Hallo,
ich habe ein kleines OOP Problem, bei dem ich mal einen Tip brauche.
(Ich verwende D2007)
Von einer Basisklasse sollen beliebig viele Klassen abgeleitet werden.
Diese werden in einer TClasslist verwaltet und nur bei Bedarf instanziert.

Delphi-Quellcode:
TBasis = class
  ID: string;
  Constructor Create; virtual; abstract; // oder auch nicht abstract
end;

type TBasisClass = class of TBasis;

//Ableitung

TNewClass = Class(TBasis)
  Constructor Create; override;
end;
Die Klassen werden in der Liste als TBasisClass abgelegt.

Wenn ich jetzt eine Instanz erzeuge, dann möchte ich den Constructor der letzten Vererbung aufrufen.
In dem Beispiel also der Constructor von TNewClass.

Delphi-Quellcode:
Instance : TBasisClass;
Parameter vom Typ TBasisClass;

Instance := Parameter.Create; // Create soll jezt aus der Vererbung kommen.
Ist das hinzukriegen?

Gruß
Peter

Uwe Raabe 27. Jul 2012 14:25

AW: D2007 Vererbung Constructor
 
Zitat:

Zitat von hanspeter (Beitrag 1176062)
Ist das hinzukriegen?

Ja.

Zitat:

Zitat von hanspeter (Beitrag 1176062)
ich habe ein kleines OOP Problem

Wobei denn?

Was du beschreibst, müsste eigentlich so einfach funktionieren.

uligerhardt 27. Jul 2012 14:26

AW: D2007 Vererbung Constructor
 
Einfach mal so in den Forumseditor getippt:
Delphi-Quellcode:
function Erzeugs(AClass: TBasisClass): TBasis;
begin
  Result := AClass.Create;
end;

MyBasisList.Add(Erzeugs(TNewClass));

himitsu 27. Jul 2012 15:26

AW: D2007 Vererbung Constructor
 
Es wird die Methode (Create) verwendet, welche im Basistyp deklariert ist.
Mit Virtual wird dort allerdings ein Eintrag in der VMT der Klasse erstellt.

Und jedesmal, wenn diese Methode nun aufgerufen wird, schaut Delphi in der VMT nach, was "aktuell" dort für eine Methode verlinkt ist.

Aktuell = Der Typ, welcher für die Erstellung der Klasse verwendet wurde, bzw. bei solch einer "class method" (in diesem Fall ein constructor) was in der VMT des Typs deklariert ist, welcher in deiner Variable gespeichert wurde.
Also die Methode welche in diesem Typen als letzes per Override dort eingetragen wurde.


Wäre dein "Parameter" z.B. vom Typ TClass, würde in TObject nachgesehn, dort steht nur ein nichtvirtuelles Create und somit würde direkt das Create des TObject verwendet, selbst wenn es im gespeichertem Typ ein "neueres" Create gäbe.

hanspeter 28. Jul 2012 12:20

AW: D2007 Vererbung Constructor
 
Eigentlich sollte es funktionieren, tut es aber nicht.

Hier nochmal ein gekürztes Beispiel.
Es gibt dann viele unterschiedliche WorkClass, die sich bei einem zentralen Handler registrieren und von diesen bei Bedarf instanziert werden.
Hat wer noch einen Tip?

Delphi-Quellcode:
unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    btn1: TButton;
    procedure btn1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;


(***************  Beispiel Code *****************)
type
  TBasisClass = class
    ID : String;
    Constructor Create; virtual;
  end;

type
  TGruppenClass = class(TBasisClass)
    const GruppenID='KA';
    Constructor Create; virtual;
  end;

type
  TWorkerClass = class(TGruppenClass)
    Constructor Create;
  end;

type
  TBasisClassClass = class of TBasisClass;


implementation

{$R *.dfm}

{ TWorkerClass }

var
  Instance : TBasisClassClass;
  Work: TBasisClass;

procedure Register(Classe : TBasisClassClass);
begin
  Instance := Classe;

  Work := Instance.Create;
  if Work.ID = '123' then
    Messagebeep(1);
end;

constructor TWorkerClass.Create;
begin
  ID := '123';
end;

procedure TForm1.btn1Click(Sender: TObject);
begin
  Register(TWorkerClass);
end;

{ TGruppenClass }

constructor TGruppenClass.Create;
begin
  inherited;
end;

{ TBasisClass }

constructor TBasisClass.Create;
begin
  inherited;
end;

end.

sx2008 28. Jul 2012 12:27

AW: D2007 Vererbung Constructor
 
Virtuelle Konstruktoren müssen in den abgeleiteten Klassen mit override deklariert werden.
Delphi-Quellcode:
type
  TGruppenClass = class(TBasisClass)
    const GruppenID='KA';
//    Constructor Create; virtual; // falsch
    Constructor Create; override; // richtig
  end;

  TWorkerClass = class(TGruppenClass)
//    Constructor Create; // falsch
    Constructor Create; override; // richtig
  end;

hanspeter 28. Jul 2012 13:54

AW: D2007 Vererbung Constructor
 
Zitat:

Zitat von sx2008 (Beitrag 1176143)
Virtuelle Konstruktoren müssen in den abgeleiteten Klassen mit override deklariert werden.

Das wars. Danke.
override schon 100 mal verwendet.
Manchmal hat man Tomaten auf den Augen oder wird langsam alt.

Gruß Peter

jbg 28. Jul 2012 17:24

AW: D2007 Vererbung Constructor
 
Hattest du dir die Warnung, die der Compiler ausgegeben hat, etwa nicht angeschaut?

Zitat:

[DCC Warnung] Unit1.pas(34): W1010 Methode 'Create' verbirgt virtuelle Methode vom Basistyp 'TBasisClass'

Sir Rufo 28. Jul 2012 18:45

AW: D2007 Vererbung Constructor
 
Zitat:

Zitat von hanspeter (Beitrag 1176151)
Zitat:

Zitat von sx2008 (Beitrag 1176143)
Virtuelle Konstruktoren müssen in den abgeleiteten Klassen mit override deklariert werden.

Das wars. Danke.
override schon 100 mal verwendet.
Manchmal hat man Tomaten auf den Augen oder wird langsam alt.

Gruß Peter

oder du kennst den Shortcut Strg-Space innerhalb der Klassendeklaration nicht, dann kommt das von ganz alleine ;)

himitsu 28. Jul 2012 20:58

AW: D2007 Vererbung Constructor
 
Zitat:

Zitat von jbg (Beitrag 1176157)
Hattest du dir die Warnung, die der Compiler ausgegeben hat, etwa nicht angeschaut?

Währe ja auch zu einfach, wenn alle sich das ansehn würden. :roll:

Zitat:

Delphi-Quellcode:
var
  Instance : TBasisClassClass;
  Work: TBasisClass;

Das würde ich eher als CLASS VAR mit in die TBasisClass aufnehmen, genauso wie die Register-Methode als CLASS PROCEDURE.

Ist dir denn nicht aufgefallen, daß Register fett ist?
Es gibt schon von der VCL eine Register-Prozedur,
Und dein "Instance" ist keine Instanz, denn darin wird nur die Klasse gepseichert.
Die eigentliche "Instanz" speicherst du allerdings in Worker. :stupid:


Alle Zeitangaben in WEZ +1. Es ist jetzt 09:24 Uhr.

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz