Lokalisieren von standard Delphi BPLs? (z.B. vcl140.bpl)

[ralfiii]

Hallo!

Ich hab hier eine EXE die mit mit Packages kompiliert wird.
D.h. es werden am Kundenrechner unsere EXEs und die zugehörigen standard Delphi BPLs installiert.
Die Anwendung ist lokalisiert (übrigens mit Localizer), d.h. zur Anwendung "MyApp.exe" gibt's die Files "MyApp.de" (für deutsch), "MyApp.rus" für Russisch etc.

Nun mein Problem: Wird ein MessageDlg in der App gefeuert, dann ist zwar der Meldungstext lokalisiert, aber die Buttons (OK, Yes, No, Cancel...) und der Fenster-Titel ("Confirmation", "Information"...) nicht.
Für deutsch lässt sich das lösen, da liefere ich einfach zur VCL140.bpl auch noch die vcl140.de (kommt ja mit dem deutschen Delphi mit).
Nur was mache ich mit den anderen Sprachen?
Kann ich ein Delphi-Package nachträglich übersetzen? (oder zumindest Teile davon)

Vielen Dank!
Ralf

[Furtbichler]

Deswegen habe ich mir einfach einen eigenen Message-Dialog geschrieben und dabei das Design ein wenig gepimpt. Ich verwende DevExpress-Komponenten und da macht sich so ein 'Wollen Sie wirklich speichern' Dialog im guten alten Windows-Style einfach nicht so gut.

Nebeneffekt: Ich kann das lokalisieren.

Ach: Prozedurenamen und Parameter sind natürlich identisch zu den aus der Dialogs-Unit.

Für das Speichern und Öffnen der Dateien habe ich das aber nicht gemacht, denn erstens ist das eh der native Windows Dialog und zweitens hat das imho nichts mit meiner Anwendung zu tun. Das ist aber Geschmackssache.

[ralfiii]

Die Anwendung ist geskinned, da schauen auch die MessageDialoge halbwegs nett aus.
Und beim Lokalisieren geht's ja potentiell auch um ein paar (wenige) Exception-Texte wie z.B. "Cannot create file..." die in Ausnahmefällen bis zum User durchkommen.
Klar kann ich das überall in try-except-Blöcke wickeln und versuchen das zu übersetzen, aber die bpl zu lokalisieren wäre VIEL einfacher.

[Bentissimo]

Man kann das gewünschte Ziel per einfachem Hook erreichen. Die Anregung dazu fand ich glaube ich auch hier und hab eine eigene Unit daraus gemacht:

Delphi-Quellcode:

unit MsgDlgLanguage;

interface

// Ändert die Beschriftungen gemäss der vorgegebenen Sprache
procedure HookDlgResources(ALanguage: Integer);

implementation

uses
  Windows,
  Consts;

// Führt das "Hooking" der Sprach-Ressource durch  
procedure HookResourceString(ResStringRec: PResStringRec; NewStr: PChar);
var
  OldProtect: DWORD;
begin
  VirtualProtect(ResStringRec, SizeOf(ResStringRec^), PAGE_EXECUTE_READWRITE, @OldProtect);
  ResStringRec^.Identifier := Integer(NewStr);
  VirtualProtect(ResStringRec, SizeOf(ResStringRec^), OldProtect, @OldProtect);
end;

procedure HookDlgResources(ALanguage: Integer);
begin
  case ALanguage of
    // Deutsch
    1: begin
         // Titel für MessageDlg
         HookResourceString(@SMsgDlgWarning, 'Warnung');
         HookResourceString(@SMsgDlgError, 'Fehler');
         HookResourceString(@SMsgDlgInformation, 'Information');
         HookResourceString(@SMsgDlgConfirm, 'Bestätigung');
         // Buttons für MessageDlg
         HookResourceString(@SMsgDlgYes, '&Ja');
         HookResourceString(@SMsgDlgNo, '&Nein');
         HookResourceString(@SMsgDlgOK, 'Ok');
         HookResourceString(@SMsgDlgCancel, 'Abbrechen');
         HookResourceString(@SMsgDlgAbort, '&Abbrechen');
         HookResourceString(@SMsgDlgRetry, '&Wiederholen');
         HookResourceString(@SMsgDlgIgnore, '&Ignorieren');
         HookResourceString(@SMsgDlgAll, 'A&lle');
         HookResourceString(@SMsgDlgNoToAll, 'A&lle Nein');
         HookResourceString(@SMsgDlgYesToAll, 'A&lle Ja');
         HookResourceString(@SMsgDlgHelp, '&Hilfe');
       end;
    // Französisch
    2: begin
         // Titel für MessageDlg
         HookResourceString(@SMsgDlgWarning, 'Avertissement');
         HookResourceString(@SMsgDlgError, 'Erreur');
         HookResourceString(@SMsgDlgInformation, 'Information');
         HookResourceString(@SMsgDlgConfirm, 'Confirmation');
         // Buttons für MessageDlg
         HookResourceString(@SMsgDlgYes, '&Oui');
         HookResourceString(@SMsgDlgNo, '&Non');
         HookResourceString(@SMsgDlgOK, 'Ok');
         HookResourceString(@SMsgDlgCancel, 'Annuler');
         HookResourceString(@SMsgDlgAbort, 'R&ejeter');
         HookResourceString(@SMsgDlgRetry, '&Répéter');
         HookResourceString(@SMsgDlgIgnore, '&Ignorer');
         HookResourceString(@SMsgDlgAll, '&Tous');
         HookResourceString(@SMsgDlgNoToAll, 'To&us non');
         HookResourceString(@SMsgDlgYesToAll, 'Tou&s oui');
         HookResourceString(@SMsgDlgHelp, 'Ai&de');
       end;
    // Italienisch
    3: begin
         // Titel für MessageDlg
         HookResourceString(@SMsgDlgWarning, 'Avvertimento');
         HookResourceString(@SMsgDlgError, 'Errore');
         HookResourceString(@SMsgDlgInformation, 'Informazione');
         HookResourceString(@SMsgDlgConfirm, 'Conferma');
         // Buttons für MessageDlg
         HookResourceString(@SMsgDlgYes, '&Si');
         HookResourceString(@SMsgDlgNo, '&No');
         HookResourceString(@SMsgDlgOK, 'Ok');
         HookResourceString(@SMsgDlgCancel, 'Cancellare');
         HookResourceString(@SMsgDlgAbort, 'A&bortire');
         HookResourceString(@SMsgDlgRetry, '&Ripetere');
         HookResourceString(@SMsgDlgIgnore, '&Ignorare');
         HookResourceString(@SMsgDlgAll, '&Tutti');
         HookResourceString(@SMsgDlgNoToAll, 'Tutti N&o');
         HookResourceString(@SMsgDlgYesToAll, 'T&utti Si');
         HookResourceString(@SMsgDlgHelp, '&Aiuto');
       end;
  end;
end;

end.

Weitere Sprachen einfach in die case Anweisung einhängen und bei Sprachwechsel die Prozedur HookDlgResources aufrufen.

[Furtbichler]

Zitat:

Zitat von ralfiii (Beitrag 1207489)

...Und beim Lokalisieren geht's ja potentiell auch um ein paar (wenige) Exception-Texte wie z.B. "Cannot create file..." die in Ausnahmefällen bis zum User durchkommen....die bpl zu lokalisieren wäre VIEL einfacher.

Dann ja. Nur passiert das bei mir nicht (Stichwort: Exception-Wrapping).

Bei mir war die primäre Motivation der Unterschied beim Layout.

Hooken ist aber auch ganz witzig.