Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   GUI-Design mit VCL / FireMonkey / Common Controls (https://www.delphipraxis.net/18-gui-design-mit-vcl-firemonkey-common-controls/)
-   -   Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt (https://www.delphipraxis.net/172338-eigene-komponente-timages-werden-zur-laufzeit-nicht-angezeigt.html)

romber 27. Dez 2012 16:04

Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt
 
Hallo!

Ich bin verzweifelt: ich gerade eine eigene Komponente, die unter Anderem aus mehreren TImage besteht. Dabei habe ich das Problem, dass die bei designtime gesetzte Grafiken zur Laufzeit nicht angezeigt werden. Hier ein Beispiel, wie ich es mache?

Delphi-Quellcode:
type
  TTestControl = class(TPanel)
  constructor Create(AOwner: TComponent); override;
  destructor Destroy; override;
  private
    FButtonNormal: TImage;
    FButtonHot: TImage;

    FPictureNormal: TPicture;
    FPictureHot: TPicture;

    procedure SetPictureNormal(APicture: TPicture);
    procedure SetPictureHot(APicture: TPicture);
  published
    property PictureNormal: TPicture read FPictureNormal write SetPictureNormal;
    property PictureHot: TPicture read FPictureHot write SetPictureHot;
end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('TestControls', [TTestControl]);
end;

constructor TTestControl.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  Width := 150;
  Height := 150;

  FButtonNormal := TImage.Create(Self);
  FButtonNormal.Parent := Self;
  FButtonNormal.Top := 20;
  FButtonNormal.Left := 20;
  FButtonNormal.Width := 50;
  FButtonNormal.Height := 50;

  FButtonHot := TImage.Create(Self);
  FButtonHot.Parent := Self;
  FButtonHot.Top := 20;
  FButtonHot.Left := 50;
  FButtonHot.Width := 50;
  FButtonHot.Height := 50;

  FPictureNormal := TPicture.Create;

  FPictureHot := TPicture.Create;
end;

destructor TTestControl.Destroy;
begin
  if Assigned(FPictureHot) then FreeAndNil(FPictureHot);
  if Assigned(FPictureNormal) then FreeAndNil(FPictureNormal);
  if Assigned(FButtonHot) then FreeAndNil(FButtonHot);
  if Assigned(FButtonNormal) then FreeAndNil(FButtonNormal);

  inherited Destroy;
end;

procedure TTestControl.SetPictureNormal(APicture: TPicture);
begin
  FPictureNormal.Assign(APicture);
  FButtonNormal.Picture := FPictureNormal;
end;

procedure TTestControl.SetPictureHot(APicture: TPicture);
begin
  FPictureHot.Assign(APicture);
  FButtonHot.Picture := FPictureHot;
end;
Was mache ich falsch?

Bummi 27. Dez 2012 16:53

AW: Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt
 
Ohne es zu testen würde ich zu folgendem Versuch raten (die TPictures weglassen)


Delphi-Quellcode:
    property PictureNormal: TPicture read GetPictureNormal write SetPictureNormal;
    property PictureHot: TPicture read GetPictureHot write SetPictureHot;



procedure TTestControl.SetPictureNormal(APicture: TPicture);
begin
  FButtonNormal.Picture.Assign(APicture);
end;

procedure TTestControl.SetPictureHot(APicture: TPicture);
begin
  FButtonHot.Picture.Assign(APicture);
end;

Function TTestControl.GetPictureNormal: TPicture;
begin
  Result := FButtonNormal.Picture;
end;

Function TTestControl.GetPictureHot: TPicture;
begin
  Result :=FButtonHot.Picture;
end;

romber 27. Dez 2012 17:03

AW: Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt
 
:wall::wall::wall: Das geht, vielen Dank!!!

Bummi 27. Dez 2012 17:06

AW: Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt
 
:thumb:

DeddyH 27. Dez 2012 18:46

AW: Eigene Komponente: TImages werden zur Laufzeit nicht angezeigt
 
Eigentlich könnte man sogar die TImages weglassen und direkt auf das Panel zeichnen, der Canvas ist ja protected und somit in abgeleiteten Klassen zu erreichen.


Alle Zeitangaben in WEZ +1. Es ist jetzt 20:24 Uhr.

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz