Fastreport, mehrsprachige Reports

[EarlyBird]

Hallo,
ich überlege gerade wie ich meine mit Fast-Report (4.7) erstellten Reports am besten Mehrsprachig gestalte.
Im Augenblick arbeite ich mit Templates.
Mein Mastertemplate ist in deutsch und daraus erstelle ich dann die verschiedenen Sprachen.
Der z.B. spanische Report basiert auf dem deutschen Template.
In dem spanischen Report übersetze ich dann alle deutschen Beschriftungen ins spanische.
(Die Daten aus der Datenbank werden schon in der richtigen Sprache angezeigt)
Das ganze gefällt mir aber nicht so richtig.
Ich würde die Beschriftungen lieber auch aus der Datenbank oder einer Ini-Datei auslesen.

Wie geht Ihr bei solchen Reports vor?
Über ein paar Anregungen würde ich mich freuen.

Gruß
EarlyBird

[ibp]

was mir gerade einfällt du könntest mit der uses Klausel eine Sprachdatei einbinden in dem Textkonstanten vorhanden sind und diese dann verwenden.

[Lemmy]

Hi,

ich habe die Reports versucht mit Übersetzungstools zu bearbeiten (Sizulizer) - hatte damit aber das Problem, dass jeder Report einzeln dem Projekt hinzugefügt werden muss. War jeden falls kompliziert und fehleranfällig. Dein Weg mit dem Mastertemplate gefällt mir dagegen schon recht gut :-)

GRüße

[EarlyBird]

Zitat:

Zitat von Lemmy (Beitrag 1203465)

Dein Weg mit dem Mastertemplate gefällt mir dagegen schon recht gut :-)

Danke :) aber das ist mir zu umständlich, da ich bei Änderungen immer so viele Dateien änder muss.
Auch auf verschiedenen Servern.

Zitat:

Zitat von ibp (Beitrag 1203460)

was mir gerade einfällt du könntest mit der uses Klausel eine Sprachdatei einbinden in dem Textkonstanten vorhanden sind und diese dann verwenden.

Das muss ich mal zu ende Denken ob es mir wirklich weiterhilft.


je mehr ich darüber nachdenke scheint mir Lösung mit der Datenbank die die flexibelste zu sein.
Ich könnte die Objektnamen aus dem Report in einer Tabelle speichern und dann in "Sprachfeldern" die jeweilige Übersetzung
Nach dem Laden des Reports kann ich dann in einer Schleife alle Reportobjecte suchen und den Text anpassen.
Was meint Ihr dazu?

Weitere Anregungen und Meinungen sind herzlich Willkommen

[DSCHUCH]

Wir machen das, indem die beschriftungsfelder eigene Funktionen erhalten, welche dann vom programm übersetzt werden.

Stichworte "AddFunction" bzw. "TfrxReport.OnUserFunction"

Die Variante mit Templates und Ableitungen ist gut, hat aber den Nachteil das man 2 Scripte hat, da nur das Layout und nicht das Script vererbt ist (das könnte man aber selbst implementieren).

[EarlyBird]

Zitat:

Zitat von DSCHUCH (Beitrag 1203491)

Wir machen das, indem die beschriftungsfelder eigene Funktionen erhalten, welche dann vom programm übersetzt werden.

Stichworte "AddFunction" bzw. "TfrxReport.OnUserFunction"

Die Variante mit Templates und Ableitungen ist gut, hat aber den Nachteil das man 2 Scripte hat, da nur das Layout und nicht das Script vererbt ist (das könnte man aber selbst implementieren).

Das habe ich nicht ganz verstanden.
Kannst Du es mir bitte ein bisschen genauer erklären?

[DSCHUCH]

du kannst in FR ja callbacks implementieren. Dann kannst Du aus dem Listengestalter heraus funktionen aufrufen, die Programmseitig abgearbeitet werden und dann ein ergebnis in den Listengestalter zurückgeben.

Du kannst zB im FR eine Funktion registrieren "translate(konstante: String) : string)"

In dein Memo schreibst Du dann den Funktionsaufruf "[translate('artikel')]"

FR ruft dann zum Zeitpunkt des Drucks Deine Delphi Funktion auf, darin kannst Du dann zB dinge machen wie
"If Kunde = EN then Result:='article no.'"
"If Kunde = D then Result:='Artikel'"

Dadurch hast du zur DesignTime der Liste überall konstanten, die dann von deiner Software in Abhängigkeit andere Werte zurückgeben. Wir haben zB immer ein Wörterbuch (Dictionary) aus der DB im Cache geladen, welches alle Konstanten hält.

[user0815]

beim Erstellen des TfrxReport auf die Variablen zugreifen & die Texte entsprechend setzen:

Delphi-Quellcode:

var
  i : Integer;
  Variable : TfrxVariable;
  MemoFeld : TfrxMemoView;
begin
  i := Report.Variables.IndexOf('ReportVariable');
  if i <> -1 then
  begin
    Variable := Report.Variables.Items[i];
    Variable.Value := QuotedStr('Anzeigetext');
  end;

...

Report.ShowReport();

[ibp]

könnte man doch auch innerhalb des Reportes steuern, hätte den Vorteil dass es nur für den jeweiligen Report angepasst werden müsste. Bei der Steuerung vom aufrufenden Programm müsste das ja jedes mal angepasst werden wenn etwas ergänzt oder verändert wird...

[ensaron]

Ähnlich wie user0815 mit den Variablen nutze ich folgende Funktion um die Komponenten eines Reports zu übersetzen (mittels der gnugettext):

Delphi-Quellcode:

for i := 0 to Report.ComponentCount - 1 do
begin
  if Report.Components[i] is TfrxMemoView then
  begin
    TranslateMemo := TStringList.Create;
    try
      TranslateMemo.Text := TfrxMemoView(lComponent).Memo.Text;
      for j := 0 to TranslateMemo.Count - 1 do
        TranslateMemo[j] := _(TranslateMemo[j]); //Übersetzungsfunktion der gnuggettext
      TfrxMemoView(lComponent).Memo.Text := TranslateMemo.Text;
    finally
      TranslateMemo.Free;
    end;
  end;
end;
Report.ShowReport;

[EarlyBird]

Zitat:

Zitat von DSCHUCH (Beitrag 1203510)

Du kannst zB im FR eine Funktion registrieren "translate(konstante: String) : string)"

In dein Memo schreibst Du dann den Funktionsaufruf "[translate('artikel')]"

Dadurch hast du zur DesignTime der Liste überall konstanten, die dann von deiner Software in Abhängigkeit andere Werte zurückgeben. Wir haben zB immer ein Wörterbuch (Dictionary) aus der DB im Cache geladen, welches alle Konstanten hält.

Vielen Dank für die Info.
Ich habe es gerade getestet und es funktioniert wie gewünscht.
Ich werde es nun mit der registrierten Funktion implementieren.
So kann ich die Übersetzungen gut in der Datenbank speichern und bei bedarf anpassen ohne den Report zu ändern.
Und ich brauche nur einen Report für viele Sprachen :-D

Noch eine weitere Frage:
Übergebt Ihr alle möglichen Konstanten aus dem Wörterbuch an den Report damit sie als Auswahlliste im Designer zur Verfügung stehen?
Und Wenn ja wie?

[DSCHUCH]

nein, wir geben den konstantennamen zurück, wenn es keine übersetzung exstiert. wir haben allerdings eine möglichkeit implementiert, vom reportdesigner aus in unser wörterbuch zu schauen, damit man weiß welche konstanten bereits vorhanden sind und somit automatisch übersetzt werden.

das andere bsp (wurde hier auch schon einmal vorgeschlagen) haben wir aber auch implementiert:

darin werden alle felder übersetzt, in abhängigkeit dessen was im listenlayout hinterlegt wurde. man hat aber dadurch das problem "zufälliger übersetzungen"

Code:

   For I:=0 to frxReport1.ComponentCount-1 do
       If (frxReport1.Components[I] IS TfrxMemoView)then
          begin
           If not (Sender=btDesignReport) then//keine Übersetzung der Captions im Designer!
              (frxReport1.Components[I] AS TfrxMemoView).Memo.Text:=DM1.GetFieldAlias(Trim((frxReport1.Components[I] AS TfrxMemoView).Memo.Text));
           (frxReport1.Components[I] AS TfrxMemoView).DisplayFormat.DecimalSeparator:=FormatSettings.DecimalSeparator;
           If (frxReport1.Components[I] AS TfrxMemoView).Frame.Width=1 then
              (frxReport1.Components[I] AS TfrxMemoView).Frame.Width:=0.1;
          end

[EarlyBird]

Zitat:

Zitat von DSCHUCH (Beitrag 1203730)

nein, wir geben den konstantennamen zurück, wenn es keine übersetzung exstiert.

Ich gebe den konstantennamen mit angehängtem ? zurück.
Damit sieht man sofort wo etwas fehlt

Zitat:

Zitat von DSCHUCH (Beitrag 1203730)

wir haben allerdings eine möglichkeit implementiert, vom reportdesigner aus in unser wörterbuch zu schauen, damit man weiß welche konstanten bereits vorhanden sind und somit automatisch übersetzt werden.

Kannst Du mir da noch einen Tipp geben wie Ihr das gelöst habt.
So eine List würde ja schon mal viel helfen beim erstellen der Reports

[DSCHUCH]

...letztendlich über ein form, welche mittels hotkey aufgerufen kann und ein Memdataset in form eines Grids darstellt. ;)

als zB über einen timer und GetASyncKeystate, formStyle StayOnTop

[Union]

Wir haben das wie folgt gelöst (es wird Localizer eingesetzt, aber die Funktion GetTranslatedProperty sowie die Native-Abfrage kann ja leicht angepasst werden). Die Funktion wird dann vor dem ShowReport oder PrepareReport aufgerufen.

Delphi-Quellcode:

procedure PrepareFrx(Report : TFrxReport);
   //------------------------------------------------------------------------
   // Abfrage der Strings aus Localizer
   //------------------------------------------------------------------------
    function GetTranslatedProperty(const FormName, PropertyName : string): string;
    begin
       Result := LocOnFly.LocalizerOnFly.GetTranslatedProperty(Formname, PropertyName);
    end;
var
   i : integer;
   ResString : widestring;
   FormName, CompName : string;
   Native : boolean;
begin
   // Feststellen, ob übersetzt werden müss
   Native := (LocalizerOnFly.NativeLocale = LocalizerOnFly.CurrentLocale);

   // Name der Elternkomponente, sollte immer das Formular sein ...
   if Report.Owner <> nil then
      Formname := Report.Owner.Name;

   // Alle Reportkomponenten durchlaufen
   for i := 0 to Report.ComponentCount-1 do
   begin
      // wenn es ein Textfeld ist
      if TFrxComponent(Report.Components[i]) is TFrxMemoView then
      begin
         // Die Spezialfälle eintragen, die müssen dann so heißen
         CompName := Lowercase(TFrxComponent(Report.Components[i]).Name);
         if CompName = 'qrluser' then
            TFrxMemoView(Report.Components[i]).Memo.Text := UserName
         else
         if CompName = 'qrlprogramname' then
            TFrxMemoView(Report.Components[i]).Memo.Text := ProgramName+' '+CopyRight
         else
         if CompName = 'qrlversion' then
            TFrxMemoView(Report.Components[i]).Memo.Text := ProgramVersion
         else
         if not Native then
         begin
            // Wenn Übersetzung notwendig, dann den übersetzten String holen
            // ResString := LocOnFly.LocalizerOnFly.GetTranslatedProperty(Formname,TFrxComponent(Report.Components[i]).Name+'.Memo.UTF8');
            ResString := GetTranslatedProperty(Formname,TFrxComponent(Report.Components[i]).Name+'.Memo.UTF8');

            // und eintragen
            if ResString <> '' then
               TFrxMemoView(Report.Components[i]).Memo.Text := ResString;
            // wichtig, da UTF8 keine CHARSETS verträgt! Localizer trägt aber
            // beim Einlesen der Übersetzung das Charset der Zielsprach-Lokale ein.
            // Also DEFAULT_CHARSET setzen
            TFrxMemoView(Report.Components[i]).Font.Charset := 1;
         end;
      end;
   end;
   if frmData.tblSetup.FieldByName('WaterMark').AsString <> '' then
      CreateReportWaterMark(Report, frmData.tblSetup.FieldByName('WaterMark').AsString);
end;

[EarlyBird]

Zitat:

Zitat von DSCHUCH (Beitrag 1203736)

...letztendlich über ein form, welche mittels hotkey aufgerufen kann und ein Memdataset in form eines Grids darstellt. ;)
als zB über einen timer und GetASyncKeystate, formStyle StayOnTop

Ich habe den Designer ein wenig erweitert.
Mit folgendem Code füge ich meine Konstanten in einer Combobox in der Toolbar des Designers ein.
Ob alles funktioniert muss ich aber noch Testen.
Angezeigt wird die Combobox mit den Konstanzen schon.

Delphi-Quellcode:

var
   designer: TfrxDesignerForm;
   myDesigner: TfrxCustomDesigner;
   cbb2: TComboBox;
   tlb2: TToolBar;
begin
  myDesigner := TfrxCustomDesigner(frxDesignerClass.NewInstance);
  myDesigner.CreateDesigner(nil, frxReport);
  frxReport.Designer :=  MyDesigner;

  designer := TfrxDesignerForm(frxReport.Designer);
  cbb2 := TComboBox.Create(Self);
  tlb2 := TToolBar.create(self);
  tlb2.Parent:= Designer.DockTop;

  cbb2.Parent :=  tlb2;
  cbb2.Items.Add('Anzahl');
  cbb2.Items.Add('Ausfuehrung');
  cbb2.Items.Add('Box');
  cbb2.Items.Add('Breite');
  cbb2.Items.Add('Durchmesser');
  cbb2.Items.Add('Waage');
  Designer.Showmodal;

und mit folgendem Code kann man einen weitern Tab im Databaum hinzufügen und die Konstanten z.B in einer Listbox anzeigen

Delphi-Quellcode:

  lb_Constanten := TListBox.Create(self);
  Pn_Constanten := TPanel.Create(Self);
  Designer.Show;
  for x := 0 to Designer.DataTree.ControlCount - 1 do
    begin
      myClassname := Designer.DataTree.Controls[x].ClassType.ClassName;
      if  myClassname = 'TTabSet' then
        begin
          MyTabs := TTabSet(Designer.DataTree.Controls[x]);
          Break;
        end;
    end;
  Pn_Constanten.parent := Designer.DataTree.DataPn.parent;
  Pn_Constanten.Align := Designer.DataTree.DataPn.Align;
  Pn_Constanten.BoundsRect := Designer.DataTree.DataPn.BoundsRect ;
  Pn_Constanten.Visible := False;
  lb_Constanten.Parent :=  Pn_Constanten;
  MyTabs.Tabs.AddObject('TransLations', Pn_Constanten);
  lb_Constanten.Items  :=  cbb2.Items;
  lb_Constanten.Align  := alClient;
  Designer.DataTree.UpdateItems;

Ist alles noch nicht perfekt aber der Ansatz gefällt mit gut

Jetzt möchte ich natürlich noch die Translate Funktion per doppelklick auf die Combobox oder Listbox in die Memos schreiben.
Hat da jemand einen Tipp?

[EarlyBird]

Zitat:

Zitat von EarlyBird (Beitrag 1203780)

Jetzt möchte ich natürlich noch die Translate Funktion per doppelklick auf die Combobox oder Listbox in die Memos schreiben.
Hat da jemand einen Tipp?

Mein Eigener Tipp :-D
Für die die es interessiert

Delphi-Quellcode:

  MyDesigner: TfrxCustomDesigner;
implementation

{$R *.dfm}

procedure TForm3.btn1Click(Sender: TObject);
var
   ...
   ...
begin
  MyDesigner := TfrxCustomDesigner(frxDesignerClass.NewInstance);
  MyDesigner.CreateDesigner(nil, frxReport);
//usw wie oben beschrieben


procedure lst1DblClick(Sender: TObject);
var
 tranlateStr: string;
 myMemoView : TfrxMemoView;
 myListBox : TListBox;
begin
  myListBox := TListBox(Sender);
  tranlateStr:= myListBox.Items[myListBox.ItemIndex] ;
  myMemoView := MyDesigner.SelectedObjects.Items[0];
  myMemoView.Text := 'TransLate[' +  QuotedStr(tranlateStr) +']';
end;

Es gibt noch ein bisschen was zu tun am Code
aber das Prinzip funktioniert.
Jetzt muss ich es nur noch ein bisschen verfeineren

Das ganze wird schon eine deutliche Hilfe beim erstellen mehrsprachiger Dokumente.
Die Verschiedenen Sprachen speicher ich in einer Datenbank mit den Konstanten
Diese kann ich dann immer per doppelklick in ein TfrxMemoView im Fastreport Designer einfügen.
Für mich eine sehr gute Lösung.

Vielen Dank für all die Tipps und Anregungen :-D

[EarlyBird]

Wenn mal jemand etwas ähnliches machen möchte.
Diesen Code kann man als ersten Ansatz nutzen.

Delphi-Quellcode:

unit Unit3;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Tabs,
  Dialogs, ExtCtrls, frxDesgn, frxClass, StdCtrls, ToolWin, ComCtrls;

type
  TForm3 = class(TForm)
    btn1: TButton;
    frxreport: TfrxReport;
    frxDesigner1: TfrxDesigner;
    pnl1: TPanel;
    procedure btn1Click(Sender: TObject);
    procedure lst1DblClick(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form3: TForm3;
  MyDesigner: TfrxCustomDesigner;
implementation

{$R *.dfm}

procedure TForm3.btn1Click(Sender: TObject);
var
   Designer: TfrxDesignerForm;
   cbb2: TComboBox;
   tlb2: TToolBar;
   MyTabs : TTabSet;
   lb_Constanten: TListBox;
   Pn_Constanten: TPanel;
   x : Integer;
   myClassname : String;
   mymemp :  TfrxMemoView;
begin
  MyDesigner := TfrxCustomDesigner(frxDesignerClass.NewInstance);
  MyDesigner.CreateDesigner(nil, frxReport);
  frxReport.Designer :=  MyDesigner;
  Designer := TfrxDesignerForm(frxReport.Designer);
  cbb2 := TComboBox.Create(Self);
  tlb2 := TToolBar.create(self);
  tlb2.Parent:= Designer.DockTop;
  cbb2.Parent :=  tlb2;
  cbb2.Items.Add('Anzahl');
  cbb2.Items.Add('Ausfuehrung');
  cbb2.Items.Add('Box');
  cbb2.Items.Add('Breite');
  cbb2.Items.Add('Durchmesser');
  cbb2.Items.Add('Waage');

  lb_Constanten := TListBox.Create(self);
  Pn_Constanten := TPanel.Create(Self);


  Designer.Show;
  for x := 0 to Designer.DataTree.ControlCount - 1 do
    begin
      myClassname := Designer.DataTree.Controls[x].ClassType.ClassName;
      if  myClassname = 'TTabSet' then
        begin
          MyTabs := TTabSet(Designer.DataTree.Controls[x]);
          Break;
        end;
    end;

  Pn_Constanten.parent := Designer.DataTree.DataPn.parent;
  Pn_Constanten.Align := Designer.DataTree.DataPn.Align;
  Pn_Constanten.BoundsRect := Designer.DataTree.DataPn.BoundsRect ;
  Pn_Constanten.Visible := False;
  lb_Constanten.Parent :=  Pn_Constanten;
  MyTabs.Tabs.AddObject('TransLations', Pn_Constanten);
  lb_Constanten.Items  :=  cbb2.Items;
  lb_Constanten.Align  := alClient;
  lb_Constanten.OnDblClick := lst1DblClick;
  Designer.DataTree.UpdateItems;
end;

procedure TForm3.btn2Click(Sender: TObject);
begin
  frxReport.DesignReport;
end;

procedure TForm3.lst1DblClick(Sender: TObject);
var
 tranlateStr : string;
 myMemoView : TfrxMemoView;
 myListBox : TListBox;
begin
  if MyDesigner.SelectedObjects.Count > 1 then
    begin
      MessageDlg('Bitte wählen Sie ein einzelnes MemoView aus.',
        mtInformation, [mbOK], 0);
      Exit;
    end;
  myListBox := TListBox(Sender);
  tranlateStr := myListBox.Items[myListBox.ItemIndex] ;
  try
    myMemoView := MyDesigner.SelectedObjects.Items[0];
    myMemoView.Text := 'TransLate[' +  QuotedStr(tranlateStr) +']';
    MyDesigner.Report.Designer.ReloadReport;
    MyDesigner.SelectedObjects.Clear;
    MyDesigner.SelectedObjects.Add(myMemoView) ;
  except
     MessageDlg('Das einfügen ist nur iin MemoViews mäöglich',
       mtInformation, [mbOK], 0);
  end;
end;

end.

Mir ist schon klar das es noch einiges zu tun und zu verbessern gibt :wink: